Версия для печати темы

Автор: what is 13.01.2007 1:25

Задача-поменять в строке местами самое длинное и короткое слова. Разделители:' ',',','.','!','"','?','/'.
Написала прогу, заработала она, но не так. Удаляет самое короткое слово, а длинное копирует и вставляет в начало строки. Не могу найти ошибку. Помогите. Я знаю, что такая задача есть в FAQ, но найти не смогла.

Program uzas;
const
 limit=[' ',',','.','!','"','?','/'];
var
 s:string;
 i,k,l,imax,imin,b,lmax,lmin:integer;
 s1,s2:string;
begin
 writeln('строка');
 readln(s);
 i:=1;
 k:=0;
 lmin:=length(s);
 while i<=(length(s)) do
 begin
  if not (s[i] in limit) then
  begin
   k:=i;
   s1:=' ';
   while (i<=length(s)) and (not(s[i] in limit)) do
    begin
     s1:=s1+s[i];
     inc(i);
    end;
   if length(s1)<lmin then
   begin
     lmin:=length(s1);
     imin:=k;
   end;
  end;
  inc(i);
 end;
 lmax:=1;
 while i<=length(s) do
 begin
  if not(s[i] in limit) then
  begin
    l:=i;
    s2:=' ';
    while (i<=length(s)) and (not(s[i] in limit)) do
    begin
     s2:=s2+s[i];
     inc(i);
    end;
   if length(s2)>lmax then
   begin
    lmax:=length(s2);
    imax:=l;
   end;
  end
  else
   inc(i);
 end;
  delete(s,imin,lmin);
  delete(s,imax,lmax);
  insert(s2,s,imin);
  insert(s1,s,imax);
  write(s);
  writeln;
end.

Автор: Артемий2 13.01.2007 1:39

Program uzas;
const
 limit=[' ',',','.','!','"','?','/'];
var
 s:string;
 i,k,l,imax,imin,b,lmax,lmin:integer;
 s1,s2:string;
begin
 writeln('строка');
 readln(s);
 i:=1;
 k:=0;
 lmin:=length(s);
 while i<=(length(s)) do
 begin
  if not (s[i] in limit) then
  begin
   k:=i;
   s1:=' ';
   while (i<=length(s)) and (not(s[i] in limit)) do
    begin
     s1:=s1+s[i];
     inc(i);
    end;
   if length(s1)<lmin then
   begin
     lmin:=length(s1);
     imin:=k;
   end;
  end;
  inc(i);
 end;
 lmax:=1;
 while i<=length(s) do
 begin
  if not(s[i] in limit) then
  begin
    l:=i;
    s2:=' ';
    while (i<=length(s)) and (not(s[i] in limit)) do
    begin
     s2:=s2+s[i];
     inc(i);
    end;
   if length(s2)>lmax then
   begin
    lmax:=length(s2);
    imax:=l;
   end;
  end
  else
   inc(i);
 end;
  delete(s,imin,lmin);
  delete(s,imax,lmax);
  insert(s2+' ',s,imin);
  insert(s1+' ',s,imax);
  write(s);
  writeln;
readln
end.

а вот так вроде пашет.

Автор: what is 13.01.2007 1:57

Спасибо за ответ. Еще раз проверю.

вот прогон:

 
строка
че делать? скоро экзамен по проге. ужас!!
ужас  делать? скоро экзамен по проге. ужас!!

все равно не прет...неправильно она слова меняет. В чем причина?
П.С.ужас! я - лузер!!

Помогите несчастному лузеру....

Автор: Артемий2 13.01.2007 1:58

А как именно ты хочешь менять самую длинное слово на короткое? Местами, или длинное вперед а короткое назад? Она у тебя видимо копирует последнее вперед, а короткое вообще ничего, а первое слово удаляет!

Автор: what is 13.01.2007 2:06

ну я это я вижу.
ну я сначала нашла короткое и длинное слова. затем я удаляю короткое слово и с его начального символа(imin) вставляю длинное. так же с длинным. хотя я вижу, что это вышло только теоритически((

Автор: volvo 13.01.2007 2:14

Ну, давай попробуем вот это:

Program uzas;
const
  limit=[' ',',','.','!','"','?','/'];
var
  s:string;
  i,k,imax,imin,b,lmax,lmin:integer;
  s1,s2, subs:string;

begin
  write('s = '); readln(s);
  { s := '1 123456 12 12345678 1234'; }

  i:=1; k:=0;
  lmin:=length(s); lmax := 1;

  while i<=(length(s)) do begin

    subs := '';
    if not (s[i] in limit) then begin
      k:=i;
      while (i<=length(s)) and (not(s[i] in limit)) do begin
        subs := subs + s[i];
        inc(i);
      end;

      if length(subs) < lmin then begin
        s1 := subs;
        lmin:=length(s1);
        imin:=k;
      end;
      if length(subs) > lmax then begin
        s2 := subs;
        lmax:=length(s2);
        imax:=k;
      end;
    end;
    inc(i);
  end;

  {
    Очень трудноуловимая ошиибка была у тебя: СНАЧАЛА надо удалять слово,
    которое ближе к концу, и СРАЗУ на его место записывать второе - иначе 
    собъешь индексацию ...
  }
  if imin > imax then begin
    delete(s,imin,lmin);
    insert(s2,s,imin);
    delete(s,imax,lmax);
    insert(s1,s,imax);
  end
  else begin
    delete(s,imax,lmax);
    insert(s1,s,imax);
    delete(s,imin,lmin);
    insert(s2,s,imin);
  end;

  write(s);
  writeln;
end.

Кстати, чтобы не делать 2 цикла, я один удалил - это стоило одной дополнительной переменной...

Автор: what is 13.01.2007 2:15

все.....

огромное спасибо!!!!
жизнь продолжается...