IPB
ЛогинПароль:

2 страниц V  1 2 >  
 Ответить  Открыть новую тему 
> Игрушка змейка., Курсавая работа. Срок месяц.Спасайте :)
сообщение
Сообщение #1


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Меня сегодня убили sad.gif С помощью Вольвы сдала программку с графикой на 5 ^_^
Но сегодня дали курсавик. Змейка. Полистала тут форум, одни исходники.
Хочется написать самой, ну или кусочки кодов украсть.
Объекты еще не проходили, но без них думаю неполучится написать. Если не трудно.
Можете помочь сделать игрушку... Объяснить с чего начать, привести парочку примеров ( Я НЕ КОГО НЕ ЗАСТАВЛЯЮ НИЧЕГО ДЕЛАТЬ, ПРОСТО ПРОШУ ПОМОЧЬ, КОМУ НЕ ТЯЖЕЛО) кусочков кодов и для чего они служат, просто совести не хватит взять чужое, и впихнуть, да и сама должна понять, как такое делается...

Сообщение отредактировано: DarkMoonSide -
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #2


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


М
Пожалуйста, измени заголовок (Правила, п.8)



Тебе змейка в какой моде нужна: в тексте или графике?


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #3


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


graph+crt режимы.


Добавлено через 1 мин.
Что-то типа
(Модуль + основная программа)


Прикрепленные файлы
Прикрепленный файл  SOLITER.PAS ( 16.34 килобайт ) Кол-во скачиваний: 584
Прикрепленный файл  TEXTURE.PAS ( 6.62 килобайт ) Кол-во скачиваний: 464
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #4


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


М
Спасибо



Для змейки тебе понадобится FIFO. Реализуй его на обычных массивах, динамическая память не обязательна. Два целочисленных массива - x и y, координаты звена.


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #5


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Цитата

Для змейки тебе понадобится FIFO. Реализуй его на обычных массивах, динамическая память не обязательна. Два целочисленных массива - x и y, координаты звена.

Что есть фифо?..
Учу паскаль, да и вообще программирование 3 месяца...
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #6


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


Цитата(DarkMoonSide @ 18.02.2009 1:07) *
Что есть фифо?..

Буфер типа "первым вошел - первым вышел (First In - First Out)"

Поищи на это слово по Форуму.


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #7


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Называется Очередь.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #8


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


На самом деле, FIFO не обязательно. Если не жалко памяти и есть возможность хранить состояния всех точек поля (экрана), то может быть даже проще.

Вот простенькая реализация змейки с FIFO, я сейчас набросал с учетом твоих требований (юниты, текст с возможностью подключения графики). Управление на стрелочках, конец игры при ударе в стенку, самопересечения допускаются пока. Поиграйся и попробуй разобраться. А потом можно будет и без фифы сделать - кстати, так даже проще отлавливать самопересечения.

Файл FIFO.pas
unit FIFO;

interface

const
lMax=$1000;

procedure Put(x,y: integer);
procedure Get(var x,y: integer);

implementation

var
u,v: array[0..lMax-1]of integer;
i,j,h,t,l: integer;


procedure Put(x,y: integer);
begin
if l<lMax then begin
Inc(l);
h:=(h+1) mod lMax;
u[h]:=x;
v[h]:=y
end
end;


procedure Get(var x,y: integer);
begin
if l>0 then begin
Dec(l);
x:=u[t];
y:=v[t];
t:=(t+1) mod lMax
end
end;


begin
h:=0;
t:=1;
l:=0
end.


Файл Board.pas
unit Board;

interface

uses CRT;

type
tMode=(No,Gr,Tx);
tPict=(Noth,Head,Bond,Rabb);

const
TxPict: array[tPict]of char=(' ','%','0','@');

var
Mode: tMode;

procedure SetMode(m: tMode);
function MinX: integer;
function MaxX: integer;
function MinY: integer;
function MaxY: integer;
procedure ShowBoard;
procedure Show(p: tPict; x,y:integer);


implementation

procedure SetMode(m: tMode);
begin
Mode:=m
end;


function MinX: integer;
begin
case Mode of
Gr: ;
Tx: MinX:=Lo(WindMin)+1;
end
end;


