Строки Опции

[Altair]

Строки. Краткая теория.

В Паскале определены два типа строк:

• Тип String
• тип PChar

I. String

Стандартная строка (string) в Паскале, представляет из себя массив, первый элемент которого содержит длину строки, а начиная со второго элемента начинается полезная информация. Поскольку нумерация начинается с 0, то первый элемент строки, содержащий длину строки, имеет индекс 0.

Если Вы попытаетесь осуществить следующее присвоение:

var
  s:string;
  I:byte;
begin
  readln(s);
  i:=s[0];
end.

то компилятор выдаст сообщение об ошибке (несовместимость типов), потому что
все элементы строки - символы (Char)

Для определения длины строки можно использовать или стандартную процедуру Length(stroka) или так:

var
  dlinna_stroki:byte
  s:string;
begin
  readln(s); {вводим строку}
  dlinna_stroki:=Ord(s[0]);
end.

Второй способ менее нагляден, но полезен если Вы забыли стандартные процедуры.

К каждому элементу строки можно обратиться, как к элементу массива. Длина строк ограниченна 255 символами. Поскольку первый элемент строки кодируется одним байтом, он может закодировать максимум 255 элементов.

II. PChar
Для обеспечения поддержки строк, длиннее 255 символов, в TP7 был введен новый тип - PChar. Он имеет следующую структуру:

Type
  PChar = ^Char;

Т.е. представляет собой указатель, но в отличие от обычных указателей, он трактуется необычным образом: считается, что он указывает на цепочку символов, заканчивающуюся символом с кодом #0.

Тип PChar совместим с одномерным символьным массивом с нулевой левой границей (array[0..max]).

Переменные типа PChar индексируются, т.е. к элементам длинной строки можно обратиться по их индексу, как к элементам обычной строки.

СТРОКИ. ЧаВо.

• После посимвольного ввода строки, не получается вывести ее на экран. В чем дело?
  При посимвольном вводе строки, Вы забыли указать длину получившейся строки
  

  s[0]:=chr(dlinna)

  
  Или иначе, при вводе:
  

  {...}
  {ввод очередного символа}
  {...}
  Inc(S[0]);

• Почему не получается индексировать длинную строку?
  Включите расширенный синтаксис директивой {$X+} или в настройках компилятора
• Есть какие-нибудь процедуры для работы с длинными строками?
  Да, есть. В модуле strings
• Как вывести длинную строку на экран?
  Процедурой Writeln, при включенно расширенном синтаксисе.
• Сколько занимает в памяти строка?
  Для обычных строк, если не указана длина строки, то 256 байт.
  Если, при описании переменной, указана длина строки явно (string[8]), то столько, сколько указано +1 байт на нулевой элемент (хранение длинны строки).
  Для PChar размер в памяти равен количеству элементов до символа #0 +1 байт.
• Как перевернуть строку?
  (с использованием второй строки):
  

  var
    s,f: string;
    i,j: byte;
  begin
    readln(s); j:=1;
    for i:=length(s) downto 1 do begin
      f[j]:=s[i]; inc(j);
    end;
    f[0]:=chr(j);
    writeln(f);
  end.

  
  
  (from APAL с использованием одной строки и одной переменной типа Char):
  

  var
    s:string;
    f:Char
    i:byte;
  begin
    readln(s);
    for i:=1 to Length(s) div 2 do begin
      f:=s[i];
      s[i]:=s[Length(s)-i+1];
      s[Length(s)-i+1]:=f;
    end;
    writeln(s);
  end.

[volvo]

Для удобства использования процедуру GetWords можно определить как функцию, которая возвращает количество найденных слов в строке (в переменной delimiters должны храниться символы, которые нужно считать разделителями слов):

type
	TWords = array[1 .. 100] of string[100];
	TDelimiter = set of Char;

function GetWords(s: string; var mas: TWords; delimiters: TDelimiter): Byte;
var i, p: Byte;
begin
	{ Заменяем все разделители пробелами }
	for i := 1 to Length(s) do
		if s[i] in delimiters then s[i] := #32;
		
	{ Удаляем лишние пробелы }
	repeat
		p := Pos('  ', s);			{ Здесь 2 пробела !!! }
		if p > 0 then Delete(s, p, 1);
	until p = 0;

	{ Удаляем пробел в начале строки }
	if s[1] = ' ' then
		Delete(s, 1, 1);
		
	{ Удаляем пробел в конце строки }
	If s[Length(s)] = ' ' then
		Delete(s, Length(s), 1);
		
	i := 0;
	{ Заполняем массив словами из строки }
	repeat
		p := Pos(' ', s); Inc(i);
		if p > 0 then begin
			mas[i] := Copy(s, 1, Pred(p)); Delete(s, 1, p)
		end
		else mas[i] := s;
	until p = 0;
		
	GetWords := i
end;

var
	i, count: Word;
	words: TWords;
		
{ Пример использования функции }
const
	s: string = ' That is   all folks ';
		
begin
	Count := GetWords(s, words, []);
	for i := 1 to Count do
		WriteLn(words[i]);
end.

Иногда может быть полезно вернуть список, а не массив слов, содержащихся в строке. Для этого можно воспользоваться вот такой модификацией:

type
	TWordStr = string[100];
	TDelimiter = set of Char;

	PTItem = ^TItem;
	TItem = 
	record
		Data: TWordStr;
		next: PTItem;
	end;

	TWordList = 
	record
		first, last: PTItem;
	end;

procedure InsertWord(var L: TWordList; s: string);
var p: PTItem;
begin
	New(p);
	p^.Data := s;
	p^.next := nil;
	
	if L.first = nil then L.first := p
	else L.last^.next := p;
		
	L.last := p
end;

function GetWords(s: string; var L: TWordList; delimiters: TDelimiter): Byte;
var i, p: Byte;
begin
	{ Заменяем все разделители пробелами }
	for i := 1 to Length(s) do
		if s[i] In delimiters then s[i] := #32;
			
	{ удаляем лишние пробелы }
	repeat
		p := Pos('  ', s);			{ Здесь 2 пробела !!! }
		if p > 0 then Delete(s, p, 1)
	until p = 0;
		
	{ Удаляем пробел в начале ... }
	if s[1] = ' '
		then Delete(s, 1, 1); 
	{ ... и в конце строки }
	if s[Length(s)] = ' '
		then Delete(s, Length(s), 1);
			
	i := 0;
	{ заполняем список словами из строки }
	repeat
		p := Pos(' ', s); Inc(i);
		if p > 0 then begin
			InsertWord(L, Copy(s, 1, Pred(p)));
			Delete(s, 1, p)
		end
		else InsertWord(L, s)
	until p = 0;
		
	GetWords := i
end;

{ пример использования функции }
const
	s: string = ' That is - all folks;;. ';
var
	i, count: Word;
	L: TWordList;
	p: PTItem;

begin
	Count := GetWords(s, L, ['-', ';', '.']);
	WriteLn(Count, ' words found ...');
		
	p := L.first;
	while p <> nil do begin
		WriteLn(p^.Data);
		p := p^.next;
	end;
end.

Другие способы разбиения строк на слова собраны вот в этой теме: Разбиение на слова. Все способы.