Движение табличек со словами, модуль graph Опции

[Провинциалка]

Здравствуйте ребята! Мне очень нужна помощь в написании данной программы в Паскаль. Помогите , пожалуйста, кто может.
Построить движущиеся изображения двух прямоугольников и круга, на которых помещены слова из фразы «КТО СКАЗАЛ МЯУ?»

[Lapp]

Здравствуйте ребята! Мне очень нужна помощь в написании данной программы в Паскаль. Помогите , пожалуйста, кто может.

Здравствуй, Оля. Мне тоже нужна помощь. Я уже замучился закрывать/переименовывать темы с совершенно УНИКАЛЬНЕЙШИМ и ОРИГИНАЛЬНЕЙШИМ (особенно для форума по Pascal и в разделе Pascal!) названием "Pascal". Пожалуйста, помоги мне - напряги свою фантазию в следующий раз (в этот раз я переименовал). Договорились?

Теперь по теме.
Вот, посмотри на этот код. Задавай вопросы, что неясно. А когда все выяснишь - займемся кружками.. Хорошо? ))

uses
  CRT,Graph,DOS;

const
  nTag=4;
  BkCol=0;
  qt=0.02;

type
  tShape= (Rect,Roun);
  tTag= record
    sh: tShape;
    c1,c2,c3,size: integer;
    x,y,vx,vy: single;
    s: string
  end;

function ScrX(x: single): integer;
begin
  ScrX:=Round(x*GetMaxX)
end;

function ScrY(y: single): integer;
begin
  ScrY:=Round(y*GetMaxY)
end;

procedure HideTag(Tag: tTag);
var
  i,j: integer;
begin
  with Tag do begin
    i:=ScrX(x);
    j:=ScrY(y);
    SetFillStyle(SolidFill,BkCol);
    SetTextStyle(0,HorizDir,size);
    Bar(i-1,j-1,i+size*4+TextWidth(s)+1,j+size*4+TextHeight(s)+1)
  end
end;

procedure ShowTag(Tag: tTag);
var
  i,j: integer;
begin
  with Tag do begin
    i:=ScrX(x);
    j:=ScrY(y);
    SetColor(c1);
    SetTextStyle(0,HorizDir,size);
    Rectangle(i,j,i+size*4+TextWidth(s),j+size*4+TextHeight(s));
    SetFillStyle(SolidFill,c3);
    Bar(i+2,j+2,i+size*4+TextWidth(s)-2,j+size*4+TextHeight(s)-2);
    SetColor(c2);
    OutTextXY(i+size*2,j+size*2,s)
  end
end;

function Timer: double;
var
  h,m,s,f: word;
begin
  GetTime(h,m,s,f);
  Timer:=(h*60+m)*60+s+f*0.01
end;

var
  t,t0,dt: double;
  gd,gm,i: integer;
  Tag: array [1..nTag] of tTag;
  ch: char;

begin
  t:=Timer;
  gd:=0;
  InitGraph(gd,gm,'');
  SetLineStyle(SolidLn,0,ThickWidth);
  Randomize;
  for i:=1 to nTag do with Tag[i] do begin
    sh:=Rect;
    x:=Random;
    y:=Random;
    size:=Random(7)+2;
    c1:=Random(7)+9;
    c2:=Random(7)+9;
    c3:=Random(6)+1;
    vx:=(Random-0.5)*0.4;
    vy:=(Random-0.5)*0.4;
    s:=Char(i+64)
  end;
  Tag[1].s:='Who';
  Tag[2].s:='did';
  Tag[3].s:='say';
  Tag[4].s:='meow?';
  repeat
    t0:=t;
    t:=Timer;
    dt:=t-t0;
    for i:=1 to nTag do with Tag[i] do begin
      HideTag(Tag[i]);
      x:=x+vx*dt;
      if (x<0)or(x>1) then begin
        if x<0 then x:=-x else x:=2-x;
        vx:=-vx;
      end;
      y:=y+vy*dt;
      if (y<0)or(y>1) then begin
        if y<0 then y:=-y else y:=2-y;
        vy:=-vy;
      end;
      ShowTag(Tag[i])
    end;
    repeat
      if KeyPressed then ch:=ReadKey
    until Timer-t>qt
  until ch=#27;
  while KeyPressed do ReadKey;
  CLoseGraph
end.

[Провинциалка]

