Версия для печати темы

Автор: noskovgleb 13.12.2009 5:00

Сама задача выглядит вот так:
Дан файл "Багаж пассажиров", который содержит данные о количестве вещей и их общем весе для каждого пассажира. Выделить пассажиров, данные которых превышают средние показатели файла.
Объясните пожалуста... код мне впринципе ненужен!

Автор: volvo 13.12.2009 5:16

Автор: noskovgleb 13.12.2009 5:26

у меня такое задание в методичке по ООП)) а это нужно что б информация о каждом багаже хранилась в Массиве объектов?

Автор: volvo 13.12.2009 5:53

У тебя по условию информация в файле хранится, а не в массиве. А уж куда ты ее прочитаешь - дело твое...

Автор: noskovgleb 13.12.2009 14:53

А считать с помощью метода который будет в объекте?

Автор: volvo 13.12.2009 15:58

Опять же, смотря что за объект... Можно сделать объект - Пассажир, который будет хранить только информацию об одном пассажире + массив таких объектов, тогда можно читать файл и не из метода, а простой функцией.

Можно сделать Массив в виде объекта, тогда читать файл можно будет из метода этого объекта.

Ты определись, что именно ты будешь делать, а потом вопросы задавай.

Автор: noskovgleb 15.12.2009 23:24

Вот если я начал где то так, что б лучше всего делать дальеш?

   
   uses crt;
   type
      OO = object
              kolv : byte;
              oves : integer;

         //     constructor init;
              procedure sves;
              procedure openbogag;
           end;
{------------------------------------}
   procedure OO.sves;
   Begin
      writeln('Сдесь будет считаться общий вес');
   End;
{------------------------------------}
   procedure oo.openbogag;
      var f : text;
          i,b : byte;
   Begin
      assign(f,'bagag.txt');
      reset(f);
         while not eof (f) do
            begin
               read(f,b);
               writeln(b);
            end;
      close(f);
   End;
{------------------------------------}
   var
      BP : OO;
BEGIN
   clrscr;
   BP.sves;
   BP.openbogag;
   readln;

END.


 

Автор: volvo 15.12.2009 23:59

Автор: noskovgleb 17.12.2009 2:33

С памятью ошибка

Автор: andriano 17.12.2009 2:41

Цитата(noskovgleb @ 16.12.2009 22:33)

Автор: noskovgleb 17.12.2009 2:47

Неповерите... ошибки нет...
Так вот... правильно я начал делать? Общий вес вещей всех пассажиров или общий вес вещей одного пассажира? вот непонятно...

Добавлено через 2 мин.
Наверно всего скорей вес вещей именно одного человека...

Автор: noskovgleb 17.12.2009 3:48

вот сделал так. Хочу спросить как можно процедуре sves дать массив мой?



Добавлено через 5 мин.

   
uses crt;
   type
      OO = object
              kolv : byte;
              oves : integer;

         //     constructor init;
              procedure sves;
              procedure openbogag;
              procedure createmassiv;
           end;
{------------------------------------}
   procedure OO.sves;
   Begin
      writeln('Сдесь будет считаться общий вес');
   End;
{------------------------------------}
   procedure oo.openbogag;
      var f : text;
          i : byte;
          b : byte;
   Begin
      i:=0;
      assign(f,'bagag.txt');
      reset(f);
         while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               write(b:2,' ');
               if i=2 then
                 begin
                    writeln;
                    i:=0;
                 end;
            end;
      close(f);
   End;
{------------------------------------}
   procedure oo.createmassiv;
   var j : integer;
       i : integer;
       f : text;
       b : byte;
       m : array[1..5] of integer;
   Begin
       writeln;
       i:=0;
       j:=1;
      assign(f,'bagag.txt');
      reset(f);
         while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
           //    write(b:2,' ');
               if i=2 then
                 begin
                    m[j]:=b;
                    writeln(m[j]);
                    inc(j);
                    i:=0;
                 end;
            end;
      close(f);
   End;
{------------------------------------}
   var
      BP : OO;
      m : array[1..5] of integer;
