Оптимизация алгоритма, Помогите устранить тормоза в игре! Опции

[pashist]

Привет еще раз. Пишу игру Охотник на мышек=) Столкнулся с проблемой: как выполнять две процедуры одновременно? Ответ: никак =) Есть процедура, которая генерит вывод мышей на экран. Еще есть процедура, которая рисует охотника в центре экрана, которым нужно управлять. Но как управлять охотником, если уже выполняется процедура вывода мышей на экран? ReadKey не помогает, он останавливает программу в ожидании нажатия клавиши.
Второй вопрос, но тоже по теме. Чтобы убить мышку, нужно направить ружьё охотника на неё и нажать клавишу "Пробел". Как это можно реализовать в моём коде?

" (Показать/Скрыть)

Uses Graph,Crt;
Const m=24;
      n=28;
      Left  = #75;
      Right = #77;
Type MouseData=Record
     Data: Array[1..m,1..n] Of Integer;
     x,y: Integer;
     Visible: Boolean;
End;
Var Mouse: ^MouseData;
    Mas: Array[1..15] Of ^MouseData;
    GD,GM: Integer;
    x0, y0, x1, y1, r : Integer;
    c : Char;
    t : Real;
Procedure ReadMouseData(Path: String);
Var FT: File Of MouseData;
Begin
     Assign(FT,Path);
     ReSet(FT);
     New(Mouse);
     Read(FT,Mouse^);
     Close(FT);
End;
Function RandCoord(Coord: Char): Integer;
Var z,j: Integer;
    Flag: Boolean;
Begin
     If Coord='x' Then
        Begin
             Repeat
                   Flag:=True;
                   z:=Random(620);
                   For j:=1 To 15 Do
                       If (ABS(z-Mas[j]^.x))<26 Then
                          Begin
                               Flag:=False;
                               Break
                          End;
             Until (z>13) AND (z<620) AND Flag AND ((z<309) Or (z>331));
        End;
     If Coord='y' Then
         Begin
              Repeat
                    Flag:=True;
                    z:=Random(460);
                    For j:=1 To 15 Do
                        If (ABS(z-Mas[j]^.y))<20 Then
                           Begin
                                Flag:=False;
                                Break
                           End;
             Until (z>15) AND (z<460) AND Flag AND ((z<229) Or (z>251));
         End;
     RandCoord:=z;
End;
Procedure DrawHunter(KC: Char);

Begin
     Case KC Of
      Left:  t := t - 0.1;
      Right: t := t + 0.1;
     End;
     If (t >= 2 * Pi) Or (t <= -2 * Pi) Then t := 0;
     SetColor(Black);
     Line(x0, y0, x1, y1);
     x1 := Round(r * cos(t)) + x0;
     y1 := Round(r * sin(t)) + y0;
     SetColor(White);
     Line(x0, y0, x1, y1);
     SetColor(Blue);
     SetFillStyle(1, Blue);
     PieSlice(320, 240, 0, 360, 10);
     SetColor(Green);
     SetFillStyle(1, Green);
     PieSlice(320, 240, 0, 360, 6);
End;
Procedure MouseVis(Var MTV: MouseData);
Var i,j,x,y,xT,yT: Integer;
Begin
     {–Ґ­ва®ўЄ  ¬лиЁ}
     x:=MTV.x-12;
     y:=MTV.y-14;
     xT:=x;
     yT:=y;
     For i:=1 To m Do
         Begin
              For j:=1 To n Do
                  Begin
                       If MTV.Visible Then
                          {If MTV.Data[i,j]>0 Then} PutPixel(xT,yT,0)
                       Else
                           If MTV.Data[i,j]>0 Then
                              PutPixel(xT,yT,MTV.Data[i,j]);
                       xT:=xT+1;
                  End;
              yT:=yT+1;
              xT:=x;
         End;
        MTV.Visible:=Not MTV.Visible;
        If Not MTV.Visible Then
           Begin
             MTV.x:=RandCoord('x');
             MTV.y:=RandCoord('y');
           End;
