Версия для печати темы

Автор: markusha 8.11.2010 1:27

Здравствуйте! Помогите, пожалуйста, с задачей: "Даны 2 квадратные матрицы порядка n. Получить новую матрицу прибавлением к элементам каждого столбца первой матрицы произведения элементов соответствующих строк второй матрицы". Процедуры на ввод и вывод матриц я уже написал, а вот сам алгоритм подсчета значений элементов новой матрицы не могу.
Заранее большое спасибо!

Автор: sheka 8.11.2010 2:27

Если я правильно понял задание - то так

for i:=1 to n do
begin
  s:=1;
  for j:=1 to n do
    s:=s*b[i,j]);
  for j:=1 to n do
    inc(a[i,j],s);
end;

Пожалуйста, выкладывай все, что написал, т.к. во первых - это значит, что ты хоть что-то делал, а во вторых, нам не надо заново это писать. (именно поэтому я не проверял работоспособность).

Добавлено через 2 мин.
я понял, что соответствующий рядок - это тот рядок, в котором находится элемент.

Автор: markusha 9.11.2010 3:29

Спасибо огромное!
Вот, что у меня получилось

Uses CRT;

Const
  VG = 10;
  NG = 0;

Type
  Matrix = array [1..VG, 1..VG] of real;

Procedure ReadElem (var Elem: real);
var ElemS: string;
    ElemC: integer;
begin
  Repeat
    readln (ElemS);
    val (ElemS, Elem, ElemC);
    if ElemC <> 0 then
      writeln ('Error');
  Until ElemC = 0;
end;

Procedure ReadOrder (Prompt: string;
                     var Order: byte);
var s: string;
    c: integer;
    OK: boolean;
begin
  Repeat
    write (Prompt);
    readln (S);
    val (S, Order, C);
    if C <> 0 then
      writeln ('Error')
    else
      begin
        OK := (Order >= NG) and (Order <= VG);
        if not OK then
          writeln ('Order isn''t in a range');
      end;
  Until (C = 0) and OK;
end;

Procedure ReadMatrix (Order: byte;
                      var A: Matrix;
                      var B: Matrix);
var i, j: byte;
begin
  writeln ('Enter elements of matrix A: ');
  for i := 1 to Order do
   for j := 1 to Order do
     begin
       write ('A[', i, j, ']: ');
       ReadElem (A[i, j]);
     end;
  writeln ('Enter elements of matrix B: ');
  for i := 1 to Order do
   for j := 1 to Order do
     begin
       write ('B[', i, j, ']: ');
       ReadElem (B[i, j]);
     end;
end;

Procedure PrintMatrix (Order: byte; C: Matrix);
var i, j: byte;
begin
  for i := 1 to Order do
    begin
      for j := 1 to Order do
        write (C[i, j]: 4: 2, ' ');
        writeln;
    end;
end;

var Order, i, j: byte;
    A, B, C: Matrix;
    product: real;

begin
  Repeat
    TextBackground (0);
    ClrScr;
    ReadOrder ('Enter Order of Matrixs: ', Order);
    ReadMatrix (Order, A, B);
    for i := 1 to Order do
      begin
        product := 1;
        for j := 1 to Order do
          product := product * b[i, j];
        for j := 1 to Order do
          c[i, j] := (product + a[i, j]);
      end;
    PrintMatrix (Order, C);
    Writeln ('Continue? (y, Y)');
  Until  not (Readkey in ['y', 'Y']);
end.