Задачи на знание ООП, (только для Турбо-Паскаля 7.0) Опции

[Алена]

Честно говоря не понимаю почему так.

Потому, что этот вариант некорректен по определению. Если бы ты компилировал ЭТО в FPC, например, то получил бы Error 216 или AV. Почему?

А кто тебе сказал, что

getmem(p,sizeof(ob));

инициализирует указатель нулем? Ты что, переопределял где-то HeapFunc? По умолчанию GetMem возвращает ненулевой указатель на выделенную область памяти, а при нехватке памяти инициирует RunTime Error, то есть, корректно получить указатель равный Nil с ее помощью - проблематично.

Если TP "замалчивает" ошибку - это еще не значит, что ее нет. Насколько я знаю, эта тема как раз и создавалась для того, чтобы научить избегать подобных ошибок, а не делать их преднамеренно. Есть гораздо более корректный и красивый способ сделать то, что требовалось по условию.

[Bokul]

type
  pT = ^T;
  T = object
  end;

  pTT=^TT;
  TT=object(T)
  end;

procedure X(const the_pointer: pT);
begin
  if the_pointer=nil then writeln('not assigned');
end;

var
  p: ^TT;
  mem:longint;
begin
  mem:=memavail;
  new(p);
  X(p);
  writeln('Difference: ',mem-memavail);
  readln;
end.

[volvo]

Не пойдет... Имелся в виду другой способ... А теперь - о природе данного вопроса, почему собственно я его задал, хотя, казалось бы, предыдущий вопрос еще не решен окончательно? А вот почему. Я как раз это и хотел выяснить, знаешь ли ты, что при таком вызове

X(new(pT, Init));

в процедуру может передаваться NIL (и в каком именно случае это происходит)? Оказалось, что не знаешь... Вот отсюда и вытекает одна из проблем, с которой ты столкнулся в предыдущей задачке, решать которую тебе пришлось "костылями"...

Теперь, с подсказкой, КАК вызывать процедуру, сможешь написать код, который делает то, что требовалось?

[Bokul]

знаешь ли ты, что при таком вызове

X(new(pT, Init));

в процедуру может передаваться NIL (и в каком именно случае это происходит)? Оказалось, что не знаешь...

Даже хуже - я не понимаю почему... Ведь если есть конструктор, должно быть и поле виртуальных методов, а значит размер объекта в куче будет не нулевым. Тогда как new может вернуть nil?

Теперь, с подсказкой, КАК вызывать процедуру, сможешь написать код, который делает то, что требовалось?

Не понял, о каком коде идет речь?

[volvo]

Не понял, о каком коде идет речь?

О том коде, при добавлении которого в программу (и вызове процедуры так, как я показал), получим сообщение "not assigned"... По умолчанию ты его не получишь, нужно кое-что сделать дополнительно...

Даже хуже - я не понимаю почему...

Вот-вот... Я догадался, в чем проблема... А раз ты не понимаешь почему это происходит, то, само собой, не проверяешь и такой возможности, что при выделении памяти под объект "на лету" тебе может вернуться нулевой указатель... Может... Дело все в том, что Constructor - это не совсем простая процедура... Это, скорее, даже не процедура, а функция... И она может возвращать True/False для статических объектов и Nil/{указатель_на_объект} для динамических...

[Bokul]

И она может возвращать True/False для статических объектов и Nil/{указатель_на_объект} для динамических...

Ха, действительно так Никогда не встречал информации об этом. В каких ситуациях Constructor будет возвращать False, True? Какие преимущества дает использование конструктора для статических объектов?

О том коде, при добавлении которого в программу (и вызове процедуры так, как я показал), получим сообщение "not assigned"..

Условие менялось и, чтобы не возникло путаницы переспрошу - с такой процедурой?

procedure X(const the_pointer: pT);
begin
  if the_pointer=nil then writeln('not assigned');
end;

[volvo]

Вот с таким:

procedure X(const the_pointer: pT);
begin
  if not assigned(the_pointer) then writeln('not assigned');
end;

Аленка была абсолютна права, я сразу просто забыл поставить not, она же мне и напомнила...

[Bokul]

. В каких ситуациях Constructor будет возвращать False, True? Какие преимущества дает использование конструктора для статических объектов?

А
???????

Вот с таким:

Я же тоже самое написал...

[volvo]

Какие преимущества дает использование конструктора для статических объектов?

Попробуй обратиться к методу статического объекта, лучше - виртуальному, чтобы прочувствовать как следует, без предварительного вызова конструктора...

(главное - не запутайся, статический объект - тот, который описывается так:

var obj: TObject;

и соответственно создается в сегменте данных, а динамический - это тот, который создается через New в "куче")

[Bokul]

главное - не запутайся

Правильно заметил - я запутался с терминами. Теперь все ясно.

Почему не отвечаешь на самые интересные вопросы?

Я понял, что эта задача сводится к тому, чтобы конструктор вернул false?

По умолчанию, когда для динамического экземпляра объекта не
хватает памяти, вызов конструктора, использующий расширенный син-
таксис стандартной процедуры New, генерирует ошибку этапа выпол-
нения 203. Если вы установили функцию обработки ошибки динамичес-
ки распределяемой области, которая вместо стандартного результата
функции 0 возвращает 1, когда выполнить запрос невозможно, вызов
конструктора через New возвращает nil (вместо прерывания програм-
мы).

Восстановление ошибок конструктора
Так что, надо замусорить всю память в куче для решение?

Сообщение отредактировано: Bokul - 15.12.2006 5:27

[Bokul]

Разобрался, даже память не надо использовать, просто в конструкторе вызвать Fail, и все будет хорошо...

