Графика, помогите с задачкой Опции

[Ilius]

Составить программу для управления размерами прямоугольника и его положением на экране.Левый верхний угол исходного прямоугольника расположен в точке (50,50), правый нижний в точке(100,100).Управление выполняется клавишами:
">"-увелич.ширину прямоугольника на 5 точек;
"<"-уменьш.ширину прямоугольника на 5 точек;
"+" -увелич. высоту на 5 точек;
"-" уменьшает высоту на 5 точек.
Клавиши управл.курсором-вызывают перемещение в соответствующем направлении.
"Ввод завершает работу программы.

[MAXXX]

Уменьшают ширину-справа, слева или все равно как?

[Ilius]

Все равно, просто уменьшают или увеличивают.

[Tan]

Что - то такое ?

uses crt, Graph;
var x,y,x1,y1,
    grMode,grDriver : integer;
     ch : char;
procedure draw;
begin
clrscr;
rectangle (x,y,x1,y1);
end;
begin
grDriver := detect;
Initgraph (grDriver,grMode,'');
x := 50;
y := x;
x1 := 100;
y1 := x1;
draw;
repeat
ch := readkey;
 case ch of
   #46 : begin
             x1 := x1 + 5;
             Draw;
          end;
   #44  : begin
             x1 := x1 - 5;
             Draw;
          end;
   #61 : begin
             y := y - 5;
             Draw;
        end;
   #45 : begin
             y := y + 5;
             Draw;
        end;
    #072 : begin
            y := y - 5;
            y1 := y1 - 5;
            Draw;
         end;
    #080: begin
            y := y + 5;
            y1 := y1 + 5;
            Draw;
        end;
    #077: begin
           x := x+ 5;
           x1 := x1 + 5;
           Draw;
        end;
   #075: begin
           x := x - 5;
           x1 := x1 - 5;
           Draw;
         end;
   end;
until ord(ch) = 13;
end.

Сообщение отредактировано: Tan - 20.05.2007 19:08

[volvo]

Опять ошибаемся? Не так обрабатываются расширенные клавиши... У тебя будут отрабатываться "P", и т.п. клавиши...

[klem4]

procedure draw;
begin
clrscr; // <------------------- Тут надо ClearDevice;
rectangle (x,y,x1,y1);
end;

[Tan]

volvo, спасибо, это моя частая ошибка, я просто только по нужным кнопком понажимал, проверил, что работает, совсем забыл про расширенные коды, klem4 а зачем ? У меня и без этого всё работает на стандартном компиляторе.

[volvo]

а зачем ?

А затем, что в графике надо использовать процедуры для графики, а в тексте - для текста...

[Tan]

Просто в данном случае визуальная разница лишь в том, что с clrscr сероватый фон, а с cleardevice чёрный, но на будущее учту, спасибо!

[volvo]

Кстати, здесь можно обойтись и вообще без постоянной очистки экрана, если воспользоваться

SetWriteMode(XORPut);

, (в случае если есть фоновое изображение, например, то постоянно его очищать и перерисовывать - с ума можно сойти...)

[Ilius]

Почему то не работает, запускаю экрат мигнул, разглядел BGI Error: и т.д. Что это значит?

Сообщение отредактировано: Ilius - 20.05.2007 22:22

[klem4]

InitGraph(gd, gm, 'ТУТ укажи полный пусть к папке BGI');

Или в настройках компилера.


еще вариант

uses crt, graph;
type

  TRect = Object
    leftX, leftY, height, width: Integer;

    constructor Create(const x, y, h, w: Integer);
    destructor Done;

    procedure Run;

    function Request: Char;
    procedure Show(const visible: Boolean);
  end;

constructor TRect.Create(const x, y, h, w: Integer);
begin
  leftX := x;
  leftY := y;
  height := h;
  width  := w;
  Show(true);
end;

destructor TRect.Done;
begin end;

procedure TRect.Show(const visible: Boolean);
begin
  if visible then SetColor(white) else SetColor(black);
  Rectangle(leftX, leftY, leftX + width, LeftY + Height);
end;

function TRect.Request: Char;
var
  ch: Char;
begin
  ch := readkey;

  Show(false);

  case ch of
    #0: case readkey of
          #72: dec(leftY, 5);
          #80: inc(leftY, 5);
          #75: dec(leftX, 5);
          #77: inc(leftX, 5);
        end;
    '>', '.': inc(width, 5);
    '<', ',': dec(width, 5);
    '+', '=': inc(height, 5);
    '-':      dec(height, 5);
  end;

  Show(true);

  Request := ch;
end;

procedure TRect.Run;
begin
  while (Request <> #27) do;
end;

var
  gd, gm: Integer;
  R: TRect;
begin
  gd := Detect;
  InitGraph(gd, gm, '');

  R.Create(50, 50, 100, 100);
  R.Run;
  R.Done;

  CloseGraph;
end.

[Ilius]

Спасибо вам всем, все работает, выручили!!!