function MaxX: integer;
begin
case Mode of
Gr: ;
Tx: MaxX:=Lo(WindMax)+1;
end
end;


function MinY: integer;
begin
case Mode of
Gr: ;
Tx: MinY:=Hi(WindMin)+1;
end
end;


function MaxY: integer;
begin
case Mode of
Gr: ;
Tx: MaxY:=Hi(WindMax)+1;
end
end;


procedure ShowBoard;
begin
case Mode of
Gr: ;
Tx: ClrScr;
end
end;


procedure Show(p: tPict; x,y: integer);
begin
case Mode of
Gr: ;
Tx: begin
GoToXY(x,y);
Write(TxPict[p])
end
end
end;


begin
Mode:=No
end.


Файл Viper.pas
uses FIFO,Board,Dos,CRT;

var
i,x,y,u,v,x1,Rx,Ry,y1,x2,y2,sx,sy: integer;
t,dt: LongInt;
c: char;
e: boolean;

function Time: LongInt;
var
m,d,h,mi,s,s1:word;
l:LongInt;
begin
GetDate(h,m,d,mi);GetTime(h,mi,s,s1);l:=d;
Time:=(((l*24+h)*60+mi)*60+s)*100+s1
end;


begin
SetMode(Tx);
ShowBoard;
x1:=MinX;
x2:=MaxX;
y1:=MinY;
y2:=MaxY;
for i:=x1 to x2 do begin
GoToXY(i,y1);
Write('*');
GoToXY(i,y2);
Write('*');
end;
Inc(y1);
Dec(y2);
for i:=y1 to y2 do begin
GoToXY(x1,i);
Write('*');
GoToXY(x2,i);
Write('*');
end;
Inc(x1);
Dec(x2);

x:=x1;
y:=(y1+y2) div 2+1;
Show(Head,x,y);
Put(x,y);
sx:=1;
sy:=0;
Rx:=10;
Ry:=y;
t:=Time;
dt:=15;
e:=true;
repeat
if e then begin
Show(Rabb,Rx,Ry);
e:=false
end;
t:=t+dt;
Show(Bond,x,y);
x:=x+sx;
y:=y+sy;
Show(Head,x,y);
Put(x,y);
if (x<>Rx)or(y<>Ry) then begin
Get(u,v);
Show(Noth,u,v)
end
else begin
Rx:=Random(x2-x1-1)+x1+1;
Ry:=Random(y2-y1-1)+y1+1;
e:=true
end;
repeat until Time>t;
if KeyPressed then begin
c:=ReadKey;
if c=#0 then begin
c:=ReadKey;
case c of
#72: if sy<>1 then begin
sx:=0;
sy:=-1
end;
#75: if sx<>1 then begin
sx:=-1;
sy:=0
end;
#77: if sx<>-1 then begin
sx:=1;
sy:=0
end;
#80: if sy<>-1 then begin
sx:=0;
sy:=1
end
end
end
end
until (x<x1)or(y<y1)or(x>x2)or(y>y2)
end.


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #9


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Спасибо, пойду разбираться потихоньку.
Приболела sad.gif
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #10


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Если рисовать змейку в текстовом режиме, то я бы рисовал её из треугольничков (#16, #17, #30, #31), указывающих на следующий сегмент. Конечно, запоминать где голова и хвост - всё равно надо. Зато сразу самопересечения легко обнаруживать. Конечно, при условии, что у нас есть возможность узнать, какой символ изображён на экране по таким-то координатам. Не знаю, какая процедура за это отвечает, в принципе можно обратиться к видеопамяти.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #11


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Ребят я конечно понимаю, что вы тут все уже профи, я учу паскаль только 3 месяца....
по этому не сильно "матюкайтесь" smile.gif))
плохо знаю структуры и т.п smile.gif
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #12


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Какое конкретно слово если непонятно - спрашивайте.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #13


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


В общем вот примерная реализация того, что я имел в виду:

uses
CRT;

const
sLeft = #17;
sRight = #16;
sUp = #30;
sDown = #31;
sHead = '%';
sApple = '@';

kUp = #72;
kLeft = #75;
kDown = #80;
kRight = #77;

type
TScreenSymbol = record
Symbol: char;
Color: byte;
end;

