Помогите решить!(матрицы и массивы в одной задаче), Сижу на экзамене Опции

[АноНим]

Дана матрица чисел(n x n)
Создать массив строк (n),содержащих слова:"отрицат." "положит." "ноль".
Если в строке все числа отрицательны,положительны,или нули соответсвенно.
В противном случае записать слово:"Неопределенн.".Использовать процедуры.

[klem4]

Ну держи, если еще не поздно ...

const
   n = 4;
type

   TArr = array [1..n] of string;
   TMx  = array [1..n,1..n] of integer;

procedure Input(var mx : TMx);
var
   i,j : byte;
begin
   for i := 1 to n do
    for j := 1 to n do begin
      write('mx[',i,',',j,']=');
      readln(mx[i,j]);
    end;
end;

procedure PrintMX(mx : TMx);
var
   i,j : byte;
begin
   for i := 1 to n do begin
     writeln;
     for j := 1 to n do write(mx[i,j] : 3,' ');
   end;
end;

procedure PrintArr(arr : TArr);
var
   i : byte;
begin
   for i := 1 to n do writeln(arr[i]);
end;

function Sign(T : integer) : integer;
begin
   Sign := 0;
   if T > 0 then Sign := 1
    else
    if T < 0 then Sign := - 1
end;

procedure CheckRow(mx : TMx; row : byte; var st : TArr);
const
   _pos : string = 'Положительные';
   _neg : string = 'Отрицательные';
   _zer : string = 'Нулевые';
   _udf : string = 'Неопределенные';
var
   i : byte;
begin
   i := 1;
   while (i <= n-1) and (Sign(mx[row,i]) = Sign(mx[row,succ(i)])) do inc(i);
   if i = n then
    case Sign(mx[row, 1]) of
      1 : st[row] := _pos;
      0 : st[row] := _zer;
      -1: st[row] := _neg;
    end
   else st[row] := _udf;
end;

procedure Work(var mx : TMx; var st : TArr);
var
   k : byte;
begin
   for k := 1 to n do CheckRow(mx, k, st);
end;

var
   m : TMx;
   s : TArr;
begin
   clrscr;
   Input(m);
   PrintMx(m);
   writeln;
   Work(m, s);
   PrintArr(s);
   readln;
end.

[Гость]

clrscr;
[Error] ProjectXXX.dpr(78): Undeclared identifier: 'clrscr'
[Warning] ProjectXXX.dpr(86): Text after final 'END.' - ignored by compiler
Чё делать??