Дан массив записей, содержащих дату (число, месяц, год) и время (час, минута, секунда). Упорядочить этот массив в порядке «возрастания», т.е. от более ранних значений к более поздним.
Я её сделал я её сделал полным переборам всех дат(перевести в секунды у меня не получилось, в проблеме не далекого ума) только она выдаёт новый массив с записями не так как надо(пропадают некоторые даты) найдите ошибку и напишите пожалуйста какже всётаки правильно сделать!

type
Data = record
Year: integer;
Month: 1..12;
Day: 1..31;
Hour: 0..11;
Minute: 0..59;
Second: 0..59;
end;
var
dat:Data;
a:array [1..20] of data;
i,j,t,k:integer;
c:data;
begin
   with dat do
   for i:=1 to 20 do
   begin
   randomize;
   a[i].Year:=random(random(3))+2006;
   a[i].Month:= random(random(11))+1;
   a[i].Day:= random(30)+1;
   a[i].Hour:= random(11)+1;
   a[i].Minute:= random(58)+1;
   a[i].Second:= random(58)+1;
   end;
   writeln('DO':20,'POSLE':45);
   for i:=1 to 19 do
   begin
   write('Den ',a[i].Day:2,',','mesiac ',a[i].Month:2,',God ',a[i].Year:4,
      ' Vremya:',a[i].Hour:2,':',a[i].Minute:2,':',a[i].Second:2,'      ');
   for j:=20 downto i do
   begin
   if a[i].year>a[j].year then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end else
   if a[i].year=a[j].year then
   if a[i].month>a[j].month then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end else
   if a[i].month=a[j].month then
   if a[i].day>a[j].day then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end else
   if a[i].day=a[j].day then
   if a[i].hour>a[j].hour then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end else
   if a[i].hour=a[j].hour then
   if a[i].minute>a[j].minute then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end else
   if a[i].minute=a[j].minute then
   if a[i].second>a[j].second then
   begin
   c:=a[i];
   a[i]:=a[j];
   a[j]:=c;
   end;
   end;
   write('Day ',a[i].Day:2,',',a[i].Month:2,',',a[i].Year:4,' vremya:',
      a[i].Hour:2,':',a[i].Minute:2,':',a[i].Second:2);
   writeln;
   end;
 readln;
end.

Например, так:

type
  Data = record
    Year: integer;
    Month: 1..12;
    Day: 1..31;
    Hour: 0..11;
    Minute: 0..59;
    Second: 0..59;
  end;

function F(value: Data): longint;
begin

  with value do
    F := (((((year - 2000) * 12 + month) * 31 + day) * 24 +
           hour) * 60 + minute) * 60 + second;

end;

var
  a: array [1..20] of data;
  indexes: array[1 .. 20] of integer;
  i, j, T: integer;

begin
   randomize;
   for i:=1 to 20 do begin
     a[i].Year:=random(random(3))+2006;
     a[i].Month:= random(random(11))+1;
     a[i].Day:= random(30)+1;
     a[i].Hour:= random(11)+1;
     a[i].Minute:= random(58)+1;
     a[i].Second:= random(58)+1;

     indexes[i] := i;
   end;

   { Bubble sort }
   for i := 1 To 20 Do
     for j := 20 DownTo i+1 Do
       if F(a[indexes[j - 1]]) > F(a[indexes[j]]) then begin
         T := indexes[j - 1]; indexes[j - 1] := indexes[j]; indexes[j] := T
       end;

   writeln('DO':20,'POSLE':45);
   for i := 1 to 20 do begin
     with a[i] do
       write(Day:2, '/', Month:2, '/', Year:4, ' - ',
             Hour:2, ':', Minute:2, ':', Second:2, '      ');
     with a[indexes[i]] do
       write(Day:2, '/', Month:2, '/', Year:4, ' - ',
             Hour:2, ':', Minute:2, ':', Second:2);
     writeln;
   end;
   readln;
end.