Задачи с матрицами, Задача по замене злементов матрицы Опции

[Dead.MorozZ]

Помогите с задачкой справиться PlzZ:
1. Заменить
 Минимальный элемент в каждой строке на противоположный по знаку;
 Все элементы первых трех столбцов на их квадраты;
 Все симметричные элементы квадратной матрицы на нули.
2. Поменять местами
 Средние столбцы;
 Средние строки с первой и последней;
 Средние столбцы со вторым и предпоследним;
 Средние строки;
 Первый максимальный и последний минимальный элементы;
 В каждой строке первый отрицательный и последний положительный;
 Первую строку и строку, в которой находится первый нулевой элемент;
 Вторую и предпоследнюю строки;
 Первую строку с последней строкой, вторую – с предпоследней и так далее;

[volvo]

как в твоей проге одновременно менять местами и столбы и строки??

Гораздо проще, чем кажется:

const
 size_row = 10; { число строк }
 size_col = 10; { число столбцов }

type { это - матрица из строк }
 tvector = array[1 .. size_col] of integer;
 tVecmatrix = array[1 .. size_row] of tvector;

{ меняем строки местами }
procedure swap_rows(var mx: tVecmatrix;
         const i, j: integer);
 var T: tvector;
 begin
   T := mx[i]; mx[i] := mx[j]; mx[j] := T
 end;

type { это - матрица из столбцов }
 trow = array[1 .. size_row] of integer;
 tRowmatrix = array[1 .. size_col] of trow;

{ меняем столбцы местами }
procedure swap_cols(var mx: tRowmatrix;
         const i, j: integer);
 var T: trow;
 begin
   T := mx[i]; mx[i] := mx[j]; mx[j] := T
 end;

{ печатаем (матрицу СТРОК !!!) }
procedure print(var mx: tVecmatrix);
 var i, j: integer;
 begin
   for i := 1 to size_row do
     begin
       for j := 1 to size_col do
         write(mx[i][j]:4);
       writeln
     end;
 end;

{ преобразуем матрицу строк -> матрицу столбцов }
procedure convert_vr(mv: tVecmatrix; var mr: tRowmatrix);
var i, j: integer;
begin
  for i := 1 to size_row do
    for j := 1 to size_col do
      mr[j, i] := mv[i, j];
end;
{ обратное преобразование }
procedure convert_rv(mr: tRowmatrix; var mv: tVecmatrix);
var i, j: integer;
begin
  for i := 1 to size_row do
    for j := 1 to size_col do
      mv[i, j] := mr[j, i];
end;


var
 mx: tVecmatrix;
 mr: tRowmatrix; { для промежуточных вычислений }
 i, j: integer;

begin
 for i := 1 to size_row do
   for j := 1 to size_col do
     mx[i][j] := random(100); { заполняем матрицу }

 writeln('before:'); print(mx); { начальная матрица }

 swap_rows(mx, 1, 5); { меняем 1 и 5 СТРОКИ местами }

   convert_vr(mx, mr); { преобразуем в матрицу столбцов }
   swap_cols(mr, 1, 5); { меняем местами 1 и 5 столбцы }
   convert_rv(mr, mx); { и возвращаем назад -> матрицу строк }

 writeln('after:'); print(mx); { полученная матрица }
end.