Форум «Всё о Паскале» > Удаление N столбцов из матрицы

Помощь - Поиск - Пользователи - Календарь

Полная версия: Удаление N столбцов из матрицы

Форум «Всё о Паскале» > Pascal, Object Pascal > Задачи

Hindelberg

29.10.2005 18:14

Задача: Удалить все столбцы в двумерном массиве где есть нули.

Я хотел сделать программу с помощью процедуры.

Код

Procedure DEL(k1:integer);
Begin
for j:=k1-z to m-1-z do
for i:=1 to n do
mas[i,j]:=mas[i,j+1];
for i:=1 to m do
mas[i,m-z]:=0;
z:=z+1;
end;

Где n- кол-во строк, m- столбцов.
k1- стролбец который надо удалить.

Проблема- не удается сделать корректную проверку на наличие нуля в столбце и вызов процедуры. Удаляются не все столбцы.

Если возможно помогите с циклом обработки!

volvo

29.10.2005 18:25

Hindelberg,
как именно задана матрица, и что значит "удалить" столбцы? Это не всегда возможно, так что полный "код - в студию!" (С)

Hindelberg

29.10.2005 19:26

Удалить.. Например, было:

1 2 4 1
1 0 5 8
1 3 0 4

Результат:

1 1
1 8
1 4

Код

uses crt;
const n=10;
m=10;
var mas:array[1..n,1..m] of integer;
i,z,j,k1:integer;
ps:boolean;

Procedure DEL(k1:integer);
Begin
for j:=k1-z to m-1-z do
for i:=1 to n do
mas[i,j]:=mas[i,j+1];
for i:=1 to m do
mas[i,m-z]:=0;
z:=z+1;
end;

BEGIN
randomize;
clrscr;
z:=0;
for i:=1 to n do
begin
for j:=1 to m do
begin
mas[i,j]:=random(10);
write(mas[i,j]:3);
end;
writeln;
end;

for j:=1 to m do
begin
ps:=true;
for i:=1 to n do
if mas[i,j]=0 then ps:=false;

if ps=false then
Del(j); {Вот в это месте я и застрял, понимаю, что здесь надо что-то кроме j, но
вот что-не доходит/не получается}
end;

{Далее просто вывести матрицу но у нее будет (m-сколько раз удаляли) столбцов}
END.

volvo

29.10.2005 19:51

Я немного подкорректировал твою программу. Если что непонятно, спрашивай

uses crt;
const
  n=10;
  m=10;

var
  mas:array[1..n,1..m] of integer;
  i, j: integer;

  has_zero, m_count: integer;

Procedure Del(k1: integer);
var i, j: integer;
Begin

  for i := 1 to n do
    for j := k1 to m_count - 1 do
      mas[i, j] := mas[i, j+1];

end;

BEGIN
  randomize;
  clrscr;

  writeln(' before: ');
  for i:=1 to n do begin
    for j:=1 to m do begin
      mas[i,j]:=random(10);
      write(mas[i,j]:3);
    end;
    writeln;
  end;

  m_count := m;
  j := 1;
  while j <= m_count do begin

    has_zero := 0;
    for i := 1 to n do
      if mas[i,j]=0 then inc(has_zero);

    if has_zero > 0 then begin
      del(j); dec(m_count);
    end
    else
      inc(j);
  end;

  writeln(' after: ');
  for i:=1 to n do begin
    for j:=1 to m_count do
      write(mas[i,j]:3);
  writeln;
end;

END.

Hindelberg

29.10.2005 21:04

Спасибо большое за столь быстрый ответ! Все понял!

Это текстовая версия — только основной контент. Для просмотра полной версии этой страницы, пожалуйста, нажмите сюда.