Очередь, Задача с тремя конвейерами Опции

[БелАчкА]

Задача такая:

Имеются три конвейера. Конвейеры работают независимо друг от друга. Изначально на первом конвейере располагаются детали N типов, а второй и третий – пусты. Время обработки детали каждого типа с каждого конвейера задается матрицей Time[1..N, 1..3]. После обработки детали с конвейера k она поступает на конвейер k+1. Деталь после третьего конвейера считается изготовленной. Требуется по начальному расположению деталей на первом конвейере определить время, через которое все детали будут изготовлены.

Помогите, пожалуйста, понять хотя бы алгоритм решения: вообще не могу разобраться , где здесь используется очередь и как, собственно, высчитывается само время обработки.

[Lapp]

БелАчкА, чтобы лучше разобраться, просто представь себя тем человеком, который следит за конвеерами (я прошу прощения за орфографию, правильно писать "конвейер", но у мя рука не поворачивается такое уродство изображать..) и перекладывает детали с одного К на другой, когда они готовы. Что он делает? Он кладет деталь на конвеер, смотрит в табличку, сколько времени она будет обрабатываться и отмечает это время у себя в блокноте (контрольная точка, КТ). И так с каждым конвеером. Потом идет спать, а будильник заводит на ближайшую КТ.

Дальше зависит от реализации. Если он вместе с КТ отметил и номер конвеера, то он идет прямо к нужному конвееру. Если же он отметил просто время, то он проверяет все конвееры по очереди, начиная с первого, выискивая тот, у которого КТ совпадает с текущим временем. Находит, перекладывает деталь на следующий конвеер (или кладет на склад готовых деталей) и смотрит, есть ди детали в очереди для этого конвеера. Если есть, то загружает его следующей деталью и передвигает его КТ. Так он обходит все К в этот момент, а потом снова идет спать до следующей ТК. Я предпочел второй способ. Первый кажется эффективнее - попробуй его реализовать.

Вот и все . Непыльная работенка. А ты у него ее отбираешь, заменяешь машиной...

Я добавил наглядный вывод всего процесса с использованием псевдографики. Как только его увидишь, все станет понятно . Но при его использовании нужно задавать времена только целыми (я имею в виду, без дробей). Это в принципе не запрещается алгоритмом, но псевдографика не сдюжит..

Еще одно замечание. Эта программа неправильно обрабатывает ситуацию, когда время обработки какой-то детали на одном из конвееров нулевое. Но тут нужно уточнить услови - можно ли сразу перепрыгивать через такой конвеер на следующий (это приведет к изменению порядка следования деталей, что, как мне кажется, не страшно) или нужно все-таки выстоять очередь на нем.

Выкладываю вторую версию .
1. Исправлена ошибка, замеченная тобой выше.
2. Выкинута переменная Work (она не нужна, если начальные КТ задать отрицательными).
3. Добавлены комментарии.
4. Добавлена псевдографика, которая наглядно представляет процесс.

Вот, на всякий случай, еще один входной файл, побольше:

Код

5             number of lines
8             number of details
3 2 3 2 1     matrix TDK (time-detail-konv)
2 1 1 3 5
5 2 1 2 1
2 1 5 4 1
5 2 1 3 4
4 1 5 1 1
6 2 1 2 2
8 5 5 4 1
1 2 3 5 8 6 1 7  input line (left to right)

- который выдает такой результат:

Код

T=  47.000
aaabbccccceeeeehhhhhhhhffffaaagggggg
---aab----cc---ee------hhhhhf-aa----gg
-----aaab---c----e----------hhhhhfffffaaag
--------aabbbcc---eee------------hhhh-f--aagg
----------a--bbbbbc--eeee------------h-f---a-gg

- тут четко видно продвижение каждой детали (буква) по конвеерам.

Ну, и сама прога:

//real time multy-line processing model
//by Lapp for Belachka
//Version 2