Уважаемый Андрей!
Вы уж извините, что я не так оформила свою тему, но видит бог, я честное слово старалась. Видимо правила недопоняла.
За программу огромное спасибо!!! Честно скажу, для моего уровня знаний она построена на невероятно сложнейшем уровне. (Не пойму, почему на первом курсе дают такие сложные задания?)
Интересно, если ещё учесть, что нет одного кружочка со словом «МЯУ», программа ещё более усложнится или будет выглядеть по другому?
Вопросы по программе конечно же есть, но их слишком будет много, а я не хотела бы выглядеть глупой. Поэтому я лучше повнимательней почитаю тему по графике, а потом задам один-два вопроса.
Спасибо!!!

[Lapp]

Уважаемый Андрей!

Уважаемая Ольга! давай попроще, а?..

для моего уровня знаний она построена на невероятно сложнейшем уровне. (Не пойму, почему на первом курсе дают такие сложные задания?)

Да ну брось ты... чего тут сложного.. ))
Если будешь задавать вопросы - со всем разберешься.

Интересно, если ещё учесть, что нет одного кружочка со словом «МЯУ», программа ещё более усложнится или будет выглядеть по другому?

Когда ты разберешься - увидишь, что добавление другой формы впишется довольно логично и несложно. Но все же не в две строчки..

я не хотела бы выглядеть глупой.

Вот ЭТО и есть самая глупая фраза из возможных. Спрашивай все, даже если кажется глупым. Это единственный способ нормально чему-то научиться. Плюнь на все цацки-пецки..

Поэтому я лучше повнимательней почитаю тему по графике, а потом задам один-два вопроса.

Читать, конечно, можешь.. Но главное - нужно пробовать руками, экспериментировать.

В этой программе собственно графики не так уж и много. Только процедуры HideTag и ShowTag. Остальное - это общая логика. Попробуй ее разбить на блоки по назначению каждого.

ЛЮБУЮ непонятность - спрашивай (если не можешь найти ответа за 10 мин).

[Lapp]

Оль, и напиши, пожалуйста, каким компилятором ты пользуешься. Что у тебя - TurboPascal?
А компиляция моего кода прошла без проблем, все заработало?
Я не проверял под Турбо, все писал в FP.

[Провинциалка]

Господин администратор! Я постараюсь спросить обо всём, что мне непонятно, но пока я в некотором замешательстве (меня всё ещё трясёт, т.к. я не ожидала увидеть такое).
А в само название процедур HideTag и ShowTag вложен какой-то смысл (если да, то какой, а то у меня по учебной программе идёт немецкий язык)?
И ещё сразу вопрос: (не знаю как покорректней задать) этот вариант программы самый простой?
Да, установлен ТурбоПаскаль. С компиляцией всё в порядке, программа работает.

Сообщение отредактировано: Провинциалка - 12.12.2010 19:08

[Krjuger]

В названии процедур действительно очень часто закладывается смысл того,что они должны выполнять и обычно это делается английскими словами,чтобы большее число людей могли понять(имеются в виду люди не говорящие на русском,но знающие английский).В данном случае переменный несут смысл.show tag - показать обьект.Hide tag- спрятать обьект.Show hide это английские слова,а tag скорее всего сокращение от английского.Насчет простоты....это смотря что вкладывать в это слово.Программа написана грамотно(другие lapp не пишет),но здесь возникает вопрос смогли бы вы сами сотворить нечто подобное пусть даже с ошибками.Если нет,то программа сложная и в ней надо разбираться и заваливать lapp'a вопросами,а то потом вас могут обвинить в том ,что вы ее просто списали.

P.S.Вам сказали,что можно обращаться попроще.А то "уважаемый администратор",звучит, как призыв смертного к богам)))

[Lapp]

Господин администратор!

Как хотите, уважаемая мисс Ольга, можно и так )).

Я постараюсь спросить обо всём, что мне непонятно, но пока я в некотором замешательстве (меня всё ещё трясёт, т.к. я не ожидала увидеть такое).

Я вас хорошо понимаю. Но мы приложим все усилия для преодоления трудностей - так ведь?

А в само название процедур HideTag и ShowTag вложен какой-то смысл (если да, то какой, а то у меня по учебной программе идёт немецкий язык)?

Да, как уже сказал Krjuger. Постарайтесь запомнить эти два слова Hide (хайд), что значит скрывать или прятать, и Show (шоу) - показывать. Эти слова обычно употребляются при написании графических программ. Слово Tag (таг) означает "ярлык" (например, price tag - ценник на товаре в магазине). Мне показалось, что это слово хорошо подходит для того, что требуется в программе. Как вы считаете? Но вы можете заменить все идентификаторы (названия переменных) на другие (например, немецкие, а также русские, написанные латиницей), которые вам нравятся. Желательно давать в меру простые, ясные и говорящие за себя названия (не правда ли, похоже на проблему с названием тем на форуме?)).

