Опять же графика!, Сохранение изображения Опции

[-=АнЮтА=-]

Пы талась проявить фантазию, но очень осторожно и с переменным успехом. Хочу так сохранить рисунок по кускам, но в два разных файла. Из одного файла прочитать оба кусочка записанных боюсь мозгофф пока не хватит. Не могу сообразить где ошибка, может стоит с разными переменными попробовать? Если тока один кусочек копировать - работает, размер кусочка проверяла - меньше 64 кб. Подскажите пожалуйста
Написала такую процедуру:

Procedure Copy_image;
    var size:word;
        buffer,:pointer;
        f:file;
begin
        size:=imagesize(200,20,400,220);  {копирую первый кусочек}
        getmem(buffer,size);
        getimage(200,20,400,220,buffer^);
        assign(f,'pic.dat');
        rewrite(f,size);
        blockwrite(f,buffer^,1);
        close(f);

        size:=imagesize(400,220,630,435);     {копирую второй}
        getmem(buffer,size);
        getimage(400,220,630,435,buffer^);
        assign(f,'pic1.dat');
        rewrite(f,size);
        blockwrite(f,buffer^,1);
        close(f);

        assign(f,'pic.dat');                    {воспроизвожу первый}
        reset(f,1);
        getmem(buffer,filesize(f));
        blockread(f,buffer^,filesize(f));
        close(f);
        putimage(200,20,buffer^,normalput);

        assign(f,'pic1.dat');                     {  воспроизвожу второй}
        reset(f,1);
        getmem(buffer,size);
        blockread(f,buffer^,filesize(f));
        close(f);
        putimage(400,220,buffer^,normalput);
             end;

[Lapp]

Я немного подкорректировал (добавил freemem и разбил процедуру на две) - и у меня все получилось.
Больших изменений не вносил.

uses
  Graph;

var
	gd:integer=vga;
	gm:integer=vgahi;

Procedure WriteImage;
    var size:word;
        buffer:pointer;
        f:file;
begin
        size:=imagesize(0,0,99,99);  {копирую первый кусочек}
        getmem(buffer,size);
        getimage(0,0,99,99,buffer^);
        assign(f,'pic.dat');
        rewrite(f,size);
        blockwrite(f,buffer^,1);
        FreeMem(buffer);
        close(f);

        size:=imagesize(100,100,199,199);     {копирую второй}
        getmem(buffer,size);
        getimage(100,100,199,199,buffer^);
        assign(f,'pic1.dat');
        rewrite(f,size);
        blockwrite(f,buffer^,1);
        FreeMem(buffer);
        close(f);
end;


Procedure ReadImage;
    var size:word;
        buffer:pointer;
        f:file;
begin
        assign(f,'pic.dat');                    {воспроизвожу первый}
        reset(f,1);
        size:=FileSize(f);
        getmem(buffer,Size);
        blockread(f,buffer^,filesize(f));
        close(f);
        putimage(100,0,buffer^,normalput);
        FreeMem(buffer);

        assign(f,'pic1.dat');                     {  воспроизвожу второй}
        reset(f,1);
        size:=FileSize(f);
        getmem(buffer,Size);
        blockread(f,buffer^,filesize(f));
        close(f);
        putimage(0,100,buffer^,normalput);
        FreeMem(buffer);
end;

begin
  InitGraph(gd,gm,'');
  Line(0,0,200,200);
  Line(200,0,0,200);
  WriteImage;
  ReadLn;
  ClearDevice;
  ReadLn;
  ReadImage;
  ReadLn;
end.

Да, еще размер картинки уменьшил - она все же была очень большая...