Помощь - Поиск - Пользователи - Календарь
Полная версия: Задача. Указатели
Форум «Всё о Паскале» > Pascal, Object Pascal > Задачи
Killer
24.12.2005 21:08
Подскажите пожалуйста как написать вот эту программу БЕЗ использования МАССИВОВ...
Код

program test;
uses crt;
type id_node=^node;
     node=record
     x:integer;
     next:id_node;
     end;

var
i,max,n:integer;
nach,tek,temp:id_node;
f:TEXT;
posl:array [0..1000] of integer;
begin
clrscr;

writeln('LabRab 10, variant 9');
writeln;

i:=0; write('Datum order: ');
assign(f,'input.txt'); reset(f);
repeat read(f,posl[i]); write(posl[i],' '); i:=i+1; until (posl[i-1]=0);
close(f); n:=i;

writeln; write('Numbers of greatest elements: '); max:=posl[0];
for i:=1 to n-1 do if posl[i]>max then max:=posl[i];
for i:=0 to n-1 do if posl[i]=max then write(i+1,' ');

new(nach); tek:=nach;
for i:=0 to n-1 do
    if posl[i]<>max then
       begin
            tek^.x:=posl[i];
            if posl[i]<>0 then begin new(tek^.next); tek:=tek^.next; end
        else tek^.next:=NIL;
       end;

writeln; write('One-way list without greatest elements : ');
tek:=nach;
repeat write(tek^.x,' '); tek:=tek^.next; until tek=NIL;

readkey;
end.
volvo
24.12.2005 21:20
Ты бы задание привел, было бы проще...
Killer
24.12.2005 22:30
Дана непустая последовательность натуральных чисел, за которой следует 0. Напечатать порядковые номера тех чисел последовательности, которые имеют наибольшую величину, и удалить эти элементы.
Сформировать односвязный список и вывести на печать полученную информацию согласно варианту
Гость
25.12.2005 14:08
Уважаемый Volvo, отзовитесь...
volvo
25.12.2005 14:53
Ну, вот так, например:
type
  plist = ^tlist;
  tlist = record
    info: integer;
    next: plist;
  end;

var
  p, r, first, last: plist;
  X, max: integer;


begin
  first := nil; last := nil;

  repeat

    write('next number = '); readln(X);
    if X <> 0 then begin
      new(p);
      p^.info := x;
      p^.next := nil;

      if first = nil then first := p
      else last^.next := p;

      last := p
    end;

  until X = 0;

  max := 0;
  writeln('print list:');
  p := first;
  while p <> nil do begin
    write(p^.info:4);

    if p^.info > max then max := p^.info;

    p := p^.next;
  end;
  writeln;
  writeln('max = ', max);

  X := 1;
  p := first;
  while p <> nil do begin
    if p^.info = max then write('#':3, X);
    p := p^.next; inc(X);
  end;
  writeln;

  { Deleting max }
  p := first;
  while p <> nil do begin
    if p^.info = max then begin

      r := p^.next;
      p^ := r^;
      dispose( r );
      r := nil

    end;
    p := p^.next;
  end;

  writeln('print list:');
  p := first;
  while p <> nil do begin
    write(p^.info:4);
    p := p^.next;
  end;
  writeln;

end.
Гость
25.12.2005 15:00
Спасибо Большое за помощь, Volvo.
Гость
25.12.2005 15:05
dispose®;
Это опечатка ?
volvo
25.12.2005 15:09
Это не я, это форум smile.gif ... Просто ( r ) без пробелов записывается как ®... Исправлено...
Гость
25.12.2005 15:10
Я так и понял smile.gif
Еще раз спасибо за помощь...
Гость
25.12.2005 15:27
Volvo
Честное слово неловко, но кажется программа работает некорректно, при первом запуске все нормально, но потом появляются проблемы в виде ошибки 204:Invalid pointer operation и к примеру вводим последовательность 12330
порядковые номера наибольших чисел 3 и 4, но вот на печать выводится результат 123, а должно быть по идее 12...
Гость
25.12.2005 15:28
А вводим к примеру 1234440 - ошибка 204
volvo
25.12.2005 15:39
Насчет
Цитата
к примеру вводим последовательность 12330
порядковые номера наибольших чисел 3 и 4, но вот на печать выводится результат 123, а должно быть по идее 12...
- согласен, недосмотрел... А вот
Цитата
204:Invalid pointer operation
ни разу поймать не удалось... Напиши при каких входных значениях она возникает... И что значит
Цитата
при первом запуске все нормально, но потом появляются проблемы
? 2 раза подряд запускаешь НЕизмененную программу и она первый раз работает нормально, а второй раз делает проблемы?

Вот немного измененная версия:
type
  plist = ^tlist;
  tlist = record
    info: integer;
    next: plist;
  end;

var
  p, r, first, last: plist;
  X, max: integer;


begin
  first := nil; last := nil;

  repeat

    write('next number = '); readln(X);
    if X <> 0 then begin
      new(p);
      p^.info := x;
      p^.next := nil;

      if first = nil then first := p
      else last^.next := p;

      last := p
    end;

  until X = 0;

  max := 0;
  writeln('print list:');
  p := first;
  while p <> nil do begin
    write(p^.info:4);

    if p^.info > max then max := p^.info;

    p := p^.next;
  end;
  writeln;
  writeln('max = ', max);

  X := 1;
  p := first;
  while p <> nil do begin
    if p^.info = max then write('#':3, X);
    p := p^.next; inc(X);
  end;
  writeln;

  { Deleting max }
  while first^.info = max do begin
    p := first;
    first := first^.next;
    dispose(p);
  end;

  p := first;
  while p^.next <> nil do begin
    if p^.next^.info = max then begin

        r := p^.next;
        p^.next := r^.next;
        dispose( r );
        r := nil

    end
    else
    p := p^.next;
  end;

  writeln('print list:');
  p := first;
  while p <> nil do begin
    write(p^.info:4);
    p := p^.next;
  end;
  writeln;

end.
Гость
25.12.2005 15:50
Все OK
Работает без сучка и задоринки
Спасибо !
Это текстовая версия — только основной контент. Для просмотра полной версии этой страницы, пожалуйста, нажмите сюда.