И ещё сразу вопрос: (не знаю как покорректней задать) этот вариант программы самый простой?

Вот скажите: как проще есть - руками или вилкой? Маугли из джунглей скажет, что руками. А вы, думаю, скажете, что вилкой )). А вот в программировании вы пока и есть тот самый Маугли. А моя задача - научить вас есть вилкой )). Не знаю, ответил ли я на ваш вопрос, но боюсь, что однозначного ответа (да - нет) просто не существует.

Да, установлен ТурбоПаскаль. С компиляцией всё в порядке, программа работает

Это хорошо. Но я бы все же рекоменодовал вам установить FreePascal (http://freepascal.org). Он внешне очень похож на ТР, но при этом НАМНОГО лучше во многих других отношениях. Установочный файл весит что-то около 32 МБ. Если ваше соединение позволит, сделайте это, пожалуйста (можете рассматривать как одолжение мне)).
Всего доброго, уважаемая мисс Ольга.

P.S.
прошу прощения за задержку с ответом.. Поскольку я пишу из США, время дня и ночи у нас сильно разнится. Пожалуйста, учитываейте это в общении. Но вообще, я надеюсь, что мне помогут..

[Провинциалка]

Здравствуйте уважаемые!
Я очень внимательно прочитала все ваши отзывы и пожелания. Премного благодарна! Да…мне есть над чем поработать, а то уж очень не хочется быть похожей на Маугли. Как я уже говорила, буду очень стараться , все ночи – мои! (Днём дети отвлекают)
Я оказывается сильно отстала от жизни – даже не знала, что существует еще и FP, весящий 32 мБ. (Меня просто распирает от нетерпения поскорее узнать чем он лучше обычного TurboPascal). Думаю скорости 1мБит/сек мне хватит.
А по поводу вашего проживания в США – вы меня просто убили. Очень впечатляет. Сочувствую. Надеюсь вы там по своей воле оказались.
До свидания.

[Lapp]

Здравствуйте, мисс Ольга!

уж очень не хочется быть похожей на Маугли.

Ну, почему же? В чем-то он не так уж и плох, мне кажется.. У него тоже наверняка есть, чему поучиться. Просто еда вилкой - не его конек )). Я не думал, что этот образ окажется для вас таким отталкивающим..

буду очень стараться , все ночи – мои! (Днём дети отвлекают)

Гм. Но спать все же надо..
Ваше желание стараться очень обнадеживает (лишь бы не впустую..) Дети? Ну, вот подучите предмет - и сделаете для них игрушку. Будут меньше отвлекать )).

Тут я еще, возможно, должен исправиться.. Может, мне надо сменить обращение на Mrs.? Или, лучше просто Ольга? Прошу прощения, _тут_ к студентам и школьникам принято обращаться официально: мисс, мистер, сэр.. На форуме же я обычно "тыкаю" по свойски. Но вы задали несколько необычный тон, и я в растерянности..

Я оказывается сильно отстала от жизни – даже не знала, что существует еще и FP, весящий 32 мБ.

Это не вы, это ваши преподаватели отстали от жизни (и неслабо так).. Размер же я немного округлил - он весит 37.8 МБ на самом деле. Скачивайте версию 2.4.2 для Win32.

(Меня просто распирает от нетерпения поскорее узнать чем он лучше обычного TurboPascal)

Бальзам на измученное сердце форумского админа.. Неужели есть студенты (-тки), которым не все равно, что там есть? И вообще - надо ли кому-то что-то лучшее, чем лапти? ))
Turbo Pascal потерял свою актуальность около 15 лет назад (что в терминах IT-индустрии = вечность). Я не понимаю, как можно до сих пор строить на нем программу обучения. Вот короткий перечень переимуществ FP: 32/64-битность, много/кросс-платформенность, достаточно большое разнообразие библиотек, постоянная обновляемость, бесплатность. Последнее не всегда есть преимущество, ибо бесплатный софт часто плохо обновляется, но тут не тот случай. Вдобавок, можно не краснеть всякий раз (как при старте ТР, который до сих пор платный). Далее, нужно сказать, что в ТР графика не идет на Windows Vista и 7, а на 64-разрядных системах он вовсе не запускается.
Достаточно ли вам этих преимуществ для перехода на FP?

. Думаю скорости 1мБит/сек мне хватит.

Должно.

