Программа должна рисовать катащийся эллипс. Элиппс рисовать вроде получается, а вот дальше непонятно, формулы поворота вроде верны. Но что-то не то получается. У кого есть время гляньте плз.

 
uses graph,crt;

const
sizex=30;
sizey=300;
sizexp=25;
sizeyp=15;
speed=1;
one=pi/180;
t=one*speed;
ms=2000;
Type TEllipse=object
         f1,f2:real;
         angle,xxpp,yypp,xxp,yyp:real;
         x,y:integer;
         Constructor Init (focus1,focus2:integer; xp,yp:integer);
         Procedure show;
         procedure rotate (xO,yO:integer;xp:real);
         Destructor Done;
         end;
TScreen=object(TEllipse)
        Constructor Init(focus1,focus2:integer; xp,yp:integer);
        Procedure GraphInit;
        Procedure Go;
        Destructor Done;
        end;

Constructor TEllipse.Init(focus1,focus2:integer; xp,yp:integer);
            begin
            x:=focus1; y:=focus2;
            f1:=xp;
            f2:=yp;
            fillellipse(x,y,round(f1),round(f2));
            end;
 Procedure TEllipse.Rotate(xO,yO:integer; xp:real);
           begin
           x:=xo;
           y:=yo;
           xxpp:=xo+(xp*(cos(t)));
           yypp:=yo+(xp*(sin(t)));
           fillellipse(x,y,Round(xxpp),Round(yypp));
           end;
procedure TEllipse.show;
          begin
          end;
Destructor TEllipse.Done;
           begin end;

Constructor TScreen.Init(focus1,focus2:integer; xp,yp:integer);
            begin
            x:=focus1;
            y:=focus2;
            f1:=xp;
            f2:=yp;
            fillellipse(x,y,round(f1),round(f2));
            angle:=0;
            end;

Procedure TScreen.GraphInit;
          var gd,gm,ErrorCode:integer;
          begin
          if GetGraphMode=2 then Exit;
          gd:=Detect;
          InitGraph(gd,gm,'');
          ErrorCode:=GraphResult;
          if ErrorCode<>grok then begin
          writeln('Error: ',GraphErrorMsg(ErrorCode));
          Halt(1);
          end;
          end;
procedure TScreen.Go;
          begin
          repeat
           angle:=angle+t;
           rotate(x,y,Round(xxpp));
           delay(ms);
           show;
          until keypressed;
          end;
Destructor Tscreen.done;
           begin CloseGraph; end;

{$I GrInit}
var Screen:Tscreen;
begin
GRInit;
 Screen.Init(sizex,sizey,sizexp,sizeyp);
 Screen.GraphInit;
 Screen.Go;
 Screen.done;
 end.

.

а зачем у тебя переменная angle заведена ?
она у тебя, вроде как, ни на что не влияет...
и вообще, закоментируй код, где ты что пытаешься сделать. Глядишь, в процессе этого и сам ошибку найдешь

To: Manner
Вот объясни мне, человеку, который только что увидел твою программу, зачем ты TScreen наследуешь от TEllipse? Ну я понимаю, что задание такое, нужно наследование, но не так же !!! Хотя бы определить абстрактный класс TFigure, а от него - твой конкретный TEllipse...

Ну, или в крайнем случае (если тебе больше никаких других фигур отрисовывать не надо),

Type
  TGraphix = Object
    { инициализация/закрытие граф. режима }
  End;
  TEllipse = Object(TGraphix)
    {
      Тебе же для того, чтобы отрисовать эллипс, нужна графика,
      а не наоборот !!!
    }
  End;

Теперь по теме: самый простой способ нарисовать вращающийся (он же - катящийся) эллипс - это представить его параметрически... Тогда все дело сводится к 2-м простым формулам. Если нужно - скажи, я покажу как это делается...

Да, если можно был бы рад посмотреть как параметрически решается данная задача.

Ну, смотри ...

uses Crt, Graph;

Function max(a, b: Integer): Integer;
Begin
  max := a;
  If a < b Then max := b;
End;

const
  r2d = 180/Pi;
  ms = 5000;

type
  TGraphix = Object
    Constructor Init;
    Destructor Done;
  End;

  TEllipse = Object(TGraphix)
    a, b: integer;
    X0, Y0: Integer;
    Angle: Integer;

    Constructor Init(TheA, TheB, CoordX, CoordY: Integer);
    Destructor Done;

    Procedure Show(Visible: Boolean);
    Procedure Rotate;
  End;

Constructor TGraphix.Init;
Var
  GrDriver, GrMode, ErrCode: Integer;
Begin
  GrDriver := Detect;
  InitGraph(GrDriver, GrMode, '');
  ErrCode := GraphResult;
  If ErrCode <> grOk Then Fail;
End;

Destructor TGraphix.Done;
Begin
  CloseGraph;
End;

{
  TheA, TheB - полуоси эллипса
  CoordX, CoordY - начальные координаты центра
}
Constructor TEllipse.Init(TheA, TheB, CoordX, CoordY: Integer);
Begin
  If not Inherited Init Then Fail;

  a := TheA; b := TheB;
  X0 := CoordX; Y0 := CoordY;
End;
Destructor TEllipse.Done;
Begin
  Inherited Done;
End;

Procedure TEllipse.Show(Visible: Boolean);
Var
  Alpha, Phi, _X, _Y: Real;
  i, X, Y: Integer;
Begin
  If Visible Then Begin

    Alpha := Angle/r2d;
    For i := 0 To 359 Do Begin
      Phi := i / r2d;
      _X := a * Cos(phi);
      _Y := b * Sin(phi);

      X := Trunc(x0 + _X * Cos(Alpha) - _Y * Sin(Alpha));
      Y := Trunc(y0 + _X * Sin(Alpha) + _Y * Cos(Alpha));
      PutPixel(X, Y, White);
    End;

  End
  Else Begin
    SetFillStyle(SolidFill, GetBkColor);
    SetColor(Black);
    FillEllipse(X0, Y0, max(a, b)+10, max(a, b)+10);
  End;
End;
Procedure TEllipse.Rotate;
Begin
  Show(False);
  { А вот на сколько увеличивать Angle и X0 - с этим можно и поиграться... }
  Inc(Angle); Inc(X0);
  Show(True);
End;

Var
  ell: TEllipse;

begin
  If not ell.Init(30, 40, 50, 200) Then Exit;

  Repeat
    ell.Rotate;
    Delay(ms);
  Until KeyPressed;

  While Keypressed Do ReadKey;

  ell.Done;
end.

Прорисовка эллипса происходит по пиксельно, т.е. прошитываются координаты пикселя, он окрашивается в белый цвет и выводиться. Я правильно понял?
Можно пояснение для чего используется функция max.

А как иначе при отрисовке функции, заданной параметрически?
Только учти, эллипс НЕ залитый, т.е. движется только контур эллипса (хотя, прежде чем задавать вопросы, ты должен был как минимум запустить программу, чтобы иметь представление о том, что она делает...)

А функция Max ... Для того, чтобы удалить старый эллипс (перед отрисовкой нового), я поверх него рисую окружность, залитую цветом фона с радиусом немного превышающим бОльшую полуось (можно было бы делать ClearDevice, но моим способом будет меньше мерцать), а т.к. TEllipse не знает, какая из полуосей больше, то используется Max чтобы это определить...

Обязательно запущу.
Просто мне говорили,что при пиксельной прорисовке сильно тормозить будет, но раз пользуетесь значит все-таки можно.
Спасибо.