Версия для печати темы

Procedure TQueue.Push(var q:TQueue; e: Char);
var z:Tlist;
begin
  new(z);
  z^.info:=E;
  z^.next:=nil;
  If Empty(q) then q.head:=z else q.tail^.next:=z;
  q.tail:=z
end;

unit MyQueue;

interface

type
PNode = ^Node;
Node = record
     Info:Char;
     Next:PNode;
end;
TQueue = class
   private
     head,tail:PNode;
   public
     function Empty:Boolean;
     procedure Push (Value:Char);
     procedure Pop (var Value:Char);
     constructor Create;
     destructor Destroy; override;
end;

implementation

constructor TQueue.Create;
begin
   inherited;
   head:=nil;
   tail:=nil;
end;

destructor TQueue.Destroy;
var Value:Char;
begin
   while (not Empty) do Pop (Value);
   inherited;
end;

function TQueue.Empty:Boolean;
begin
   Empty := not assigned(head);
end;

procedure TQueue.Push (Value:Char);
var P:PNode;
begin
   new(P);
   p^.info:=value;
   p^.next:=nil;
   if empty then head:=p
   else tail^.next := p;
   tail:=p;
end;

procedure TQueue.Pop (var Value:Char);
var P:PNode;
begin
   if not Empty then
     begin
       value:=head^.info;
       p:=head;
       head:=p^.next;
       if head=nil then tail:=nil;
       dispose(p);
     end;
end;

end.