121/11 YES!, Проверка делимости. Опции

[Cheburashka]

Для делимости числа на 11 необходимо, чтобы разность между суммой цифр, стоящих на четных местах, и суммой цифр, стоящих на нечетных местах, делилась на 11.

Приведу небольшие примеры:
121/11=11. Вывод: yes;
1211/11=110,(09). Вывод: no;

Я в принципе понимаю что данная задача лёгкая, но я хочу поинтересовться по поводу условия задачи:
Там написано, цитирую:

"...чтобы разность между суммой цифр, стоящих на четных местах, и суммой цифр, стоящих на нечетных местах, делилась на 11."

Если подбирать под мой пример(1), то я так понимаю это выглядит так: 2-(1+1)/11.
Как видите по примеру нельзя вычислить что данное число делится на 11.

ОБЪЯСНИТЕ СМЫСЛ!

[volvo]

Число делится на 11 тогда и только тогда, когда сумма цифр с чередующимися знаками равна 0 или делится на 11 (то есть 182 919 делится на 11, так как 1 — 8 + 2 — 9 + 1 — 9 = −22 делится на 11)

[Cheburashka]

Ага ясно!
То есть для чисел 121 (1-2+1=0) Условие будет выполнятся?

Сообщение отредактировано: Сергей Меркурьев - 27.05.2009 19:55

[Krjuger]

Ну тебе же красным цветом цветом выделили.Да будет.

[Cheburashka]

ДАдада, спасибо)
Вот моё решение к этой задачке)) Не судите строго так сказать)

program metro;
  var i,j,sum,ibr,cod:integer;
      s,sch:string;
begin
  Read(s);
  j:=1;
  For i:=1 to length(s) do
    Begin
      sch:=Copy(S,i,1);
      Val(sch,ibr,cod);
      inc(j);
      If j mod 2=0 then Sum:=Sum-ibr
                   else Sum:=Sum+ibr;
    End;
  If (sum=0) or (sum mod 11=0) then Write ('YES')
                               else Write ('NO');
End.

[Krjuger]

Я немног оне согласен, с реализацией,если ты читаеш и файла зачем тебе строка?Я бы сделал так.

program metro;
  var i,j,sum,ibr,cod:integer;
      ch:string[1];
begin
  j:=1;
  while not eol(fin)  do{таже самая строка,только не запоминаем,как переменную и еще я точно не помню,либо eol(fin) либо еоln(fin)}
    Begin
      read(fin,ch);
      Val(ch,ibr,cod);
      inc(j);
      If j mod 2=0 then Sum:=Sum-ibr
                   else Sum:=Sum+ibr;
    End;
  If (sum=0) or (sum mod 11=0) then Write ('YES')
                               else Write ('NO');
End.

просто зачем тебе полная строка, если ты туда записываеш всего 1 элемент,да и чтобы строку пройти не обязательно ее считывать и запоминать длинну.Я бы вообще использовал на твоем месте не стоку,а чар,тогда и процедура val ушла бы,но тогда надо было бы делать функцию chartoint.

Сообщение отредактировано: Krjuger - 27.05.2009 20:57

[Cheburashka]

В этой строке у меня не один элумент, а само выражение! А вторая запоминает элемент. И я с данными функциями ещё не знаком.

[volvo]

Не надо преобразовывать строку к числу там, где можно обойтись без преобразования. Все проще:

var
  n: longint;
  curr, s: integer;

begin
  readln(n);
  curr := 1; s := 0;
  while n <> 0 do begin
    s := s + curr * (n mod 10);
    curr := - curr;
    n := n div 10;
  end;
  if (s = 0) or (abs(s) mod 11 = 0) then writeln('yes')
  else writeln('no');
end.

[Cheburashka]

А если Вам дано число большее 2 миллиардов? (болше longint)

[Krjuger]

а что тебе чтоит разбить число? посчитаеш первые 9 знаков,потом еще 9 знаков и тд сколько надо.Тут же невашен порядок числа.Все равно операции с одним типом будут быстрее чем преобразование из 1 типа в другой.

[volvo]

Обычное для таких задач ограничение - 10⁹, то есть, один миллиард. Если больше - придется использовать более емкие типы: dword, int64, qword... Ну, или тогда уже переходить к строке.

P.S. Кстати, по условию в оригинале - строка она тоже не метод, там говорится о числах 1 .. 10¹⁰⁰⁰⁰, тут уж только посимвольное чтение, да и сумму надо сделать типа LongInt, с Integer-ом может быть переполнение:

var
  ch: char;
  curr, s: longint;

begin
  curr := 1; s := 0;
  while not eoln do begin
    read(ch);
    s := s + curr * (ord(ch) - ord('0'));
    curr := - curr;
  end;
  if (s = 0) or (abs(s) mod 11 = 0) then writeln('yes')
  else writeln('no');
end.

[Cheburashka]

Как раз таки такое ограчение мне и требовалось!!!