IPB
ЛогинПароль:

> Прочтите прежде чем задавать вопрос!

1. Заголовок темы должен быть информативным. В противном случае тема удаляется ...
2. Все тексты программ должны помещаться в теги [code=pas] ... [/code], либо быть опубликованы на нашем PasteBin в режиме вечного хранения.
3. Прежде чем задавать вопрос, см. "FAQ", если там не нашли ответа, воспользуйтесь ПОИСКОМ, возможно такую задачу уже решали!
4. Не предлагайте свои решения на других языках, кроме Паскаля (исключение - только с согласия модератора).
5. НЕ используйте форум для личного общения, все что не относится к обсуждению темы - на PM!
6. Одна тема - один вопрос (задача)
7. Проверяйте программы перед тем, как разместить их на форуме!!!
8. Спрашивайте и отвечайте четко и по существу!!!

 
 Ответить  Открыть новую тему 
> Циклический сдвиг, на динамических данных
сообщение
Сообщение #1


Гость






Помогите плиз!
Нужно с помощью динамичесой организации данных, организовать сдвиг впрво. Пример вводим L1=(a, b, c) , а выводим L2=(c, a, b).

Кто поможет в двух-трёх словах как лучше организовать цикличкский сдвиг на одни элемент вправо?

сразу большое спасибо

М
Гость, не задавай вопросы в чужих темах! Предупреждение..
Тема разделена. Lapp


 ! 
Как оказалось позднее, ты сделал это ДВА раза!
Второе ПРЕДУПРЕЖДЕНИЕ!
Твоя подсеть может вся пострадать за тебя..
Lapp

 К началу страницы 
+ Ответить 
сообщение
Сообщение #2


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


Показываю на примере простого массива. Не знаю, что ты имел в виду под использованием динамической организации - уточни.

Сначала запоминаем последний элемент в буфер.
Затем делаем цикл сверху вниз от n-1 до 1 по перекладыванию соседних ячкеек (из меньшего номера в больший).
Потом переносим содержимое буфера в первый элемент.
A:array[1..n]of tElement;
Buff:tElement;
.........
Buff:=A[n];
for i:=n-1 downto 1 do A[i+1]:=A[i];
A[1]:=Buff


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #3





Группа: Пользователи
Сообщений: 2
Пол: Мужской

Репутация: -  0  +


Извините пож-та! Каюсь, больше не буду!

Я имел ввиду связанный список с динамическим выделенияем памяти (лаба про динамические структуры данных).


P.S. Вообщето задание на С, но спасибо если кто-чего подскажет и на Паскале, думаю пойму lol.gif .

Сообщение отредактировано: Judgedim -
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #4


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


Если список - то ход решения может быть разным.
В принципе, можно сделать и аналогично, но только это будет нерационально, особенно в случае однонаправленного списка (в нем от одного элемента можно перейти вперед, к следующему, но нельзя перейти назад, к предыдущему). В двунаправленных списках, грубо говоря, работы будет столько же, сколько и с массивом. Но суть в том, что в списках (обоих типов) это можно сделать даже быстрее, чем в массиве. Вот примерный алгоритм (для однонаправленного списка)..

1. Содержимое самого начального указателя (указателя на список) перекладываешь в указатель последнего элемента (который до этого содержал NIL).
2. В начальный указатель списка кладешь содержимое указателя предпоследнего элемента.
3. В указатель предпоследнего элемента кладешь NIL.

Все это нужно делать именно в указанной последовательности, чтобы не затереть информацию в процессе.
Сказанное проиллюстрировано рисунком:
Прикрепленное изображение
Сверху - начальное состояние списка, внизу - циклически сдвинутый список.
Как видишь, то, что с массивом делалось в цикле (зависящем от длины массива), в списке делается тремя присваиваниями.. Конечно, чтобы найти последний и предпоследний элемент, все равно нужен цикл (типа while или repeat).. smile.gif Но если элементы крупные (большие записи), то это все равно будет эффективнее.


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #5


N337
****

Группа: Пользователи
Сообщений: 737
Пол: Мужской

Репутация: -  26  +


Цитата
Вообщето задание на С
Здесь будет только на Паскале. Иначе - в разделе "Другие языки".

Вот возможная реализация. Используется двунаправленный список с фиктивным элементом. Такая организация списка позволяет без дополнительного просмотра списка: добавлять элементы в начало и конец списка, удалить любой элемент, вставить элемент в произвольное место списка, выводить список в любом порядке, сдвигать список с обоих направлениях. Использование фиктивного элемента избавляет нас от проверок на пустоту списка и его границы. Разберись - пригодится!

program ShiftList;

type
PList = ^TList;
TList = record
Prev, Next: PList;
n: Integer;
end;

procedure InitList(var List: TList);
begin
List.Prev := @List;
List.Next := @List;
end;

procedure AddItem(var List: TList; n: Integer);
var
p: PList;
begin
New(p);
p^.Next := @List;
p^.Prev := List.Prev;
List.Prev^.Next := p;
List.Prev := p;
p^.n := n;
end;

procedure FreeList(var List: TList);
var
p: PList;
begin
while List.Next <> @List do
begin
p := List.Next;
List.Next := p^.Next;
Dispose(p);
end;
List.Prev := @List;
end;

procedure ShrList(var List: TList);
var
p: PList;
begin
p := List.Prev;

List.Prev := p^.Prev;
List.Prev^.Next := @List;

p^.Next := List.Next;
p^.Next^.Prev := p;
p^.Prev := @List;
p^.Prev^.Next := p;
end;

procedure WriteList(const List: TList);
var
p: PList;
begin
p := List.Next;
while p <> @List do
begin
Write(p^.n, ' ');
p := p^.Next;
end;
Writeln;
end;

var
List: TList;
i: Integer;

begin
InitList(List);

for i := 1 to 10 do
AddItem(List, i);

WriteList(List);

ShrList(List);
WriteList(List);

ShrList(List);
WriteList(List);

ShrList(List);
WriteList(List);

FreeList(List);

Writeln;
end.


--------------------
The idiots are winning.
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #6





Группа: Пользователи
Сообщений: 2
Пол: Мужской

Репутация: -  0  +


Big thanks.
Буду разбираться ypriamii.gif
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #7


Гость






Извините, но программа циклится. Подскажите в чем тут дело?
 К началу страницы 
+ Ответить 

 Ответить  Открыть новую тему 
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 





- Текстовая версия 24.09.2020 22:04
500Gb HDD, 6Gb RAM, 2 Cores, 7 EUR в месяц — такие хостинги правда бывают
Связь с администрацией: bu_gen в домене octagram.name