BEGIN
   clrscr;
   BP.sves;
   BP.openbogag;
   BP.createmassiv;
   readln;

END.

Автор: volvo 17.12.2009 4:24

Никак... У тебя данные читаются в ЛОКАЛЬНЫЙ массив, описанный в методе createmassiv. Чтобы получить к нему доступ из любого другого метода этого объекта - просто перенеси его описание:

type
  OO = object
    kolv : byte;
    oves : integer;
    //     constructor init;
    procedure sves;
    procedure openbogag;
    procedure createmassiv;

  private // пусть будет приватным членом
    m : array[1..5] of integer;
  end;

Автор: noskovgleb 17.12.2009 4:47

ии... у меня получилось что то такое...

uses crt;
   type
      OO = object
              kolv : byte;
              oves : integer;

         //     constructor init;
              procedure sves;
              procedure openbogag;
              procedure createmassiv;
           private
              m : array[1..5] of integer;
           end;
{------------------------------------}
   procedure OO.sves;
      var
         i    :byte;
         summa:integer;
         j    :byte;
   Begin
      j:=0;
      writeln('Сдесь будем определять кто взял большой вес одежды) ');
      writeln;
      for i:=1 to 5 do
          begin
             summa:=summa+m[i];
             inc(j);
          end;
      for i:=1 to 5 do
         if m[i] > (summa/j)
            then writeln(i,'-й пассажир превысил средний вес вещей.');

   End;
{------------------------------------}
   procedure oo.openbogag;
      var f : text;
          i : byte;
          b : byte;
   Begin
      i:=0;
      assign(f,'bagag.txt');
      reset(f);
         while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               write(b:2,' ');
               if i=2 then
                 begin
                    writeln;
                    i:=0;
                 end;
            end;
      close(f);
   End;
{------------------------------------}
   procedure oo.createmassiv;
   var j : integer;
       i : integer;
       f : text;
       b : byte;
   Begin
       writeln;
       i:=0;
       j:=1;
      assign(f,'bagag.txt');
      reset(f);
         while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
           //    write(b:2,' ');
               if i=2 then
                 begin
                    m[j]:=b;
                    writeln(m[j]);
                    inc(j);
                    i:=0;
                 end;
            end;
      close(f);
   End;
{------------------------------------}
   var
      BP : OO;
BEGIN
   clrscr;
   BP.openbogag;
   BP.createmassiv;
   BP.sves;
   readln;

END.

Автор: noskovgleb 17.12.2009 14:42

А как бы тут можно добавить наследование и полиморфизм?

Автор: volvo 17.12.2009 15:00

Во первых, "Это" надо сначала причесать, чтоб оно хотя бы без наследования и полиморфизма на что-то было похоже... А во-вторых, ну пойми же ты: не нужно на такой простой задаче ни полиморфности, ни дерева наследования, ни вообще ООП. Она элементарно решатся другими средствами, и решение получается ПРОЩЕ, чем с Объектами. Это - главный признак того, надо тебе ООП или нет. Ну ладно, допустим, задание такое. Ну хорошо, сделал "ООП" (будем считать наличие слова Object в программе достаточным для того, чтоб она стала Объектно-Ориентированной), остановись на этом. Ты уже и так кашу заварил, потом долго расхлебывать будешь (если конечно, тебе не сдать и забыть) - надо ж будет научиться писать программы с ООП правильно, а не просто чтоб было слово Object...

Автор: volvo 17.12.2009 17:56

На всякий случай, чтоб было понятнее, что такое наследование и полиморфизм -

type
  PTBaseItem = ^TBaseItem;
  TBaseItem = object
    constructor init;
    destructor done; virtual;

    procedure Get(var f: text); virtual;
    procedure Print; virtual;
  end;

constructor TBaseItem.init;
begin end;
destructor TBaseItem.done;
begin end;

procedure TBaseItem.Get(var f: text);
begin end;
procedure TBaseItem.Print;
begin end;

type
  PTPassenger = ^TPassenger;
  TPassenger = object(TBaseItem)
    name: string;
    amount, weight: integer;
    constructor Init;
    destructor Done; virtual;

    procedure Get(var f: text); virtual;
    procedure Print; virtual;
  end;