А по поводу вашего проживания в США – вы меня просто убили. Очень впечатляет. Сочувствую. Надеюсь вы там по своей воле оказались.

Хм.. Сочувствовать мне не надо, мне здесь достаточно хорошо. Безусловно, по своей - как могло быть иначе??

Итак, уважаемая Ольга, давайте перейдем к делу.
Вы хотели "попроще"? Что ж, это разумно. Давайте начнем с самого простого.

Следующая программа двигает одну точку по экрану (слева направо, сверху вниз) - самое простое, что я смог придумать.

{ graphic motion, 02 }

uses
  WinCRT,          // WinCRT для FP, CRT для TP
  Graph;

var
  gd,gm,x,y,i,j: integer;

begin
  gd:=0;                          // задаем автоматическое определение граф.параметров
  InitGraph(gd,gm,'');            // инициализировать графику
  x:=0;                           // задаем начальные координаты точки
  y:=0;
  repeat                          // цикл отрисовки
    PutPixel(x,y,Black);            // стереть точку
    Inc(x);                         // перейти к соседней точке справа
    if x>GetMaxX then begin         // если зашли за край, то ..
      x:=0;                           // .. перейти к началу экрана ..
      Inc(y);                         // .. и на следующую строку
      if y>GetMaxY then y:=0          // если экран закончился, перейти снова вверх
    end;
    PutPixel(x,y,White);            // нарисовать точку в новой позиции
    Delay(100);                     // подождать некоторое время (можно изменять число)
  until KeyPressed;               // выход из цикла отрисовки по нажатии любой клавиши
  while KeyPressed do ReadKey;
  CloseGraph                      // закрываем графику
end.

Я снабдил программу комментариями. Они поясняют, что делает каждый оператор. Но эти комментрарии в стиле языка С. Они очень удобные (все, что после // до конца строки - комментарий). Компилятор FP их понимает, но TP - нет. Это еще один повод переходить на FreePascal. Но если вы все же захотите компилировать этот код с помощью TP, либо переделайте комментарии на исконно паскалевские, {...}, либо просто удалите их.

После того, как вы разберетесь с этой простейшей программой, продвинемся дальше. Завайте теперь двигать (аналогичным образом) некотороый текст. Какие изменения нужно сделать в нашей программе? Заменить вывод/стирание точки (PutPixel, ПутПиксел) на вывод/стирание текста. Я подготовил код со всеми нужными (и не очень) изменениями (помимо описанных выше, я еще поменял скорость движения, разберитесь с этим, пожалуйста).

// graphic motion, 02

uses
  WinCRT,Graph;

var
  gd,gm,x,y,i,j: integer;

begin
  gd:=0;
  InitGraph(gd,gm,'');
  x:=0;
  y:=0;
  repeat
    SetColor(Black);                  // устанавливаем цвет текста (черный)
    OutTextXY(x,y,'Hi!');             // стираем текст (пишем его черным)
    Inc(x,10);                       // увеличиваем позицию x на 10
    if x>GetMaxX then begin
      x:=0;
      Inc(y,50);
      if y>GetMaxY then y:=0
    end;
    SetColor(White);                  // устанавливаем цвет (белый)
    OutTextXY(x,y,'Hi!');             // печатаем текст
    Delay(30);                        // ждем..
  until KeyPressed;
  while KeyPressed do ReadKey;
  CloseGraph
end.

Все вопросы, которые у вас возникнут (даже самые "глупые"), приносите сюда, пожалуйста. Не должно остаться ничего неясного.

[Провинциалка]

Здравствуйте!
(Вы уж Извините, что захожу сюда редко, сейчас очень напряженный темп начался в конце учебного семестра и время для общения нахожу как правило только ночью.)
Хочу сказать Огромное спасибо за ваше внимание!
Побольше бы таких людей как вы на на земле, и мир наверное был бы другим.
Из вас, как мне кажется, вышел бы отличный и всеми уважаемый преподаватель. Жаль что у нас таких нет.
Вы знаете, Андрей, давайте так: вы ко мне на ты, а я к вам на вы. Очень уж большое уважение вызывает у меня к вам уровень вашего интеллекта и профессионализма. Вообщем я просто Оля, а вы – уважаемый администратор.
Free Pascal я скачала и установила. Работает нормально.
То что графика в ТР не идет на Windows Vista и 7 – это ужас конечно, но пока для меня это не актуально, т.к. у меня стоит ХР SP2. Хотя надо признаться, что уже не раз были мысли о переходе на Windows 7. Я правильно поняла, что на семёрке FP работает без проблем?
В данный момент углубленно изучаю ваши программы.
Как только появятся вопросы я их непременно задам.
Всего доброго.

[Lapp]

Free Pascal я скачала и установила. Работает нормально.

Очень хорошо, молодец, так всем будет проще. Но если сдавать программы нужно будет все же на ТР (да?), то придется их перед сдачей "причесывать". А может, и при написании учитывать.. Но это не проблема.

То что графика в ТР не идет на Windows Vista и 7 – это ужас конечно, но пока для меня это не актуально, т.к. у меня стоит ХР SP2. Хотя надо признаться, что уже не раз были мысли о переходе на Windows 7. Я правильно поняла, что на семёрке FP работает без проблем?

Как рыба в воде - и на 32 бита, и на 64.

Как только появятся вопросы я их непременно задам.

Успехов ).