var
Key, ScanKey: char;
Time: longint absolute $0040: $006C;
T: longint;
HeadX, HeadY, TailX, TailY: integer;
Direction: (dUp, dLeft, dDown, dRight);
Screen: array [0 .. 49, 0 .. 79] of TScreenSymbol absolute $B800: $0000;
Lost, Win: boolean;
oldTail: char;
x, y, c: integer;

begin
randomize;
TextMode(259);
ClrScr;
HeadX := 40;
HeadY := 40;
TailX := 40;
TailY := 41;
Direction := dUp;
Screen[HeadY, HeadX].Symbol := sHead;
Screen[HeadY, HeadX].Color := 14;
Screen[TailY, TailX].Symbol := sUp;
Screen[TailY, TailX].Color := 2;
Screen[HeadY - 10, HeadX].Symbol := sApple;
Screen[HeadY - 10, HeadX].Color := 4;
Lost := false;
repeat
if KeyPressed then begin
Key := ReadKey;
if Key = #0 then ScanKey := ReadKey
else ScanKey := #0;
end else begin
Key := #0;
ScanKey := #0;
end;
while T = Time do;
T := Time;
case ScanKey of
kUp: if Direction <> dDown then Direction := dUp;
kLeft: if Direction <> dRight then Direction := dLeft;
kDown: if Direction <> dUp then Direction := dDown;
kRight: if Direction <> dLeft then Direction := dRight;
end;
case Direction of
dUp: begin
Screen[HeadY, HeadX].Symbol := sUp;
Screen[HeadY, HeadX].Color := 2;
dec(HeadY);
if HeadY < 0 then Lost := True;
end;
dLeft: begin
Screen[HeadY, HeadX].Symbol := sLeft;
Screen[HeadY, HeadX].Color := 2;
dec(HeadX);
if HeadX < 0 then Lost := True;
end;
dDown: begin
Screen[HeadY, HeadX].Symbol := sDown;
Screen[HeadY, HeadX].Color := 2;
inc(HeadY);
if HeadY >= 50 then Lost := True;
end;
dRight: begin
Screen[HeadY, HeadX].Symbol := sRight;
Screen[HeadY, HeadX].Color := 2;
inc(HeadX);
if HeadX >= 80 then Lost := True;
end;
end;
case Screen[HeadY, HeadX].Symbol of
sUp, sLeft, sDown, sRight: Lost := True;
sApple: begin
c := 0;
repeat
inc©;
if c = 1000 then Win := True;
x := random(80);
y := random(50);
until (Screen[y, x].Symbol = ' ') or (c >= 1000);
Screen[y, x].Symbol := sApple;
Screen[y, x].Color := 4;
end;
else begin
oldTail := Screen[TailY, TailX].Symbol;
Screen[TailY, TailX].Symbol := ' ';
case oldTail of
sUp: dec(TailY);
sLeft: dec(TailX);
sDown: inc(TailY);
sRight: inc(TailX);
end;
end;
end;
Screen[HeadY, HeadX].Symbol := sHead;
Screen[HeadY, HeadX].Color := 14;
until (Key = #27) or Lost or Win;
if Lost then WriteLn('You have lost!');
if Win then WriteLn('You win!!!');
end.


В этом коде вы можете не знать слово Textmode - оно принудительно переводит экран в режим 80 на 50 символов, и слово absolute - оно указывает переменной, какой именно адрес ей занимать. Некоторые адреса обладают специальными свойствами, например адрес $0040: $006C содержит системное время (нужно для того, чтобы корректно задавать темп игры), а адрес $B800: $0000 содержит видеопамять, поэтому любое обращение к массиву Screen эквивалентно обращению к видеопамяти. Обратите внимание, что тут приходиться в индексе сначала писать Y, а потом X.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #14


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Ага, спасибо.
А можно я немного обнаглею? мне очень понравилась та змейка которую я прикрепляла, где-то в нете нашла.
МОжет кто-то туда добавить коментариев? ООоооччень прошу smile.gif)) smile.gif хочу узнать , как там и что работает и что делается в той или иной процедуре
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #15


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Цитата(DarkMoonSide @ 20.02.2009 19:33) *

