IPB
ЛогинПароль:

> DOS-скрипт для переименования фотоснимков, обмен опытом))
сообщение
Сообщение #1


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


Думал я, думал, куда сию диковину можно поместить, да так толком и не придумал. Ладно, кладу тут, в ОС и ПО. Типа это ПО от меня)). All Rights Reserved)). Можете использовать, дорабатывать, изменять, зарабатывать на ней мульены $, единственное условие: не использовать для разработки вирусов и спама lol.gif .

Так вот, я пробовал ее на 2000, XP, Vista, Windows 7 - везде идет, НО..

Но я пробовал только на американской винде, и я сильно подозреваю, что на другой локализованной версии она может не пойти. То есть сорее всего не пойдет((. Я готов сотрудничать с любым добрым челом, кто возьмется ее локализовать под Россию. Сам я этого сделать не могу по причине неимения русской винды.

Кроме того, требуется подстройка под разные цифровые камеры. В настоящий момент она распознает Olymous, Fuji, Samsung и Sony. Распознавание самое примитивное (не забывайте, что это всего лишь батник), на основе имени.

Теперь об использовании.
Сначала делаете отдельный каталог и скачиваете туда все картинки с вашей карты (CF, SD, MS, xD или что там у вас..). Желательно, чтоб в этом каталоге не было других файлов (распознавание может ошибиться). Сам скрипт может лежать в любой директории, к которой прописан путь. У меня он называется dc2pc (digital camera to PC), рекомендую использовать это же название. Запуск без параметров выдает подсказку:
Код
P:\pix\ak\09\e_may\17>dc2pc
  usage:   dc2pc suffix      - choose a descriptive and short enough "suffix"
     or:   dc2pc undo        - the undo file must exist
example:   dc2pc _Big-Ben_   - transferred to:   05h012_Big-Ben_001 ...
months marked with letters: a - January, b - February, .. , l - December

Параметр всего один - желаемый суффикс, полностью, например: _KateBirthd_ . Обратите внимание на символы подчеркивания, с ними удобнее читать название. Скрипт произведет поиск картинок и скажет результат, а также спросит, нужно ли продолжать:
Код
P:\pix\ak\09\e_may>dc2pc _test_
No pictures found

Либо:
Код
P:\pix\ak\09\e_may\17>dc2pc _test_
Found 27 Sony pictures.  Proceed? (Y/whatever) y

В процессе работы создается файл с информацией для UNDO. Если, например, вам не понравилось название, вы можете вернуть все назад:
Код
P:\pix\ak\09\e_may\17>dc2pc undo
Undoing dc2pc ...
                  ... done!  Check it and remove dc2pc.undo file

После этого желательно вручную удалить undu-файл.

Файлы называются такаим образом:

YYmDDsuffixNNN

YY - год, типа 09
m - месяц, латинская буква: a - январь, b - февраль ... k - ноябрь, l - декабрь.
DD - день, типа 25
suffix - то, что вы задали
NNN - номер. У меня пока больше 999 не было за один раз..))

Такое соглашение о наименовании очень эффективно. Сортировка по дате и номеру кадра обеспечена. Я использую ее много лет. Плюс к тому систему директорий, ессно, если интересно, могу подробнее.
Короче, получается примерно так:
Код
..                        │  Up  │06/01/09│03:35
09e17_test_001         JPG│2099 K│05/17/09│17:38
09e17_test_002         JPG│2154 K│05/17/09│17:38
09e17_test_003         JPG│2461 K│05/17/09│17:39
09e17_test_004         JPG│1749 K│05/17/09│17:39
09e17_test_005         JPG│1794 K│05/17/09│17:39
09e17_test_006         JPG│1656 K│05/17/09│17:39
09e17_test_007         JPG│2516 K│05/17/09│17:58
09e17_test_008         JPG│2807 K│05/17/09│17:59
09e17_test_009         JPG│2564 K│05/17/09│17:59
09e17_test_010         JPG│2715 K│05/17/09│17:59
09e17_test_011         JPG│2843 K│05/17/09│17:59
09e17_test_012         JPG│2430 K│05/17/09│17:59
09e17_test_013         JPG│2762 K│05/17/09│18:00
09e17_test_014         JPG│2954 K│05/17/09│18:00
09e17_test_015         JPG│2556 K│05/17/09│18:01
09e17_test_016         JPG│2478 K│05/17/09│18:01
09e17_test_017         JPG│2605 K│05/17/09│18:01
09e17_test_018         JPG│3424 K│05/17/09│18:06
09e17_test_019         JPG│3422 K│05/17/09│18:06
09e17_test_020         JPG│3419 K│05/17/09│18:06
09e17_test_021         JPG│3310 K│05/17/09│18:06
09e17_test_022         JPG│3120 K│05/17/09│18:06
09e17_test_023         JPG│3231 K│05/17/09│18:07
09e17_test_024         JPG│3298 K│05/17/09│18:07
09e17_test_025         JPG│3559 K│05/17/09│18:07
09e17_test_026         JPG│3189 K│05/17/09│18:07
09e17_test_027         JPG│3039 K│05/17/09│18:07
dc2pc                  tmp│  1080│06/01/09│03:35
dc2pc                 undo│   918│06/01/09│03:35


