Параллельный порт Опции

[Selena]

Помогите пожалуйста написать программу. Я впринципе не понмаю что здесь надо сделать.
Задание:
Параллельный порт имеет регистр данных (DR) по адресу B+0, регистр состояния (SR) адрес B+1, регистр управления (CR) адрес B+2, где В - базовый адрес, имеющий одно из значений - 378h, 278h, или 3ИСрю В обычном режиме вывод производится в DR и CR, а ввод из SR.
Составить программу для управления индикаторами и чтение состояния кнопок. В отпущенном состоянии с кнопок подается "1", а в нажатом - "0". Определить какие биты регистров CR и SR инвертируются.

Адрес регистров порта LPT1 > Пуск\настройка\панель управления\система\устройства\порты\LPT1\свойства\ресурсы

Вот такое задание. Помогите пожалуйста.

[volvo]

Составить программу для управления индикаторами и чтение состояния кнопок. В отпущенном состоянии с кнопок подается "1", а в нажатом - "0". Определить какие биты регистров CR и SR инвертируются.

Управления какими индикаторами? Чтение состояния каких кнопок? Как (и какие) кнопки связаны с портами LPT (или с регистрами управления портами LPT)?
Первая часть понятна, а вот со второй - проблематично. Надо бы уточнить...

[Selena]

Я сама не знаю причем тут порт LPT. На сколько я знаю он нужен для принтера. Препод нам выдал карточки и сказал делайте. А что и как делать не объяснил. Все задание от туда я периписала как там было написано.
Ну хотя бы тогда с первой частью помогите. А про остальное я потм строшу у него зачем это надо.

[xds]

Препод нам выдал карточки и сказал делайте.

В лучших традициях... Аминь %)

Видимо предполагается, что к LPT подключено некое (абстрактное, если, конечно, препод его сам не спаял ) устройство, состоящее из светодиодов, резисторов и кнопок. Следует уточнить, на каких именно ножках LPT "висят" индикаторы (светодиоды?) и кнопки. В общих чертах, c помощью записи в регистр данных (DR) и (или) в регистр управления (CR) можно будет управлять индикаторами, а по считанному из регистра состояния (SR) значению определить текущее состояние кнопок. Обмен данными с портами ввода/вывода в Паскале осуществляется с помощью конструкции Port, например:

Port[$378] := 1; { запись значения 1 в порт $378 (регистр данных LPT) }
a := Port[$379]; {чтение значения из порта $379 (регистр состояния LPT) в переменную a }

Предположим, что требуется:
1) изменить логический уровнь на любом выходе LPT на противоположный;
2) проверить логический уровень на любом входе LPT (учитывая, что некоторые из входов - инверсные).

Получим примерно такой код (полноценно работает только в DOS/Win 9x и при наличии указанного в задании устройства )

program LPT;

uses
  Crt;

const
  Base = $3BC;
  DR = Base;
  SR = Base + 1;
  CR = Base + 2;

procedure WriteButton(n, s, Bit: Integer);
begin
  Write('Кнопка ', n, ': ');
  if s shr Bit and 1 = 1 then
    Writeln('отпущена')
  else
    Writeln('нажата  ')
end;

procedure WriteByte(n: Integer);
var
  i: Integer;
begin
  for i := 7 downto 0 do
    Write(n shr i and 1);
end;

var
  c: Char;
  s: Integer;

begin
  ClrScr;
  Writeln('Клавиши: <1>..<9>, <0>, <->, <=> - включить/выключить индикатор; <q> - выход');
  repeat
    if KeyPressed then
      begin
        c := ReadKey;
        case c of
        'q': Break;
        '1'..'8':
          Port[DR] := Port[DR] xor 1 shl (Ord(c) - Ord('1'));
        '9':
          Port[CR] := Port[CR] xor 1;
        '0':
          Port[CR] := Port[CR] xor 2;
        '-':
          Port[CR] := Port[CR] xor 4;
        '=':
          Port[CR] := Port[CR] xor 8;
        end;
      end;
    s := Port[SR];
    GotoXY(1, 3);
    WriteButton(1, not s, 7);
    WriteButton(2, s, 6);
    WriteButton(3, s, 5);
    WriteButton(4, s, 4);
    WriteButton(5, s, 3);
    Writeln;
    Write('DR = ');
    WriteByte(Port[DR]);
    Writeln;
    Write('SR = ');
    WriteByte(s);
    Writeln;
    Write('CR = ');
    WriteByte(Port[CR]);
    Writeln;
  until False;
end.

Определить какие биты регистров CR и SR инвертируются.

CR: биты 0, 1, 3
SR: бит 7

Вообще, рекомендую почитать про LPT, например http://www.beyondlogic.org/spp/parallel.htm (на английском).

Сообщение отредактировано: volvo - 2.11.2006 13:29