Дано условие:
Вводится последовательность слов. Определите, какое количество слов потребуется, чтобы задействовать все буквы английского (русского) алфавита. Ввод слов оканчивается, когда задействованы все буквы.

Я только не могу понять - Вводится последовательность слов - это кем должно вводиться последовательность, мной в самом коде или пользователем? Помогите разобраться

Да уж наверное пользователем

Я тоже так думаю...

Что такое слово и как оно вводится?

Вот решения (для английского алфавита), но оно имеет глюк: без этой строки

alph[0]:=chr(26);

переменной alph не присваивается значений
Почему?

uses crt;
var alph:string; s:string;
    i,j,n:byte;
    f: set of 'a'..'z';
begin
clrscr;
f:=['a','b','c','d','e','f','g','h','i','j','k','l','m','n','o','p','q','r','s','t','u','v','w','x','y','z'];
n:=0;
alph:='';
j:=0;
writeln('Enter the words');
s:='';
alph[0]:=chr(26);
repeat
      readln(s);
      for i:=1 to length(s) do
          begin
               if (s[i] in f) and (pos(s[i],alph)=0) then
                  begin
                       inc(j);
                       alph[j]:=s[i];
                  end;
          end;
      inc(n);
until j>=26;
writeln('Number : ',n);
readln;
end.

Вот тебе еще одна причина не пользоваться грязным хаком

При работе со строками никогда не прикасайся к нулевому символу !!! В FPC, например, такая программа откажется компилироваться...

Покажи мне в своей программе, где ты заполняешь строку alph значениями? Вот это:

alph[j]:=s[i];

- не в счет, здесь ты меняешь какой-то определенный символ, а это не совсем корректно (с учетом того, КАК ты в начале изменил длину строки)...

Насколько я вижу, правильным вариантом будет такой:

uses crt;
var
  alph:string; s:string;
  i,j,n:byte;
  f: set of 'a'..'z';
begin
  clrscr;
  f:=['a','b','c','d','e','f','g','h','i','j','k','l','m','n','o','p','q','r','s','t','u','v','w','x','y','z'];
  n:=0;
  alph:='';
  j:=0;
  writeln('Enter the words');
  s:='';
  // alph[0]:=chr(26);
  repeat
      readln(s);
      for i:=1 to length(s) do begin
         if (s[i] in f) and (pos(s[i],alph)=0) then begin
            // inc(j);
            // alph[j]:=s[i];
            alph := alph + s[i]; // Эквивалентная замена, но корректная !!!
         end;
      end;
      inc(n);
  until j>=26;
  writeln('Number : ',n);
  readln;
end.

(Не тестировал, но по-моему, должно работать)

Большое спасибо за объяснение Не первый раз делаю такую ошибку, теперь
наконец-то понял из-за чего она возникает...

until j>=26;

Так как убрана переменная j, то надо поминять и цикл...

until length(alph)>=26;

По идее, раз задание на множества, то и делать надо через множества, примерно вот так:

type sett=set of 'a'..'z';
var f,z:sett;
i:integer;
c:char;
s:string;
begin
for c:='a' to 'z' do f:=f+[c];
repeat
readln(s);
for i:=1 to length(s) do z:=z+[s[i]];
until f-z=[];
end.