End;
Procedure Animation(D: LongInt);
Var i,j :Integer; Flag: Boolean;
Begin
     For i:=1 To 15 Do
         Begin
              New(Mas[i]);
              Mas[i]^:=Mouse^;
              Mas[i]^.x:=RandCoord('x');
              Mas[i]^.y:=RandCoord('y');
         End;
     Repeat
           Repeat
                 i:=Random(15);
           Until i>0;
           c:=ReadKey;
           If (c=Left) Or (c=Right) Then DrawHunter©;
           MouseVis(Mas[i]^);
           Delay(D);
     Until c=#27;
End;
Begin
     x0 := 320;
     y0 := 240;
     r  := 20;
     x1 := r + x0;
     y1 := y0;
     t  := 0;
     GD:=Detect;
     InitGraph(GD,GM,'');
     Randomize;
     ReadMouseData('Mouse.Dat');
     Animation(65535);
End.

[klem4]

Видимо не верно ты ридкей юзать пытаешься ... Делай так :

 while keypressed do ch := readkey; 

Паузы в ожидании нажатия не будет.

[pashist]

Это выход, но все равно скорости работы явно не хватает. Может, есть принципиально другие решения? И что с вторым вопросом?

[Бродяжник]

Вот это

PutPixel(xT,yT,0);

ЗЛО.
Злое злостное зло.
Рисовать ПутПикселем медленно.
Лучше использовать PutImage.
И вообще Unit Graph тормозной. С его помощью быструю игру не сделаешь. И прозрачность в спрайтах он не поддерживает. Конечно, если все дело в том, что нужно сделать лабораторку, тогда ничего не попишешь, а так-то лучше перейти на Delphi и использовать что-то вроде Asphyre. Для "Охотника на мышей" самое то.

[Гость]

Пишу именно лабораторку..

[pashist]

Всем доброе время суток. Переписал алгоритм, используя GetImage. Сама по себе эта функция не устранила тормоза, но с ней работать оказалось гораздо удобнее.

Вот код: (Показать/Скрыть)

Uses Graph,Crt;
Const m = 18;
      n = 18;
      Left  = #75;
      Right = #77;
      Mouses = 10;
Type MouseData=Record
     x,y: Integer;
     Visible: Boolean;
     End;
     Data=Array[1..m,1..n] Of Integer;
Var
   Mouse: ^Data;
   Mas: Array[1..Mouses] Of ^MouseData;
   p: Pointer;
   GD,GM,Size: Integer;
   x0,y0,x1,y1,r: Integer;
   t: Real;
Procedure ReadMouseData(Path: String);
Var FT: File Of Data;
Begin
     Assign(FT,Path);
     ReSet(FT);
     New(Mouse);
     Read(FT,Mouse^);
     Close(FT);
End;
Procedure GetImageData;
Var i,j: Integer;
Begin
     For i:=1 To m Do
         For j:=1 To n Do
             PutPixel(j,i,Mouse^[i,j]);
     Size:=ImageSize(0,0,m,n);
     GetMem(p,Size);
     GetImage(0,0,m,n,p^);
     ClearDevice;
End;
Function RandCoord(Coord: Char): Integer;
Var z,i: Integer;
    Flag: Boolean;
Begin
     If Coord='x' Then {m}
        Begin
          Repeat
                Flag:=True;
                z:=Random(640);
                For i:=1 To Mouses Do
                    If (ABS(z-Mas[i]^.x))<20 Then
                       Begin
                          Flag:=False;
                          Break
                       End;
          Until (z<622) AND Flag AND ((z<280) Or (z>360));
        End;
     If Coord='y' Then {n}
        Begin
          Repeat
                Flag:=True;
                z:=Random(480);
                For i:=1 To Mouses Do
                    If (ABS(z-Mas[i]^.y))<20 Then
                       Begin
                            Flag:=False;
                            Break
                       End;
             Until (z<462) AND Flag AND ((z<200) Or (z>280));
         End;
     RandCoord:=z;
End;
Procedure InitHunter;
Begin
     x0:=320;
     y0:=240;
     r:=20;
     x1:=r+x0;
     y1:=y0;
     t:=0;
