Будьте так добры. Используя директиву absolute, создать построчно с помощью
подпрограммы матрицы 5х5 и 2х3.

И в чем конкретно проблема?

проблема в том что я не понимаю какую функцию будет выполнять эта директива в программе и с чем она будет работать. если она совмещает адрес локальной переменной с адресом нетипизированного параматра то что и с чем она должна совмещать? помогите, оч нужна ваша помощь)

Если честно, я тоже не вполне понимаю. Задавая вопрос, я надеялся прояснить - но фиг. Я попытался придумать несколько схем с использованием absolute, но они все сильно притянуты за уши.. По всей видимости, тут не хватает какой-то ценной информации, которую ты недоговариваешь (надеюсь, не нарочно)). Попробуй "вспомнить все" (С) . Любая мелочь может оказаться полезной.
Например, почему именно такие размеры - 5х5 и 2х3? и ты не сказала, какой тип элементов.. И почему именно построчно? Тут чувствуются какие-то намеки, но я не улавливаю их пока..
Откуда задача? Может, просто более точное воспроизведение условия поможет?
Попробуй нарыть еще хоть что-то.

вроде прогу написала, вот что вышло

program matr;
procedure MatrA(var z);
var 
       MasA:array [1..5,1..5] of integer absolute z;
       i,j:integer;
begin
  for  i:=1 to 5 do
  for j:=1 to 5 do
  MasA[i,j]:=Random(10);
  for i:=1 to 5 do
   begin
    for j:=1 to 5 do
    write(masA[i,j], '  ');
end;
end;
procedure MatrB(var t);
var
     MasB:array [1..2,1..3] of integer absolute t;
     i,j:integer;
begin
   for  i:=1 to 2 do
   for j:=1 to 3 do
   MasB[i,j]:=Random(10);
   for i:=1 to 2 do
    begin
     for j:=1 to 3 do
     write(MasB[i,j] , '  ');
end;
end;
var 
     x:array [1..5,1..5] of integer;
     y:array [1..2,1..3] of integer;
begin
  writeln('matrix A 5*5');
  writeln('----------------------------');
  MatrA(x);
  writeln('matrix B 2*3');
  writeln('----------------------------');
  MatrB(y);
  readln
end.

Добавлено через 4 мин.
она работает)мне преподаватель задал на защиту переделать ее, чтобы подпрограмма только создавала матрицу, а выводила ее основная программа. помогите пожалуйста к завтрашнему дню)

М

Тэги!

дождинка, я искренне удивлен: если ты сама написала прогу, неужели тебе трудно переставить печать из процедуры в основную часть?..

Впрочем, посмотрев код, я понял, что имел в виду твой преподаватель.. Неправильно это - создавать отдельную процедуру для каждого размера. Вот тебе код, разбирайся. Тут одна процедура для создания матрицы и одна для печати. Размеры матрицы передаются в параметрах.

program Matrix;

procedure FillMatrix(var Matrix; n,m: integer);
var
  x: array [1..$7FF0] of integer absolute Matrix;  {примерно максимальный размер массива в TP/BP}
  i,j: integer;
begin
  for  i:=1 to n do
    for j:=1 to m do
      x[(i-1)*m+j]:=Random(10)   {вручную пересчитываем индексы}
end;


procedure ShowMatrix(var Matrix; n,m: integer);
var
  x: array [1..$7FF0] of integer absolute Matrix;
  i,j: integer;
begin
  for i:=1 to n do begin
    for j:=1 to m do write(x[(i-1)*m+j]:4);
    WriteLn
  end
end;


var
  A: array [1..5,1..5] of integer;
  B: array [1..2,1..3] of integer;

begin
  writeln('matrix A 5*5');
  writeln('----------------------------');
  FillMatrix(A,5,5);
  ShowMatrix(A,5,5);
  WriteLn;
  writeln('matrix B 2*3');
  writeln('----------------------------');
  FillMatrix(B,2,3);
  ShowMatrix(B,2,3);
  readln
end.

нет, мне вовсе нетрудно было скопировать. к тому же я так и делала, но если бы у меня все работало, разве я к вам бы обратилась? тоже логику иметь надо. и еще. было же сказано, чтобы матрицы выводила основная программа, зачем создавать еще одну процедуру?? а про единственную подпрограмму создания матрицы спасибо. сама это поняла, но слишком поздно к сожалению. и почему вы так любите эту универсальность! я видимо вижу только то что на поверхности, а вы вглубь смотрите. все равно спасибо за ответ, хотя он мне ничем не помог.

Да, логика безупречная. Жаль только, одноуровневая..

Она и выводит. Видела вызовы? Смысл в том, чтобы избавить процедуру, заполняющую матрицы, от ЛИШНЕЙ функциональности. Как организовать вывод - через процедуру или нет - не важно. Важно, чтобы иметь возможность это делать ОТДЕЛЬНО от заполнения. Не надо соединять функциональность с интерфейсом - это разные вещи, рано или поздно возникнет необходимость заполнить матрицу без вывода. Сейчас вывод делается в основной программе - хотя, ессно, посредством подпрограммы. Не путай категории "где" и "как". Вставь вызов процедуры Show в процедуру Fill - все, ты снова получишь старую ситуацию.

Ты молодец.

Все программирование ЕСТЬ универсальность. Остальное - калькулятор.

стараемся..

Он помог тебе, я это вижу. Не надо только относиться к помощи слишком меркантильно. Спасибо и тебе - я всегда рад учится от общения с людьми.

Оффтоп: дождинка, оставь свой сарказм и говори по-человечески. И, когда говоришь на форуме, будь готова, что люди будут не просто точно отвечать на твои вопросы, как первачки учителке. И постарайся видеть в ответах больше, чем кажется на первый взгляд. А если что непонятно - спрашивай дальше.
Успехов тебе.

спасибо за адекватный ситуации ответ) все ясно и понятно

Гуд )). Заходи еще.