type
   pT=^T;
   T=object
     constructor init;
     destructor done;
   end;
constructor T.init;
begin
  done;
  fail;
end;


destructor T.done;
begin end;

procedure x(const the_pointer:pT);
begin
  if the_pointer=nil then
     writeln('not assigned');
end;

var mem:longint;
begin
  mem:=memavail;
  X(new(pT,init));
  writeln('Difference: ',mem-memavail);
  readln;
end.

Сообщение отредактировано: Bokul - 15.12.2006 10:05

[Bokul]

Значит правильно?

Теперь я хотел бы вернутся к вопросу о организации и освобождения с память указателей на один и тот же объект - Сообщение #88.

Как сделать правильное освобождение, чтобы потом не возникло Error 210?

[volvo]

Теперь я хотел бы вернутся к вопросу о организации и освобождения с память указателей на один и тот же объект

Ну что ж... Давай вернемся... Только вначале я хотел бы тебя переадресовать вот сюда:

Задачи на знание ООП (сообщение №58)... Здесь ты совершил стратегическую ошибку, выбрав для себя вариант №3 - назначение индексов самому... Я, если честно, на такой вариант не рассчитывал (потому, что я объяснил, что структура представляет собой кортеж, в котором обращение идет не как в списке, чтобы сам объект назначал нумерацию, а нумерация задается мной) - поэтому вот тот вариант, который я имел в виду, когда создавал тему:

Спойлер (Показать/Скрыть)

Код

type
  PT = ^T;
  T = object
    constructor init;
    destructor done; virtual;

    function make_copy: PT; virtual;
  end;

  PTint = ^Tint;
  Tint = object(T)
    value: integer;

    constructor init(X: integer);
    procedure print; virtual;

    function make_copy: PT; virtual;
  end;

  PTfloat = ^Tfloat;
  Tfloat = object(T)
    value: double;

    constructor init(X: double);
    procedure print; virtual;

    function make_copy: PT; virtual;
  end;


constructor T.init;
begin { abstract } end;
destructor T.done;
begin { abstract } end;

function T.make_copy: PT;
begin { abstract } end;


constructor Tint.init(X: integer);
begin value := X end;
procedure Tint.print;
begin write(value:4) end;

function Tint.make_copy: PT;
begin
  make_copy := new(PTint, init(value));
end;


constructor Tfloat.init(X: double);
begin value := X end;
procedure Tfloat.print;
begin write(value:8:4) end;

function Tfloat.make_copy: PT;
begin
  make_copy := new(PTfloat, init(value));
end;


const
  maxSize = 100;
type
  TArr = object
    arr: array[1 .. maxSize] of PT;

    constructor init;
    destructor done;
    procedure set_index(i: integer; p: PT);

    procedure count_each(const p: PT);
  end;

constructor TArr.init;
var i: integer;
begin
  for i := 1 to maxSize do arr[i] := nil;
end;
destructor TArr.done;
var i: integer;
begin
  for i := 1 to maxSize do
    if assigned(arr[i]) then dispose(arr[i], done);
end;

procedure TArr.set_index(i: integer; p: PT);
var new_instance: PT;
begin
  if i <= maxSize then begin
    if assigned(arr[i]) then dispose(arr[i], done);

    arr[i] := p^.make_copy;
  end;

  if assigned(p) then
    dispose(p, done);
end;

procedure TArr.count_each(const p: PT);
var i, count: integer;
begin
  count := 0;
  for i := 1 to maxSize do begin

    if assigned(p) and
       (typeof(arr[i]^) = typeof(p^)) then inc(count);

  end;
  writeln('count = ', count);

  if assigned(p) then dispose(p, done);
end;

function copy(p: PT): PT;
begin
  copy := p^.make_copy;
end;


var
  i: integer;
  obj_int: PTint;
  obj_float: PTfloat;
  any_arr: TArr;
var
  the_mem: longint;

begin
  the_mem := memavail;

  any_arr.init;

  { Вызываешь хоть так - через заранее инициализированный объект: }
  obj_int := new(PTint, init(3));
  any_arr.set_index(1, copy(obj_int));
  dispose(obj_int, done); { <--- не забываем - правил хорошего тона никто не отменял !!! }
  { если инициализировали объект отдельно - то и освобождать его будем отдельно }

  { Хочешь - вот так, через инициализацию "on the fly" }
  any_arr.set_index(2, new(PTint, init(3)));

  { Ну, и то, о чем я говорил - инициализация одним объектом нескольких ячеек - тоже работает }
  obj_float := new(PTfloat, init(3.5));
  for i := 7 to 76 do
    any_arr.set_index(i, copy(obj_float));
  dispose(obj_float, done); { <--- здесь тоже освобождаем, раз инициализация была отдельной }


  any_arr.count_each(new(ptfloat, init(0)));

  any_arr.done;

  writeln('difference: ', the_mem - memavail);

end.

[Bokul]

Ясно, все красиво и просто.. после того как уже посмотрел...

Я, если честно, на такой вариант не рассчитывал

А я на функцию copy не рассчитывал... Это специально для нее ты сделал метод make_copy виртуальным?

Ну как, продолжение будет?

М

Нет, продолжения не будет... Я, если честно, рассчитывал на бОльшую посещаемость данной темы. Но, как выяснилось, на этом форуме все считают себя достаточно разбирающимися в ООП (только вот непонятно, что ж никто не отвечает на вопросы по этой теме, редко, но все-же появляющиеся в разделе "Задачи"?), для одного человека я поддерживать тему не буду. Закрыто...

Сообщение отредактировано: volvo - 16.12.2006 16:45