constructor tpassenger.Init;
begin
  inherited; // инициализируем предка
  // все операции по выделению памяти - здесь
end;
destructor tpassenger.done;
begin
  // здесь - все операции по освобождению памяти, если нужно
  inherited; // удаляем предка
end;

procedure TPassenger.Get(var f: text);
var ch: Char;
begin
  ch := #0; name := '';
  repeat
    read(f, ch);
    if ch <> ' ' then name := name + ch;
  until ch = ' ';
  read(f, amount);
  read(f, weight);
  readln(f);
end;
procedure TPassenger.Print;
begin
  writeln(name:10, '':2, amount:5, '':2, weight:5);
end;

type
  TCompareFunc = function(p: PTBaseItem): Boolean;
  PTListItem = ^TListItem;
  TListItem = object
    info: PTBaseItem;
    next, prev: PTListItem;
    constructor CreateItem(p: PTBaseItem; _prev, _next: PTListItem);
    destructor DestroyItem;
  end;
  { Абстрактный список...
    Может хранить указатели на любых наследников TBaseItem }
  TBaseList = object
    constructor Init;
    destructor Done;

    procedure Append(p: PTPassenger);
    procedure FilterList(func: TCompareFunc);
    procedure PrintList;
  private
    head, tail: PTListItem;
    function find(func: TCompareFunc): PTListItem;
    procedure RemoveItem(p: PTListItem);
  end;


constructor TListItem.CreateItem(p: PTBaseItem; _prev, _next: PTListItem);
begin
  info := p; prev := _prev; next := _next;
end;
destructor TListItem.DestroyItem;
begin
  Dispose(info, Done);
end;

constructor TBaseList.Init;
begin
  head := nil; tail := nil;
end;
destructor TBaseList.Done;
begin
  while Assigned(head) do RemoveItem(head);
end;

procedure TBaseList.Append(p: PTPassenger);
var newItem: PTListItem;
begin
  new(newItem, CreateItem(p, tail, nil));
  if head = nil then head := newItem
  else tail^.next := newItem;

  tail := newItem;
end;

function TBaseList.find(func: TCompareFunc): PTListItem;
var
  p: PTListItem;
  ok: boolean;
begin
  p := head;
  ok := true;
  while Assigned(p) and ok do
    if func(p^.info) then ok := false
    else p := p^.next;

  find := p
end;

procedure TBaseList.RemoveItem(p: PTListItem);
var r: PTListItem;
begin
  r := p^.prev;
  if r <> nil then r^.next := p^.next
  else head := p^.next;

  r := p^.next;
  if r <> nil then r^.prev := p^.prev
  else tail := p^.prev;

  Dispose(p, DestroyItem);
  p := nil;
end;

procedure TBaseList.FilterList(func: TCompareFunc);
var p: PTListItem;
begin
  repeat
    p := find(func);
    if Assigned(p) then RemoveItem(p);
  until p = nil;
end;

procedure TBaseList.PrintList;
var p: PTListItem;
begin
  p := head;
  while Assigned(p) do begin
    p^.info^.Print;
    p := p^.next;
  end;
end;


type
  { А это - вполне себе конкретный список Пассажиров,
    с добавленным функционалом }
  TPassList = object(TBaseList)
    AverAmount, AverWeight: double;

    constructor Init;
    destructor Done;
    procedure FindAverages;
  end;


constructor TPassList.Init;
begin
  inherited Init;
  AverAmount := 0.0; AverWeight := 0;
end;
destructor TPassList.Done;
begin
  inherited Done;
end;

procedure TPassList.FindAverages;
var
  p: PTListItem;
  count: integer;
begin
  p := head;
  count := 0;
  while Assigned(p) do begin
    inc(count);
    AverAmount := AverAmount + PTPassenger(p^.info)^.amount;
    AverWeight := AverWeight + PTPassenger(p^.info)^.weight;	
    p := p^.next;
  end;
  AverAmount := AverAmount / count;
  AverWeight := AverWeight / count;
end;


