Работа с записью в файлы, циклы, сравнение., Укажите на мою ошибку Опции

[Bulkin]

Всем привет!
Есть условия:
В один файл (F) пишем 5 чисел. В другой (G) другие 5 чисел. Пример: 12345 и 34567

Потом читаем их из этих файлов и ищем совпадения, те которые совпали пишем в файл (H1) которые не совпали пишем в другой файл (H2).

Мой результат: в H1 пишет цифру 1, в H2 34567.

Где я ошибься!?

Тело программы:

Program Zapis_i_chtenie;
uses crt;
var
    n,i:integer;
    fs,gs:integer;
    f,g,h1,h2:text;
begin
writeln('Vvedite 5 cyfr dlya F: ');
assign(f,'d:\f.txt');
rewrite(f);
append(f);
for i:=1 to 5 do
    begin
         write('->');
         readln(n);
         writeln(f,n);
    end;
close(f);
Writeln('Vvedite 5 cyfr dlya G: ');
assign(g,'d:\g.txt');
rewrite(g);
append(g);
for i:=1 to 5 do
    begin
         write('->');
         readln(n);
         writeln(g,n);
    end;
close(g);
assign(f,'d:\f.txt');
assign(g,'d:\g.txt');
assign(h1,'d:\h1.txt');
assign(h2,'d:\h2.txt');
reset(f);
reset(g);
rewrite(h1);
rewrite(h2);
while not EOF(f) do
      begin
          Readln(f,fs);
      begin
         while not EOF(g) do
        begin
           Readln(g,gs);
           if fs=gs
           then writeln(h1,gs)
           else writeln(h2,gs);
        end;
        end;
        end;
close(f);
close(g);
close(h1);
close(h2);
end.

Сообщение отредактировано: Bulkin - 24.11.2010 14:30

[Lapp]

Потом читаем их из этих файлов и ищем совпадения, те которые совпали пишем в файл (H1) которые не совпали пишем в другой файл (H2).
...
Где я ошибься!?

Много, где.

Смотри, я даю тебе прогу, исправленную НАПОЛОВИНУ.

Program Zapis_i_chtenie;
uses crt;
var
    n,i:integer;
    fs,gs:integer;
    f,g,h1,h2:text;
    b: boolean;
begin
  writeln('Vvedite 5 cyfr dlya F: ');
  assign(f,'f.txt');
  rewrite(f);
  for i:=1 to 5 do
      begin
           write('->');
           readln(n);
           writeln(f,n);
      end;
  close(f);
  Writeln('Vvedite 5 cyfr dlya G: ');
  assign(g,'g.txt');
  rewrite(g);
  for i:=1 to 5 do
      begin
           write('->');
           readln(n);
           writeln(g,n);
      end;
  close(g);
  assign(h1,'h1.txt');
  assign(h2,'h2.txt');
  reset(f);
  rewrite(h1);
  rewrite(h2);
  while not EOF(f) do begin
    Readln(f,fs);
    reset(g);
    b:=true;
    while b and not EOF(g) do begin
      Readln(g,gs);
      if fs=gs then begin
        b:=false;
        writeln(h1,gs)
      end
    end;
    if b then writeln(h2,fs)
  end;
  close(f);
  close(g);
  close(h1);
  close(h2);
end.

Существенно:
- добавлена булева переменная b (разбирешься, зачем?)
- reset(g) переставлен внутрь цикла

Несущественно:
- убраны ненужные append и лишние assign, а также begin и end

Эта прога пишет все, что нужно в файл H1. Но в файл H2 она пишет только те несовпавшие числа, которые были в файле f. Остается добавить еще один цикл, тоже двойной. В нем только два отличия от того, что есть.
1. надо поменять местами файлы f и g (g - во внешнем цикле, f - во внутреннем).
2. выкинуть запись в файл h1

В промежутке между этими циклами файл H2 не трогай (не открывай заново). Файл H1 можешь закрыть совсем, он уже готов.