Динамические струк. данных, модуль, спасите :-( Опции

[Анна]

Люди, помогите пожалйуйста мне.
Прочитала это: http://forum.pascal.net.ru/index.php?showt...0&st=0&p=26901& и это: http://forum.pascal.net.ru/index.php?showtopic=2706
Очень плохо все поняла

Есть задача:

Все элементы в массиве С [1..30] меньше среднеарифметического положительных чисел заменить на максимальное значение массива.
Организовать это всё с помощью функции или процедуры, находящейся в модуле. Использовать линамические переменные


Что-то написала, но имхо чушь

 unit MyMod;
interface
procedure qwe (c: array [1..30] of integer);
var
i,temp: integer;

for i:=1 to 30 do
if c[i] > 0 then temp:=temp+c[i]; {среднеарифметич. .. как дальше?}

=-=-=-=-=-=-=-=-=-=-=-=-=-=

if c[i] > temp then c[i] := max

[volvo]

Там же все написано...
Модуль:

unit module;

interface

type
  ParrType = record
    arr: ^arrType;
    size: integer;
  end;
  arrType = array[1 .. 65520 div sizeof(integer)] of integer;

procedure getArray(var p: ParrType; const size: integer);
procedure freeArray(var p: ParrType);

procedure do_it(p: ParrType);

implementation

procedure getArray(var p: ParrType; const size: integer);
begin
  getmem(p.arr, size * sizeof(integer));
  p.size := size;
end;
procedure freeArray(var p: ParrType);
begin
  freemem(p.arr, p.size * sizeof(integer));
end;

procedure do_it(p: ParrType);
var
  s: real;
  i, max: integer;
begin
  s := 0; max := -maxint;

  for i := 1 to p.size do begin
    s := s + p.arr^[i];
    if max < p.arr^[i] then max := p.arr^[i];
  end;

  s := s / p.size;
  for i := 1 to p.size do
    if p.arr^[i] < s then p.arr^[i] := max;
end;

end.

Основная программа:

uses module;

var
  x: ParrType;
  i: integer;

begin
  getArray(x, 30); { <--- Создаем динамический массив }

  for i := 1 to 30 do { <--- Ну, или заполнить массив по-другому }
    x.arr^[i] := i;

  for i := 1 to 30 do { <--- Печатаем массив ДО изменения }
    write(x.arr^[i]:4);
  writeln;

  do_it(x);

  for i := 1 to 30 do { <--- Печатаем массив ПОСЛЕ изменения }
    write(x.arr^[i]:4);
  writeln;

  freeArray(x); { <--- Удаляем динамический массив }
end.