End;
Procedure InitMouses;
Var i: Integer;
Begin
     For i:=1 To Mouses Do
         Begin
              New(Mas[i]);
              Mas[i]^.x:=RandCoord('x');
              Mas[i]^.y:=RandCoord('y');
              Mas[i]^.Visible:=False;
         End;
End;
Procedure MouseVis(Var MTV: MouseData);
Var i,j,x,y,xT,yT: Integer;
Begin
     PutImage(MTV.x,MTV.y,p^,XORPut);
     MTV.Visible:=Not MTV.Visible;
     If Not MTV.Visible Then
        Begin
          MTV.x:=RandCoord('x');
          MTV.y:=RandCoord('y');
        End;
End;
Procedure DrawHunter(KC: Char);
Begin
     Case KC Of
      Left:  t:=t-0.1;
      Right: t:=t+0.1;
     End;
     If (t>=2*Pi) Or (t<=-2*Pi) Then t:=0;
     SetColor(Black);
     Line(x0, y0, x1, y1);
     x1:=Round(r*cos(t))+x0;
     y1:=Round(r*sin(t))+y0;
     SetColor(Red);
     Line(x0,y0,x1,y1);
     SetColor(Blue);
     SetFillStyle(1,Blue);
     PieSlice(320,240,0,360,10);
     SetColor(Red);
     SetFillStyle(1,Red);
     PieSlice(320,240,0,360,6);
End;
Procedure WriteCrt;
Var i,j: Integer;
Begin
     RestoreCrtMode;
     For i:=1 To m Do
       Begin
         For j:=1 To n Do
             Begin
                  Write(Mouse^[i,j]);
             End;
         WriteLn;
       End;
     ReadLn
End;
Procedure Main;
Var Tm: Real;
    i: Integer;
    c: Char;
Begin
     Tm:=0;
     Repeat
           Tm:=Tm+1;
           c:=#0;
           While KeyPressed Do c:=ReadKey;
           If (c=Left) Or (c=Right) Then DrawHunter©;
           If Tm=500000 Then
              Begin
                   Repeat i:=Random(Mouses) Until i>0;
                   MouseVis(Mas[i]^);
                   Tm:=0;
              End;
     Until c=#27;
     FreeMem(p,Size);
End;
Begin
     GD:=Detect;
     InitGraph(GD,GM,'');
     Randomize;
     ReadMouseData('Mouse.DAT');
     GetImageData;
     InitHunter;
     DrawHunter(Left);
     InitMouses;
     Main;
End.

А теперь вопросы
1) Почему в коде

     For i:=1 To m Do
         For j:=1 To n Do
             PutPixel(j,i,Mouse^[i,j]);

в PutPixel i и j нужно поменять местами, чтобы мышка выводилась на экран не в перевернутом виде? То есть если я пишу

PutPixel(i,j,Mouse^[i,j]);

, то изображение выводится на экран, повернутое на 90 град. против часовой стрелки.
2) Так никто и не ответил на вопрос, как проверить то, что я правильно прицелился на мышь, когда выстрелил? Нужно сравнить углы положения ружья и мышки относительно центра, и если они будут равны, то я удачно прицелился? Так? Как это сделать?

[Бродяжник]

2) Так, наверное, и сделать - сравнить углы. Нужно только поместить начало координат в пузо охотнику
Вот функция пересчета из декартовых координат в полярный угол (перевел с сишного алгоритма с algolist.ru).

function Angle(x, y: real): real;
var theta: real;
begin
  if (x = 0.0) and (y = 0.0) then
	 Angle := -1.0
  else if x = 0.0 then
	 begin
	   if y > 0 
		  then Angle := 0.5*Pi
		  else Angle := 1.5*Pi;
	 end
  else
	 begin
	   theta := arctan(y/x);
	   
	   if x > 0.0 then
		  begin
			if y > 0.0
			   then Angle := theta
			   else Angle := 2*Pi+theta;
		  end
	   else Angle := Pi + theta;
	 end;
end;

Возвращает полярный угол в радианах для точки с координатами Х,У (в нормальной декартовой системе!).
Если бы еще был выложен файл Mouse.Dat, можно было бы подумать над какими-то улучшениями, а так ведь без него программу не запустить...

[pashist]