{
  Помнится, тебе нужна была полиморфность? Вот она ...
  В эту процедуру передается объект любого класса-наследника TBaseItem
}
procedure Get(var obj: TBaseItem; var f: text);
begin
  obj.Get(f);
end;

var
  Lst: TPassList;

function funcFilter(p: PTBaseItem): boolean; far;
begin
  funcFilter := (PTPassenger(p)^.Amount < Lst.AverAmount) or (PTPassenger(p)^.Weight < Lst.AverWeight);
end;

var
  f: text;
  pp: PTPassenger;
begin
  writeln('start');
  assign(f, 'bagag.txt'); reset(f);
  Lst.Init;
  while not eof(f) do
  begin
    pp := new(PTPassenger, Init);
    Get(pp^, f);
    Lst.Append(pp);
  end;
  Lst.PrintList;
  Lst.FindAverages;
  writeln('Average amount:', Lst.AverAmount:10:5, ' Average weight: ', Lst.AverWeight:10:5);
  Lst.FilterList(funcFilter);
  Lst.PrintList;
  Lst.Done;
  close(f);
  readln;
end.

ivanov 4 100
petrov 2 29
sidorov 5 115
kuznetzov 3 102

Автор: noskovgleb 19.12.2009 16:19

Задача была в том что бы реализовать эту прогу сначала просто с объектами, потом с наследованием а потом еще и с полиморфизмом...

Добавлено через 1 мин.
Да преподаватель такой попался ничего нехочет слушать, вот то что в методичке есть то и делай...

Автор: noskovgleb 26.12.2009 21:58

вот вообщем получилось зделать уже и наследование, осталось зделать полиморфизм.... и каким образом его втыкнуть? и что он должен делать)?

 
program laba13;
   type
      tm = array[1..5] of integer;
      OO = object
              m    : tm;                               { object }
              kolv : byte;                    { count of things }
              oves : integer;                { weight of things }
              constructor init(var im:tm);
              procedure openbogazh;        { open list of thing }
              procedure createmassiv(var cm:tm);{ mas of things }
           end;
      tves = object(OO)
                 procedure sves(var sm:tm);   { find max weight }
              end;
{---------------------------------------------------------------}
   constructor OO.init;
   begin
      im:=m;
   end;
{---------------------------------------------------------------}


{---------------------------------------------------------------}
   procedure tves.sves(var sm:tm);
      var
         i    :byte;
         summa:integer;
         j    :byte;
   Begin
      j:=0;
      writeln;
      writeln('3десь будем определять кто взял большой вес одежды) ');
      writeln;
      for i:=1 to 5 do
          begin
             summa:=summa+sm[i];
             inc(j);
          end;
      for i:=1 to 5 do
         if sm[i] > (summa/j)
            then writeln(i,'-й пассажир превысил средний вес вещей.');

   End;
{---------------------------------------------------------------}
   procedure OO.openbogazh;
      var f : text;
          i : byte;
          b : byte;
   Begin
      i:=0;
      assign(f,'bagag.txt');
      reset(f);
      while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               write(b:2,' ');
               if i=2 then
                 begin
                    writeln;
                    i:=0;
                 end;
            end;
      close(f);
   End;
{---------------------------------------------------------------}
   procedure oo.createmassiv(var cm:tm);
   var j : integer;
       i : integer;
       f : text;
       b : byte;
       y : byte;
       xm:   tm;
   Begin
       writeln;
       i:=0;
       j:=1;
       y:=0;
      assign(f,'bagag.txt');
      reset(f);
      while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               if i=2 then
                 begin
                    xm[j]:=b;
                    inc(y);
                    writeln('ves veshei ',y,
                            '-ogo passagira ',xm[j],' kg');
                    cm[y]:=xm[j];
                    inc(j);
                    i:=0;
                 end;
            end;
      close(f);
   End;
(*--------------------                           --------------*)
   var
      BP : OO;
      ves:tves;
BEGIN
   writeln('--------------------------------------------------');
   BP.openbogazh;
   BP.createmassiv(BP.m);
   ves.sves(BP.m);
   readln;
END.

 

Автор: volvo 26.12.2009 22:29

