операции со знаками Опции

[maksimla]

6 задание
Арифметическое значение a О b О c О d О e = r операции в знаках закрыты. Тут можно будет использовать здоровых чисел операций + , - ,* , div, mod.

Напишите правильную программу которая нашла бы какие должны быть операций знаках чтобы уравнение было бы правильное.

Первичные данные записаны в файле duom.txt На одной единственной строчке написаны отделенные пробелом здоровые числа a, b, c, d, e, r (a, b, c, d, e, r ≤ 3000).

Результат - полученое значение или слово - нельзя - записываются в файл rez.txt. Все элементы отделены одним пробелом.

Внимание Промежуточных подсчета результатов непереходят int64 .
первичные данные
4 3 2 3 1 6
результат
4 mod 3 + 2 * 3 – 1 = 6
Что еще за тип int64?
тут как то примерно как и в этом задание задача подсчет чтобы то число найти

[Lapp]

Вот возможное решение.

const
  nPar=5;
  nOper=5;
  Opers: array[0..nOper-1]of string=('+','-','*','div','mod');

var
  Par,Par0: array[0..nPar-1]of Int64;
  Oper,Oper0: array[0..nPar]of word;
  i,m: word;
  r,r0,t: Int64;
  f: text;

begin
  Assign(f,'duom.txt');
  ReSet(f);
  for i:=0 to nPar-1 do Read(f,Par0[i]);
  Read(f,r0);
  Close(f);
  for i:=0 to nPar do Oper0[i]:=0;
  m:=0;
  repeat
    Par:=Par0;
    Oper:=Oper0;
    for i:=1 to nPar-1 do case Oper[i] of
      2: begin
        Par[i]:=Par[i-1] * Par[i];
        Par[i-1]:=0;
        Oper[i]:=Oper[i-1]
      end;
      3: begin
        Par[i]:=Par[i-1] div Par[i];
        Par[i-1]:=0;
        Oper[i]:=Oper[i-1]
      end;
      4: begin
        Par[i]:=Par[i-1] mod Par[i];
        Par[i-1]:=0;
        Oper[i]:=Oper[i-1]
      end
    end;
    r:=Par[0];
    for i:=1 to nPar-1 do case Oper[i] of
      0: r:=r+Par[i];
      1: r:=r-Par[i]
    end;
    if r=r0 then begin
      Write(Par0[0]);
      for i:=1 to nPar-1 do Write(' ',Opers[Oper0[i]],' ',Par0[i]);
      WriteLn(' = ',r);
      Inc(m)
    end;
    t:=1;
    for i:=1 to nPar do begin
      t:=Oper0[i]+t;
      Oper0[i]:=t mod nOper;
      t:=t div nOper
    end
  until Oper0[nPar]=1;
  WriteLn(m,' combinations found')
end.

Максим, ты спрашивай поактивнее, что неясно.