Забавно - вроде все и несложно, а инструкция вышла ого-го!))



Добавлено через 6 мин.
Классно - а сам скрипт забыл положить)).
Вот он:
dc2pc.bat
Код
@ECHO Off
rem     dc2pc
rem     Tool to rename files taken from digital camera
rem     Written by Lapp from ForumAllAboutPascal
rem     1.0, Jan 28/05
rem     1.1, May 04/05 multicamera support added

SET sign=dc2pc.sign
IF %6a==%sign%a GOTO loop3
IF %4a==%sign%a GOTO loop2
IF %3a==%sign%a GOTO loop1
IF %1a==a GOTO error
SET undo=dc2pc.undo
IF /I %1==undo GOTO undo
SET tmp=dc2pc.tmp
SET month=a b c d e f g h i j k l
IF EXIST %undo% GOTO :undoexists
SET suffix=%1
SET num=0
SET nn=0
SET found=0
CALL %0 Olympus p???????.* %sign%
IF %nn%==0 CALL %0 Fuji DSCF????.* %sign%
IF %nn%==0 CALL %0 Canon ???_????.* %sign%
IF %nn%==0 CALL %0 Samsung sd??????.* %sign%
IF %nn%==0 CALL %0 Sony DSC?????.* %sign%
IF %found%==0 ECHO No pictures found
GOTO end

:loop1
IF EXIST %tmp% DEL %tmp%
FOR %%i IN (%2) DO (
        ECHO %%i %%~xi %%~ti >> %tmp%
        SET /A nn=%nn + 1
)
IF %nn%==0 GOTO END
SET found=1
SET /P yn=Found %nn% %1 pictures.  Proceed? (Y/whatever)
IF /I %yn%a==ya (
        FOR /F "tokens=1-3" %%i IN (%tmp%) DO CALL %0 %%i %%j %%k %sign%
) ELSE SET nn=0
GOTO end

:loop2
SET /A num=%num% + 1
IF %num% LSS 10 (
        SET z=00
) ELSE IF %num% LSS 100 (
        SET z=0
) ELSE SET z=
FOR /F "tokens=1-3 delims=/" %%l IN ("%3") DO CALL %0 %1 %2 %%l %%m %%n %sign%
GOTO end

:loop3
IF %5 GEQ 2000 (
    SET /a year=%5 - 2000
) ELSE SET year=%5
IF %year% LSS 10 SET year=0%year%
SET /A mo=1%3-100
FOR /F "tokens=%mo%" %%o IN ("%month%") DO (
        ECHO %1 %year%%%o%4%suffix%%z%%num%%2 >> %undo%
        REN %1 %year%%%o%4%suffix%%z%%num%%2
)
GOTO end

:undo
IF EXIST %undo% (
        ECHO Undoing dc2pc ...
        FOR /F "tokens=1,2" %%i IN (%undo%) DO REN %%j %%i
        ECHO                   ... done!  Check it and remove %undo% file
) ELSE ECHO No undo file %undo% found!
GOTO end

:error
ECHO   usage:   dc2pc suffix      - choose a descriptive and short enough "suffix"
ECHO      or:   dc2pc undo        - the undo file must exist
ECHO example:   dc2pc _Big-Ben_   - transferred to:   05h012_Big-Ben_001 ...
ECHO months marked with letters: a - January, b - February, .. , l - December
GOTO end
:undoexists
ECHO undo file %undo% already exists!
:end

Enjoy, как грится! smile.gif


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
 
 Ответить  Открыть новую тему 
Ответов
сообщение
Сообщение #2


Профи
****

Группа: Пользователи
Сообщений: 930
Пол: Мужской

Репутация: -  11  +


Впечатления живого пользователя, не аникейщика, представляют большой научный и практический интерес.
Чем делался скриншот, фотоаппаратом? Если программой то соотношение высоты и ширины картинки такое же? Или на экране она растянута в ширину а на скрине нормальная. И как на ЖК панели хинты в таком разрешении не искажали буквы по сравнению со скриншотом? Скрин-то вроде идеальный. НО скрин не передаст как это пашет под линем, потому что в оригинальном разрешении 720х400 на црт мониторе левый край пикселя буквы раскрашен несколькими цветами, да и сеточка поверх наложена. Чтобы такое эмулировать на ЖК, их ресурсов никак не хватит - потребуется разрешение в десятки тысяч по горизонтали и вертикали smile.gif