Давай начнем с малого: Что такое вообще "полиморфизм", ты понимаешь?

Автор: noskovgleb 26.12.2009 23:24

собственно в FAQ прочитал.
Возможность определения единого по имени действия (процедуры или функции), применимого одновременно ко всем объектам иерархии наследования, причем каждый объект может "заказывать" особенность реализации этого действия над "самим собой".

Автор: volvo 26.12.2009 23:30

Хорошо. Прочитал. А понял?

Ты мой код смотрел, из 17-го сообщения, где есть полиморфная процедура Get, которая работает с любым объектом, унаследованным от единого предка? Вот тебе и "особенности реализации действия над самим собой"...

Автор: noskovgleb 26.12.2009 23:49

Да... но что делает эта процедура.(?

Автор: volvo 27.12.2009 0:21

Автор: noskovgleb 27.12.2009 7:17

Я извеняюсь Volvo что немогу воспользоваться тем что ты написал... хочеться попробывать свое... или хотябы увидеть то что смогу понять. Еще один вопрос это будет похоже на полиморфим, если да то что здесь не так?

 
program laba15;
   type
      tm = array[1..5] of integer;
      OO = object
              m    : tm;                               { object }
              kolv : byte;                    { count of things }
              oves : integer;                { weight of things }
              constructor init(var im:tm);
              procedure openbogazh;        { open list of thing }
              procedure createmassiv(var cm:tm);{ mas of things }
           end;
      tves = object(OO)
                procedure sves(var sm:tm);virtual;   { find max weight }
             end;
      tves2= object(OO)
                procedure sves(var sm:tm);virtual;
             end;
{---------------------------------------------------------------}
   constructor OO.init(var im:tm);
   begin
      im:=m;
   end;
{---------------------------------------------------------------}


{---------------------------------------------------------------}
   procedure tves.sves(var sm:tm);
      var
         i    :byte;
         summa:integer;
         j    :byte;
   Begin
      j:=0;
      writeln;
      writeln('3десь будем определять кто взял большой вес одежды) ');
      writeln;
      for i:=1 to 5 do
          begin
             summa:=summa+sm[i];
             inc(j);
          end;
      for i:=1 to 5 do
         if sm[i] > (summa/j)
            then writeln(i,'-й пассажир превысил средний вес вещей.');

   End;
{--------------------------------------------------------------}
   procedure tves2.sves(var sm:tm);
      var
         i  :byte;
         sbv:byte;
         max:byte;
   begin
      max:=sm[1];
      for i:= 1 to 5 do
         if sm[i]>max then
             max:=sm[i];
      writeln('Найбольший вес вещей = ',max);
      readln;

   end;
{---------------------------------------------------------------}
   procedure OO.openbogazh;
      var f : text;
          i : byte;
          b : byte;
   Begin
      i:=0;
      assign(f,'bagag.txt');
      reset(f);
      while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               write(b:2,' ');
               if i=2 then
                 begin
                    writeln;
                    i:=0;
                 end;
            end;
      close(f);
   End;
{---------------------------------------------------------------}
   procedure oo.createmassiv(var cm:tm);
   var j : integer;
       i : integer;
       f : text;
       b : byte;
       y : byte;
       xm:   tm;
   Begin
       writeln;
       i:=0;
       j:=1;
       y:=0;
      assign(f,'bagag.txt');
      reset(f);
      while not eof (f) do
            begin
               i:=i+1;
               read(f,b);
               if i=2 then
                 begin
                    xm[j]:=b;
                    inc(y);
                    writeln('ves veshei ',y,
                            '-ogo passagira ',xm[j],' kg');
                    cm[y]:=xm[j];
                    inc(j);
                    i:=0;
                 end;
            end;
      close(f);
   End;
(*--------------------                           --------------*)
   var
      BP : OO;
      ves:tves;
      ves2:tves2;
BEGIN
   writeln('--------------------------------------------------');
   BP.openbogazh;
   BP.createmassiv(BP.m);
   ves.sves(BP.m);
   ves2.sves(BP.m);
   readln;
END.

Автор: volvo 27.12.2009 13:53