type
  tContent=integer;
  tpCell=^tCell;
  tCell=record
    c:tContent;
    p:tpCell
  end;
  tFifo=record
    i,o:tpCell
  end;

procedure Fifo(var b:tFifo);
begin
  b.i:=nil;
  b.o:=nil
end;

procedure Put(var b:tFifo; c:tContent);
begin
  with b do if i=nil then begin
    New(i);
    o:=i
  end
  else begin
    New(i^.p);
    i:=i^.p;
    i^.p:=nil
  end;
  b.i^.c:=c
end;

function Get(var b:tFifo; var c:tContent):boolean;
var
  p:tpCell;
begin
  with b do if o=nil then Get:=false
  else begin
    c:=o^.c;
    p:=o^.p;
    if o=i then i:=nil;
    Dispose(o);
    o:=p;
    Get:=true
  end
end;

const
  Mk=10;         //максимум конвееров (К)
  Md=28;         //максимум деталей
  e=1e-5;        //погрешность сравнения

var
  i,j,Nd,Nk,Dd:integer;
  T,T1:real;                     //реальное время
  TDK:array[1..Md,1..Mk]of real; //матрица времен обработки
  Tk:array[1..Mk]of real;        //контрольные точки (КТ) всех К
  d:array[1..Mk]of integer;      //детали в обработке в наст. время
  K:array[1..Mk]of tFifo;        //очереди ожидания К
  f:text;

var              //переменные для псевдографики
  x:integer;     //можно убрать их, а потом убрать все строчки,
  s:array[1..Mk]of string;       //где ругается компилятор


begin
  Assign(f,'Ford.txt');
  Reset(f);
  ReadLn(f,Nk);
  for i:=1 to Nk do Fifo(K[i]);
  ReadLn(f,Nd);
  for j:=1 to Nd do begin
    for i:=1 to Nk do Read(f,TDK[j,i]);
    ReadLn(f)
  end;
  for j:=1 to Nd do begin
    Read(f,i);
    Put(K[1],i)
  end;
  Close(f);
  T:=0;                          //время начинается с нуля
  for i:=1 to Nk do Tk[i]:=-0.1; //все конвееры к началу уже пустые некоторое время
  Dd:=0;                         //обнуляем конечный результат
  repeat                         //вперед по времени по КТ
    for i:=1 to Nk do begin      //цикл по конвеерам в каждой КТ
      //если время совпадает с КТ, значит на этом конвеере
      //закончилась обработка текущей детали.
      //для всех, кроме последнего, перекладываем деталь в очередь следующего К
      //для последнего просто увеличивает Dd
      if (Abs(T-Tk[i])<e) then if i<Nk then Put(K[i+1],d[i]) else Inc(Dd);
      //если К свободен, взять деталь из очереди (если там есть что-то)
      if (T>=Tk[i]-e) and Get(K[i],d[i]) then begin
        for x:=Round(Tk[i]) to Round(T)-1 do s[i]:=s[i]+'-';       //псевдографика
        //отметить КТ для этого К, как время окончания обработки детали
        Tk[i]:=T+TDK[d[i],i];
        for x:=1 to Round(TDK[d[i],i]) do s[i]:=s[i]+Char(96+d[i]) //псевдографика
      end
    end;
    //найти максимальную КТ
    //это можно заменить просто на T1:=<very_large_value>
    for i:=1 to Nk do if T1<Tk[i] then T1:=Tk[i];
    //найти минимальную КТ, бОльшую текущего времени (т.е. следующую)
    for i:=1 to Nk do if (T<Tk[i]) and (Tk[i]<T1) then T1:=Tk[i];
    //продвигаем текущее время вперед
    T:=T1
  until Dd=Nd;    //до тех пор, когда будут обработаны все детали
  WriteLn('T=',T:8:3);     //вывод полного времени
  for x:=1 to Nk do WriteLn(s[x]);    //вывод псевдографики
  ReadLn
end.