Двумерные массивы, Помогите, пожалуйста, найти ошибку Опции

[Eichhorn]

Есть задача:
Дана матрица M*N Найти номер её столбца с наименьшим произведением элементов и вывести данный номер, а также значение наименьшего произведения.
Вот текст моей программы:

const
n=4;
m=6;
var
a:array[1..m, 1..n] of integer;
i,j,p,min,f:integer;

begin
p:=1;
randomize;
for i:=1 to m do
        begin
        for j:=1 to n do
                begin
                a[i,j]:=random(51);
                writeln(a[i,j]);
                end;
        writeln;
        readln;
        end;

for i:=1 to m do
begin
        for j:=1 to n do
        min:=p*a[1,j];
                begin
                p:=p*a[i,j];
                if p<min then
                        begin
                        min:=p;
                        f:=i;
                        end;
                end;


end;
writeln(min);
writeln(f);
readln;
end.

У меня программа выводит все элементы массива, а дальше ломается. Сначала без readln она сразу ломалась, но когда я его поставила, стала выводить массив. А вот дальше я никак не могу найти ошибку, почему не выводит остальное...

[volvo]

Банальное переполнение. Вот, сравни с тем, что было у тебя:

const
  m = 6; { строки }
  n = 4; { столбцы }

var
  a: array[1..m, 1..n] of integer;
  i, j, f: integer;
  p, min: longint; { Так избегаем переполнения }

begin
  randomize;

  { генерируем матрицу - как обычно: }
  for i := 1 to m do { строки }
  begin
    for j:=1 to n do { элементы строк }
    begin
      a[i,j] := random(51);
      write(a[i,j] : 3);
    end;
    writeln;
  end;

  min := maxlongint;
  f := 0;

  for j := 1 to n do { J => идем по столбцам !!! }
  begin
    p := 1;
    for i := 1 to m do { I => а внутри - по строкам, т.е., по элементам столбцов }
      p := p * a[i, j];

    writeln('p[', j, '] = ', p); { <--- Только для теста, можешь убрать... }

    if p < min then
    begin
      min := p; f := j;
    end;
  end;

  writeln(min);
  writeln(f);
  readln;
end.

[Eichhorn]

Спасибо огромное!!! Я про longint даже не знала...