Обработка символьной информации, с помощью функций DOS Опции

[Rocket]

Вот задание: Ввести с клавиатуры две строки. Сравнить их. Вывести на экран какая из строк больше и насколько. Какие мысли есть по реализации данной программы? Как осуществить сравнение строк?

[volvo]

Значит, придется написать процедуру вывода десятичного числа:

; В сегменте данных:
count_of_digits	dw 4 ; число будет отображаться в четырех позициях
; ...

writeDEC proc
	;  выводим содержимое AX
	push ax
	push bx
	push cx
	push dx
	
	push di		; здесь будем хранить признак знака
	xor cx, cx
	mov bx, 10
	xor di, di	; 0 = число положительное
	or ax, ax	; Проверим, не отрицательное ли число в AX
	jns next_digit	; Не отрицательное... Переходим дальше
	inc di		; Отрицательное. Выставляем DI в 1 (число отрицательное) ...
	neg ax		; ... и меняем знак числа
	
next_digit:
	xor dx, dx	; DX обнуляется. Чтобы можно было делить DWORD на WORD
	div bx		; Делмм DX:AX на BX (т.е. на 10) ...
	push dx		; ... остаток забрасываем в стек ...
	inc cx		; Увеличим счетчик цифр
	or ax, ax
	jnz next_digit	; ... и продолжаем этот цикл пока AX <> 0
	
	mov dx, count_of_digits
	sub dx, cx	; вычисляем, сколько пробелов надо вывести перед числом
	or di, di
	jz _zer
	dec dx		; если ранее был установлен "признак отрицательности"
			; то уменьшаем число пробелов еще на 1, поскульку надо еще вывести "-"
_zer: 
	push cx		; сохраним число цифр в стеке
	mov  cx, dx
	mov al, ' '	; и напечатаем необходимое число пробелов
next_space:
	int 29h		; прерывание 29h - вывод на консоль
	loop next_space
	
	pop  cx		; вернем число цифр
	or di, di
	jz next_char
	mov al, '-'
	int 29h		; если нужен минус - выводим его
	
next_char:
	pop ax		; остатки от деления возвращаем в AX
	add al, '0'	; преобразуем в символ (добавляя код '0')
	int 29h		; и выводим на консоль
	loop next_char
	
	pop  di		; восстанавливаем все регистры
	pop  dx
	pop  cx
	pop  bx
	pop  ax
	ret		; и выходим из процедуры
writeDEC endp

, и вызывать вот так:

	; ...
	mov ax, len1
	sub ax, len2
	call writeDEC	; печатаем разность
	
	lea dx, mes1
	mov ah, 09h	; выводим сообщение, что первая строка длиннее
	int 21h
   	
	jmp finish		; на выход

m2:
	mov ax, len2
	sub ax, len1
	call writeDEC	; печатаем разность
	
	lea dx, mes2
	mov ah,09h	; выводим сообщение, что длиннее вторая строка
	int 21h
	
finish:
	; ...

И функция 3Fh, что она делает?

Ну ты даешь... Я что-ли эту функцию придумал использовать? Ты сам в своей программе ее применял, а теперь спрашиваешь... Она вводит с клавиатуры строку (максимально возможную длину строки надо занести в CX), и помещает ее в буфер (адрес буфера - в DX).

Сообщение отредактировано: volvo - 28.11.2008 5:09