ввод с клавы только цифр и вопросик о Eoln Опции

[DFooz]

Какими способами можно ограничить ввод с клавиатуры только цифр?
Я пробую таким, но наверняка есть способ проще и лучше=)

Код

Var
  k:Char;
  st:String;

Begin
  Repeat
      k:=ReadKey;
      If k in ['0'.. '9'] then          
        begin
          st:=st+k;
          Write(k);
        end
      Else if (ord(k)) = 8 then
        begin
          delete(st, length(st), 1);
          GotoXY(1,WhereY);
          ClrEOL;
          Write(st);
        end
    Until k = #13;
END.

второй вопросик
если напр. написать этот код, то пишутся на экране только цифры

Код

Repeat
      k:=ReadKey;
      If k in ['0'.. '9'] then  
        begin
          st:=st+k;
          Write(k);
        end
    Until [b]k = #13[/b];
  END.

если же вместо k = #13 написать EOLN, то на экране появляются также буквы. Почему? Знаю, что EOLN писать здесь неправильно, но просто интересно, почему на экране пишутся буквы?

Сообщение отредактировано: DFooz - 12.03.2006 15:38

[volvo]

наверняка есть способ проще и лучше

Я пользуюсь вот таким:

uses crt;

function get_digits: string;
var s: string; ch: char;
begin
  s := '';
  repeat
    ch := readkey;
    case ch of
      #8:
      begin
        if length(s) > 0 then begin
          write(#8,#32,#8);
          delete(s, length(s), 1)
        end
      end;

      '0' .. '9':
        begin s := s + ch; write(ch) end
    end;
  until ch = #13;
  writeln;
  get_digits := s
end;

var
  s: string;

begin
  { ... }
  s := get_digits;
  { ... }
end.

если же вместо k = #13 написать EOLN

А вот этого делать не стоит:

Более того, от EoLn без параметра не дождетесь значения False. Она "Подвешивает" программу и возвращает управление следующему оператору только после нажатия ввода...

Так что эта функция тут неприменима вообще...