Ага, спасибо.
А можно я немного обнаглею? мне очень понравилась та змейка которую я прикрепляла, где-то в нете нашла.
МОжет кто-то туда добавить коментариев? ООоооччень прошу smile.gif)) smile.gif хочу узнать , как там и что работает и что делается в той или иной процедуре


Я тоже тогда понаглею. Мне кажется, что в том, что вы прикрепили, надо бОльшую часть кода не комментировать, а выкидывать. А то зачем-то объекты приплели в такой элементарной программе, да ещё модули используюся некоторые чуть ли не из Turbo Vision.
Хотя я тут ничего не утверждаю, и возможно, мне это только кажется.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #16


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Ну тогда можеш коменты к своей програмке написать ?smile.gif плиз)
п.с. в игре нужен щетчик очков, и несколько уровней сложности.
п.с. Уровни сложности я так поняла нужно прописывать через /delay? (скорость перемешения змейки) только как ?

Сообщение отредактировано: DarkMoonSide -
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #17


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Коментарии попробую, но только после оптимизации, а то кейсов у меня в коде многовато.
Лучше скажи, что конкретно непонятно.
А вот делэя не надо. Я зря что ли переменную Time ввёл? Вот специально чтобы не было зависимости скорости игры от мощности процессора.
Счётчик очков и нарастание сложности в код вполне вставляется, но я этого делать не буду, в конце концов не мне задание дали.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #18


Новичок
*

Группа: Пользователи
Сообщений: 25
Пол: Женский
Реальное имя: Дианка

Репутация: -  0  +


Цитата(TarasBer @ 20.02.2009 22:16) *

Коментарии попробую, но только после оптимизации, а то кейсов у меня в коде многовато.
Лучше скажи, что конкретно непонятно.
А вот делэя не надо. Я зря что ли переменную Time ввёл? Вот специально чтобы не было зависимости скорости игры от мощности процессора.
Счётчик очков и нарастание сложности в код вполне вставляется, но я этого делать не буду, в конце концов не мне задание дали.

ааа...понятно smile.gif
А подсказачку как сделать сложность?(скорость передвижения змейки) и шетчик очков.
Допустим за одну пойманную точку будет +1 очко, только как это значиние выводить на экран?
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #19


Злостный любитель
*****

Группа: Пользователи
Сообщений: 1 755
Пол: Мужской

Репутация: -  62  +


Счётчик делается простым выводом на экран процедурой Write, естественно надо указать куда выводить при помощи GotoXY.
Тут правда нюанс - эта надпись будет затираться змейкой. Поэтому её надо ограничить, не позволяя ей заходить на верхние 2 строчки (1я строчка для отображения состояния, 2я строчка - "заборчик" для наглядности), и соответственно в условие проигрыша добавить.
Сложность делается, например, так - всё, что связано с движениями змейки, заключается в условный оператор
if T mod Level = 0 then begin ... end
То есть змейка будет двигаться не каждый такт игры, а только в тот, чей номер делится на Level. Значение 1 - максимальный уровень сложности, чем больше значение, тем медленнее двигается змейка.


--------------------
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 
сообщение
Сообщение #20


Уникум
*******

Группа: Пользователи
Сообщений: 6 823
Пол: Мужской
Реальное имя: Лопáрь (Андрей)

Репутация: -  159  +


TarasBer, на мой взгляд неправильно учить новичка использовать прямое обращение к системной и аппаратной памяти. Это, кроме всего прочего, вызовет удивление преподавателя (это скорее слова к DarkMoonSIde). Очень рекомендую переделать на обращение через DOS и стандартные модули.


--------------------
я - ветер, я северный холодный ветер
я час расставанья, я год возвращенья домой
 Оффлайн  Профиль  PM 
 К началу страницы 
+ Ответить 

2 страниц V  1 2 >
 Ответить  Открыть новую тему 
1 чел. читают эту тему (гостей: 1, скрытых пользователей: 0)
Пользователей: 0

 





- Текстовая версия 23.10.2020 7:40
500Gb HDD, 6Gb RAM, 2 Cores, 7 EUR в месяц — такие хостинги правда бывают
Связь с администрацией: bu_gen в домене octagram.name