>Может, там есть настройка разрешения?

Это же свободный софт, все нестандартные пожелания пользователя реализуются им лично путём правки исходника smile.gif А если серьёзно, и 800х600 отклонение от желаемого. Просто в свойствах экрана винды нет ни 720х400 ни 720х480 и выбрано меньшее зло. Прога-то создавалась по причине плохого запуска нортон командера в линуксе (для комфортного чтения фантастики и фентези, просмотра двоичных файлов) и воспроизводит в соответствии с новыми пожеланиями функции утилиты WPVIEW.EXE вместе с кусочком доса. Там миллионы цветов, но используются лишь 16 из тех что какими-либо ухищрениями можно получить в реальном досе. Образец шрифта получен сканированием скрина досовских символов 0-255. А поскольку в досе разрешение символов на экране 80х25 а символ 9х16 пикселей то и разрешение в идеале 720х400. То есть в глеаноре используемый шрифт определяет наилучшее разрешение smile.gif Нет шрифта который в разрешении 1920х1200 красиво сделает 25 строк по 80 символов, значит автор и не будет использовать такое разрешение smile.gif В будущем, когда среднего размера мониторов для ПК может и не быть, в программе может появиться эмуляция 17 дюймового монитора - нажал на кнопку и текст в прямоугольнике 16 дюймов а вокруг чёрная рамка. Может быть прямоугольник с текстом для удобства будет ездить по чёрному экрану. А вот когда (если) мониторы станут совсем крутыми можно будет полностью (смотри выше) эмулировать родное 720х400 со всей расцветкой пикселя. 21 век - высокие технологии)))
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #3


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


Цитата(SKVOZNJAK @ 3.06.2009 17:43) *
Чем делался скриншот, фотоаппаратом? Если программой то соотношение высоты и ширины картинки такое же? Или на экране она растянута в ширину а на скрине нормальная. И как на ЖК панели хинты в таком разрешении не искажали буквы по сравнению со скриншотом?
Скрин делался обычной клавишей print screen)). Естественно, пропорции на нем не сохранены. Растяни его по горизонтали до нужного аспект рейшио и увидишь, как он выглядел. Но обрати внимание на черную полосу справа. Все изображение занимало не весь экран, оставляя край справа. Это несколько улучшало ситуацию, но не до конца. Реальные размеры изображения (без черной полосы справа) были такие: 345 мм (это реальный размер монитора по вертикали) на 495 мм. Тем самым, аспект рейшио было 1.43, тогда как 800х600 это 1.33.

Что касается шрифта, никаких видимых деффектов я не заметил. Все нормально)).

Слушай, а я для чтения использую AlReader. Он идет на смартфонах и КПК. Про Линукс не знаю, но скорее всего нет.



--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 

Сообщений в этой теме
Lapp   DOS-скрипт для переименования фотоснимков   1.06.2009 17:51
SKVOZNJAK   Общего с досом скрипт имеет только синтаксис. Имен…   2.06.2009 10:45
Lapp   > Общего с досом скрипт имеет только синтаксис.…   2.06.2009 11:08
SKVOZNJAK   >у меня ничего русского под рукой, за каждой ме…   2.06.2009 11:37
Lapp   > Я же эзоповым языком ... да понл, понл..)) П…   2.06.2009 11:46
SKVOZNJAK   Цифровой камеры не держу, только вебкамеру (ей и ф…   2.06.2009 22:14
Lapp   Спасибо)). Да, суфикс задается параметром. Можно …   2.06.2009 23:10
SKVOZNJAK   [img]http://s50.radikal.ru/i128/0906/e0/d3fb347164…   3.06.2009 6:56
Lapp   Ну вот, это как раз то, что я предполагал..(( Я п…   3.06.2009 11:23
SKVOZNJAK   >Конечно, блажь все это, лучше взять и написать…   3.06.2009 12:34
Lapp   Это только в винде блажь а под никсами столько нав…   3.06.2009 13:47
Lapp   Забыл сказать: у меня тут стоит Windows 7 Ultimate…   3.06.2009 14:08
SKVOZNJAK   Впечатления живого пользователя, не аникейщика, пр…   3.06.2009 20:43
Lapp   Чем делался скриншот, фотоаппаратом? Если программ…   3.06.2009 21:32
SKVOZNJAK   >Но обрати внимание на черную полосу справа. Ч…   3.06.2009 22:09
Lapp   задумана разработчиком, надеюсь ты уже догадался к…   3.06.2009 22:46


 Ответить  Открыть новую тему 
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 





- Текстовая версия 28.03.2024 22:08
500Gb HDD, 6Gb RAM, 2 Cores, 7 EUR в месяц — такие хостинги правда бывают
Связь с администрацией: bu_gen в домене octagram.name