Задача на стеки, ... Опции

[KoKa]

Здравствуйте...
Помогите решить задачку...


- Формируются два стека, нужно чтобы значения 2 стека присвоились 1, таким образом чтобы 1 стек получился таким - 1 эл 1 стека, 1 эл 2 стека, 2 эл 1 стека... то есть поочередным =)
Решить нужно не через массив
Через массив я решил... а вот через динамику ни могу
Заранее спасибо

[volvo]

Старая добрая рекурсия:

{ Собственно реализация стека }
type
  pstack = ^tstack;
  tstack = record
    info: integer;
    next: pstack;
  end;

procedure print(s: pstack);
begin
  while s <> nil do begin
    write(s^.info:6); s := s^.next;
  end;
  writeln
end;

procedure push(var s: pstack; x: integer);
var p: pstack;
begin
  new(p);
  p^.next := s; p^.info := x;
  s := p;
end;

function empty(s: pstack): boolean;
begin
  empty := (s = nil);
end;

function pop(var s: pstack): integer;
var T: pstack;
begin
  if empty(s) then pop := -1
  else begin
    pop := s^.info;
    T := s; s := s^.next;
    dispose(T);
  end
end;


const
  len = 3;
var
  ist, ist2: pstack;
  i: integer;

var
  flag: boolean;

{
  Вот та процедура, которая тебе нужна !!!
}
procedure convert(was_s1, was_s2: integer);
var w_1, w_2: integer;
begin
  if not flag then begin
    w_1 := pop(ist); w_2 := pop(ist2);
    if empty(ist2) then flag := true;
    convert(w_1, w_2);
  end;
  push(ist, was_s2);
  push(ist, was_s1);
end;

begin
  ist := nil; ist2 := nil;

    for i := 1 to len do
      push(ist, 12*i);
    print(ist);
    for i := 1 to len do
      push(ist2, 3*i);
    print(ist2);

    flag := false;
    convert(pop(ist), pop(ist2));
    print(ist);
end.