Учти - чтобы KeyPreesed и ReadKey в FP работали в граф-окне, нужно CRT заменить на WinCRT.

[Провинциалка]

Уважаемый администратор!
У меня наконец-то появилось немного времени, чтобы напомнить о себе, и задать вам несколько вопросов по Паскалю. Хочу сказать, что я наконец-то разобралась (как мне кажется) с теми примерами, которые вы мне дали для тренировки, но есть вопросы по второму примеру (с текстом). Позвольте их задать.
1) Переменные gd и gm – как их лучше назвать по-русски?
2) Для чего при объявлении переменных указаны i и j , если они не используются в тексте программы?
3) Почему в строке InitGraph(gd,gm,'') после gm идут апострофы, а не путь ‘\TP\graph’ ?
4) Как понять смысл цикла: while KeyPressed do ReadKey (в конце текста)?
В остальном мне всё понятно.
Спасибо!

[Lapp]

Уважаемый администратор!

Послушай, я пошел тебе навстречу. Сделай и ты маленький шажок. Тут так не принято. И вообще - обращайся ко всем, а не ко мне одному. Это форум.

1) Переменные gd и gm – как их лучше назвать по-русски?

GraphDriver и GraphMode. Графический драйвер и графическая мода.

2) Для чего при объявлении переменных указаны i и j , если они не используются в тексте программы?

Наверное, рудименты. Я, наверное, брал старый код и выбрасывал лишнее. Возможно, выбросил не все. Удали.

3) Почему в строке InitGraph(gd,gm,'') после gm идут апострофы, а не путь ‘\TP\graph’ ?

Пустая строка означает, что надо брать из дефолтного пути.

4) Как понять смысл цикла: while KeyPressed do ReadKey (в конце текста)?

Это сброс буфера клавиатуры. Если было больше, чем одно нажатие, надо все сбросить перед выходом. Такая ситуация возможна, если нажали стрелку или F-клавишу - они генерируют по 2 кода. Вообще, об этом обычно никто не заботится (после меня - хоть потоп).

ты экспериментируй. Пробуй. Изменяй код и смотри, что получается (например, с теми i и j). Давай, жду еще вопросов.

[Провинциалка]

Многое стало ясно!
А дефолтный путь это что?
Я попробовала убрать while KeyPressed do ReadKey - ничего не изменилось.

И ещё: мне как лучше поступать при получении сообщения - нажимать Быстрый ответ, Ответить или Открыть новую тему? (раз я должна обращаться ко всем)

[Lapp]

А дефолтный путь это что?

Ну какой-то там путь по умолчанию, где оно обычно валяется..

Я попробовала убрать while KeyPressed do ReadKey - ничего не изменилось.

Да, в среде ничего и не увидишь. Но подобные вещи - признак того, что ты заботишься о других. Это как задвинуть стул в столовой, когда встанешь.

И ещё: мне как лучше поступать при получении сообщения - нажимать Быстрый ответ, Ответить или Открыть новую тему? (раз я должна обращаться ко всем)

Обычно отвечают НА кокой-то пост. При этом нажимают на ОТВЕТИТЬ в этом посте. Если ты хочешь ответить на несколько постов - нажми во всех на +ЦИТАТА (она покраснеет), а потом на ОТВЕТИТЬ, которое в самом низу (рядом с быстрым ответом).

Быстрый ответ действительно быстрее выходит обычно, но в нем нет цитат. Открывать новую тему нужно только когда ты действительно завершила эту и хочешь начать новую. Короче, как тебе удобнее. Поэкспериментируй )).

[Провинциалка]

Теперь мне ничего не остаётся, как засыпать вас вопросами по самой первой программе (та, которую вы написали мне в самом начале нашего общения).
Буду их тихонько подготавливать