Работа со списками, pascal Опции

[fasty]

Необходимо выполнить до 5 января 3 лабы на паскале.
1 Написать рекурсивную процедуру или функцию, определяющую, предшествует ли один заданный символ другому заданному символу.Это нужно добавить в уже выполненную лабу,каторую я предоставлю.
2. Написать программу, позволяющую ввести элементы линейного списка и выполнить задание, указанное в варианте:
Написать процедуру, которая удаляет элемент списка перед каждым вхождением элемента X, если такой есть и отличен от X. Значение X вводить с клавиатуры
3.
Написать программу, позволяющую ввести элементы линейного списка и выполнить задание, указанное в варианте:
С клавиатуры вводятся слова и помещаются в D-список (info:string). Написать проце-дуру, которая меняет местами слова с четными и нечетными номерами (1-е со 2-м, 3-е с 4-м и т.д.).

[volvo]

Вот тебе сразу решение задачи №2:

type
  plist = ^tlist;
  tlist =  record
    info: integer;
    next: plist;
  end;

procedure delete_before(first: plist;
          X: integer);
var r, p: plist;
begin
  p := first;
  while p^.next <> nil do begin

    if (p^.next^.info = X) and (p^.info <> X) then begin

      r := p^.next;
      p^ := r^;
      dispose( r );
      r := nil

    end
    else p := p^.next;
  end;
end;

var
  X: integer;
  p, first, last: plist;
begin

  first := nil; last := nil;

  repeat

    write('next element: (-999 to exit): '); readln(X);
    if X <> -999 then begin

      new(p);
      p^.next := nil; p^.info := X;
      if first = nil then first := p
      else last^.next := p;
      last := p

    end;

  until X = -999;
  writeln('list:');
  p := first;
  while p <> nil do begin
    write(p^.info:5);
    p := p^.next;
  end;
  writeln;

  write('now, enter the X element: '); readln(X);
  delete_before(first, X);

  writeln('list (after) :');
  p := first;
  while p <> nil do begin
    write(p^.info:5);
    p := p^.next;
  end;
  writeln;
end.

[volvo]

Вот №3 (D - Double Linked List: Список, каждый элемент которого имеет указатель на предыдущий и последующий элементы):

type
  ttype = string;

  plist = ^tlist;
  tlist =  record
    info: ttype;
    prev, next: plist;
  end;

var
  first, last: plist;

procedure print(p: plist);
begin
  while p <> nil do begin

    write(p^.info, '':2);
    p := p^.next;

  end;
  writeln;
end;

procedure append(x: ttype);
var p: plist;
begin
  new(p);
  p^.info := x;
  p^.next := nil;
  p^.prev := last;

  if first = nil then first := p
  else last^.next := p;

  last := p
end;

procedure change(p: plist);
var
  q: plist;
  T: ttype;
begin
  q := p;
  while (p <> nil) and (p^.next <> nil) do begin
    T := p^.info;
    p^.info := p^.next^.info;
    p^.next^.info := T;

    p := p^.next^.next;
  end;
end;


var
  X: ttype;

begin

  first := nil; last := nil;

  repeat

    write('next element (empty string to exit): '); readln(X);
    if X <> '' then append(X);

  until X = '';

  write('list: '); print(first);

  change(first);

  write('list after: '); print(first);

end.