Mouse.dat-файл, содержащий матрицу 18х18=) Вот генератор:

Uses Crt;
Const m=18;n=18;
Type Data=Array[1..m,1..n] Of Integer;
Var Mouse: Data;
    FT: File Of Data;
    T: Text;
    Str: Char;
    i,j,vStr,Err: Integer;
Begin
     ClrScr;
     Assign(T,'Picture.txt');
     Assign(FT,'Mouse.Dat');
     ReSet(T);
     ReWrite(FT);
     For i:=1 To n Do
       Begin
         For j:=1 To m Do
             Begin
                  Read(T,Str);
                  Val(Str,vStr,Err);
                  Mouse[i,j]:=vStr;
                  Write(vStr);
             End;
             ReadLn(T);
             WriteLn
       End;
     Write(FT,Mouse);
     Close(FT);
     Close(T);
       ReadLn;
End.

Файл Picture.txt

002220000000222000
020002000002000200
200000200020000020
200000200020000020
020002020202000200
200000002000000020
200022200022200020
200200020200020020
200202020202020020
200022200022200020
020000002000000200
020000002000000200
002000020200002000
002000000000002000
000200222220020000
000200200020020000
000020022200200000
000002222222000000

=) Вообще хотелось бы грузить мышку из стандартного bmp-шника.

Сообщение отредактировано: volvo - 2.11.2006 17:46

[Бродяжник]

Ну так вот:
в этом цикле

	 For i:=1 To n Do
	   Begin
		 For j:=1 To m Do
			 Begin
				  Read(T,Str);
				  Val(Str,vStr,Err);
				  Mouse[i,j]:=vStr;
				  Write(vStr);
			 End;
			 ReadLn(T);
			 WriteLn
	   End;

индекс i отвечает за строки, а j за столбцы. То есть Mouse[строка,столбец].
А в этом цикле

	 For i:=1 To m Do
		 For j:=1 To n Do
			 PutPixel(i,j,Mouse^[i,j]);

наоборот: индекс j отвечает за строки, а i за столбцы. То есть PutPixel(столбец,строка). Поэтому и приходится переставлять индексы местами.
А что тормозит? Охотник медленно вертится, или мыши редко появляются? А то у меня компьютер быстрый, может я не замечаю чего...

[pashist]

Поменяй в этом цикле

     For i:=1 To n Do
       Begin
         For j:=1 To m Do
             Begin
                  Read(T,Str);
                  Val(Str,vStr,Err);
                  Mouse[i,j]:=vStr;
                  Write(vStr);
             End;
             ReadLn(T);
             WriteLn
       End;

m и n местами-и ничего не произойдет-изображение все равно придется переворачивать. Я так и не разобрался, почему. Тормозов больше в игре нет, я же писал.

Сообщение отредактировано: volvo - 2.11.2006 17:46

[volvo]

Поменяй в этом цикле <...> m и n местами-и ничего не произойдет

Правильно... у тебя индексы-то по-прежнему перепутаны: I так же отвечает за строки, а J - за столбцы... Чего ты добился заменой M <-> N ???

Тебе I и J менять надо...

[Бродяжник]

Тем более, что матрица-то квадратная, 18х18, так что m и n равны. Сколько их не меняй...

[pashist]

Спасибо! А как заюзать функу angle? Как поместить начало координат в центр охотника(центр экрана)?

[Бродяжник]

Ну...
Предположим, что режим 640 на 480. И начало координат вверху слева. И ось У направлена вниз. Так, как это обычно в графических режимах бывает. Пусть Xg и Yg - это координаты точки в данной системе отсчета.
Переносим начало координат в центр экрана и разворачиваем ось Y.

X1 := Xg - 320;
Y1 := 240 - Yg;

Теперь у нас X1 и Y1 это координаты той же точки, но в декартовых координатах с началом отсчета в центре экрана. То есть, если экранные координаты мышонка Xm и Ym, то чтобы получить угол прицела на данную мышь, надо делать так:

Ugol := Angle(Xm-320.0, 240.0-Ym);

По-моему, так!

[pashist]

Опять косяк.. Я неправильно использую функу Angle?

