рекурсия, Определить число, получаемое выписыванием в обратном порядке цифр зада Опции

[marwell]

Определить число, получаемое выписыванием в обратном порядке цифр заданного натурального числа (использовать рекурсивную функцию). Ничего не приходит в голову Кто-нибудь, дайте пожалуйста направление(код постараюсь написать сам)

[Client]

брать остатока от деления на 10, делай с ним что надо, и дели число на 10. Так пока число не будет равно 0.

[marwell]

брать остатока от деления на 10, делай с ним что надо, и дели число на 10. Так пока число не будет равно 0.

ааа, точно! как я не догадался? спасибо большое

[marwell]

черт, даже не знаю, как это можно написать с рекурсией ведь после операции mod 10 мы потеряем все остальные числа

[volvo]

ведь после операции mod 10 мы потеряем все остальные числа

Ничего не потеряем:

procedure rec(x: longint);
begin
  if x > 0 then
  begin
    write(x mod 10);
    rec(x div 10);
  end;
end;

[marwell]

спасибо!

[marwell]

а реально ли сделать это через функцию, а не процедуру?

[Client]

пол часа мучений стоили этого
скорей всего можно и по другому.
вот что получилось

uses crt;
var
   a,b:integer;

function asd(x,i:integer) :integer;
begin
   if x=0 then asd:=-b
   else begin
      if x div 10 <>0 then
         b:=b +i*10+ x mod 10;
      asd:=(i*10+ x mod 10) + asd(x div 10,i*10+ x mod 10 )
   end;
end;

begin
   clrscr;
   b:=0;
   readln(a);
   writeln(asd(a,0));
   readkey
end.

[volvo]

скорей всего можно и по другому.

Можно конечно... Заметь, без побочных эффектов. Старайся вообще обходиться без них. А уж об использовании глобальных переменных я вообще не хочу вспоминать

function r(x: longint): longint;
const b: longint = 0;
begin
  if x = 0 then begin
    r := 0; b := 1;
  end
  else begin
    r := r(x div 10) + b * (x mod 10); b := 10 * b;
  end;
end;

begin
  writeln(r(12345));
end.

[marwell]

спасибо огроменное

[marwell]

Можно конечно... Заметь, без побочных эффектов. Старайся вообще обходиться без них. А уж об использовании глобальных переменных я вообще не хочу вспоминать

function r(x: longint): longint;
const b: longint = 0;
begin
  if x = 0 then begin
    r := 0; b := 1;
  end
  else begin
    r := r(x div 10) + b * (x mod 10); b := 10 * b;
  end;
end;

begin
  writeln(r(12345));
end.

 const b: longint = 0;
begin
  if x = 0 then begin
    r := 0; b := 1; 

а разве можно константе b=0 присвоить значение b:=1?

[Lapp]

а разве можно константе b=0 присвоить значение b:=1?

Типизированной константе - можно. По сути, это просто инициализированные переменные. Неудачное название им дали в Борланде..

[marwell]

программа выдает только нули

[Lapp]

программа выдает только нули

Попробуй вот так:

function r(x: longint): longint;
var
  a,b,c,d: longint;
begin
  if x = 0 then
    r := 0
  else begin
    b:= 1;
    while x div b div 10 > 0 do b:=b*10;
    a:= x div b;
    c:= x-a*b;
    d:= 1;
    while c div d div 10 > 0 do d:=d*10;
    r := a + b div d*r(c );
  end;
end;

begin
  writeln(r(12345));
end.

Тут наверняка наворочено больше, чем нужно, и не очень красиво ))..

[Client]

хм, а собственно где нули получаются? при каких данных?

[marwell]

хм, а собственно где нули получаются? при каких данных?

с твоим-то кодом все работает))

[Client]

volvo есть над чем подумать

Добавлено через 2 мин.
код volvo рабочий. Что не так?

[volvo]

Что не так?

Не так работает под Турбо-Паскалем, надо разбивать вычисление выражения на 2 этапа:

function r(x: longint): longint;
const
  b: longint = 0;
var v: longint;
begin
  if x = 0 then begin
    r := 0; b := 1;
  end
  else begin
    v := r(x div 10); { <--- Первый этап }
    r := v + b * (x mod 10); b := 10 * b; { <--- Второй этап }
  end;
end;

begin
  writeln(r(1234543));
end.

Вот теперь будет работать одинаково под любым компилятором.

[Lapp]

Не так работает под Турбо-Паскалем

У меня не каждый раз срабатывала под FPC.. Сейчас воспроизвести не могу.
Не знаю, стоит ли полагаться на такие вещи..

[volvo]

стоит ли полагаться на такие вещи..

На какие такие? Я не делаю ничего запрещенного, заметь, сначала - рекурсивный вызов, потом - использование значения b. То есть, никогда не будет использовано неинициализированное тобой значение b. Чтобы оно начало использоваться - рекурсия должна дойти до конца (x = 0), но тогда b уже станет равно 1. Опять же, "типизированная константа" = "статическая переменная", она описывается в сегменте данных (а не в стеке, как обычная переменная), и поэтому сохраняет свое значение не только между вызовами простых функций, но и между вызовами рекурсивных тоже, так что и с этой стороны подвохов быть не может. Так что это вполне приемлемая конструкция.

У меня не каждый раз срабатывала под FPC

Если еще у кого-то будут неправильные срабатывания - отпишитесь здесь, интересно, на каких значениях это происходит. Чему разно изначальное число, и что возвращает функция. Единственный вариант, который приходит в голову - это когда "перевернутое" число не влезет в LongInt (например, 1234567899), но тут уж ничего не поделаешь.