Function Shot(xH,yH: Real): Boolean;
Var xM,yM,HunterAngle,MouseAngle: Real;
    i: Integer;
    Flag: Boolean;
    St: String;
Begin
     HunterAngle:=Angle(xH-320,240-yH);
     SetColor(Black);
     OutTextXY(10,460,St);
     SetColor(Red);
     Str(HunterAngle,St);
     OutTextXY(10,460,St);
     For i:=1 To Mouses Do
         Begin
              MouseAngle:=Angle(Mas[i]^.x-320,240-Mas[i]^.y);
              If HunterAngle=MouseAngle Then
                 Begin
                      Flag:=True;
                      Break;
                 End;
         End;
         If Flag Then
            Begin
                 MouseVis(Mas[i]^,True);
                 Shot:=True;
            End
         Else
             Shot:=False;
End;

После выстрела появляются левые убитые мышки.. =(
Прикрепил доработанную полную версию.  MAIN.PAS ( 5.55 килобайт ) Кол-во скачиваний: 536

[Бродяжник]

Отвечу завтра. Единственное замечание - стоит ли сравнивать углы на точное равенство? Не лучше ли вычислять их разность и сравнивать ее с некоторой дельтой? Тем более что и мышка ведь не точечная...

[pashist]

Я так и хотел сделать, но сначала я хотел разобраться с точными данными, чтобы потом можно было вносить погрешности.

[Бродяжник]

Простой корявый пример, иллюстрирущий идею.

[pashist]

Круто! Бродяжник, спасибо! Вот, что примерно получилось. Уже играть можно))  MAIN.PAS ( 5.97 килобайт ) Кол-во скачиваний: 509
Теперь нужно перевести это в объекты.

[pashist]

Мужики, зацените мой первый опыт в ООП =) Переписал в ООП охотника из игры. Нормально?

Program Hunt;
Uses Graph,Crt;
Const
     Left  = #75;
     Right = #77;
Type
    Hunter=Object
       Public
           Constructor Init(xC,yC,WeaponLen,Head,Hat: Integer; Speed: Real);
           Destructor Done;
           Function CountX(D: Real): Integer;
           Function CountY(D: Real): Integer;
           Procedure Direction(c: Char);
           Procedure Draw;
       Private
           x0,y0,x1,y1,r,HIn,HOut: Integer;
           Spd,t: Real;
    End;
Constructor Hunter.Init(xC,yC,WeaponLen,Head,Hat: Integer; Speed: Real);
Begin
     x0:=xC;
     y0:=yC;
     r:=WeaponLen;
     HIn:=Head;
     HOut:=Hat;
     Spd:=Speed;
     x1:=r+x0;
     y1:=y0;
     t:=0;
End;
Destructor Hunter.Done;
Begin
     WriteLn('Done');
End;
Function Hunter.CountX(D: Real): Integer;
Begin
     CountX:=Round(r*Cos(D))+x0;
End;
Function Hunter.CountY(D: Real): Integer;
Begin
     CountY:=Round(r*Sin(D))+y0;
End;
Procedure Hunter.Direction(c: Char);
Begin
     Case c Of
          Left:  t:=t-Spd;
          Right: t:=t+Spd;
     End;
     If (t>=2*Pi) Or (t<=-2*Pi) Then t:=0;
End;
Procedure Hunter.Draw;
Begin
     SetColor(Black);
     Line(x0,y0,x1,y1);
     x1:=CountX(t);
     y1:=CountY(t);
     SetColor(Red);
     Line(x0,y0,x1,y1);
     SetColor(Blue);
     SetFillStyle(1,Blue);
     PieSlice(x0,y0,0,360,HIn);
     SetColor(Red);
     SetFillStyle(1,Red);
     PieSlice(x0,y0,0,360,HOut);
End;
Var GD,GM: Integer;
    H: Hunter;
    k: Char;
Begin
     GD:=Detect;
     InitGraph(GD,GM,'');
     H.Init(320,240,20,10,6,0.1);
     Repeat
           k:=ReadKey;
           H.Direction(k);
           H.Draw;
     Until k=#27;
     CloseGraph;
     H.Done;
     ReadLn
End.